build.gradle

plugins {
    id 'dev.architectury.loom' version '0.12.0-SNAPSHOT'
    id 'com.matthewprenger.cursegradle' version '1.4.0'
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

version = project.mod_version
archivesBaseName = project.archives_base_name

repositories {
    mavenCentral()

    maven { url "https://maven.shedaniel.me/" }

    maven {
        name = 'TerraformersMC'
        url = 'https://maven.terraformersmc.com/'
    }
}

dependencies {
    forge "net.minecraftforge:forge:${project.forge_version}"
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    //modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    //modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
    //modImplementation "com.terraformersmc:modmenu:${project.modmenu_version}"
    modApi("me.shedaniel.cloth:cloth-config-forge:${project.cloth_config_version}") {
    //    exclude(group: "net.fabricmc.fabric-api")
        exclude(module: "gson")
    }
}

loom {
    forge {
        mixinConfigs = [
            "autoreconnect.mixins.json"
        ]
    }
}

processResources {
    inputs.property "id", project.mod_id
    inputs.property "name", project.mod_name
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand(["id": project.mod_id, "name": project.mod_name, "version": project.version])
    }
}

tasks.withType(JavaCompile).configureEach {
    // Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
    it.options.release.set(17)
}

java {
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}" }
    }
    manifest {
        attributes([
                "Specification-Title"     : project.mod_id,
                "Specification-Vendor"    : "Bstn1802, ZekerZhayard",
                "Specification-Version"   : "1", // We are version 1 of ourselves
                "Implementation-Title"    : project.mod_name,
                "Implementation-Version"  : project.jar.archiveVersion,
                "Implementation-Vendor"   : "Bstn1802, ZekerZhayard",
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ])
    }
}

import com.matthewprenger.cursegradle.CurseArtifact
import com.matthewprenger.cursegradle.CurseUploadTask

def apiKey = System.getenv("CURSEFORGE_API_KEY") ?: findProperty("curseforge.api.key")

// We don’t use the task provided by the plugin because it adds some dependencies that we don’t need.
tasks.create(name: "publishCurseForge", type: CurseUploadTask) { task ->
    onlyIf {
        apiKey != null
    }

    task.apiKey = apiKey
    projectId = "646159"
    mainArtifact = new CurseArtifact().with {
        artifact = tasks.jar
        gameVersionStrings = ["Forge", "Java 17", "1.18.1", "1.18.2"]
        changelogType = "text"
        changelog = ""
        displayName = "${archivesBaseName}-${version}"
        releaseType = "release"
        it
    }
    additionalArtifacts = []
}