Expected a value of type 'Object', but received a value of type 'Array'

[hornta]

Full error:

Error: ERROR: {"status":"Failed","error":{"code":"DeploymentFailed","target":"/subscriptions/***/resourceGroups/rg-planning-dev/providers/Microsoft.Resources/deployments/planning-api","message":"At least one resource deployment operation failed. Please list deployment operations for details. Please see https://aka.ms/arm-deployment-operations for usage details.","details":[{"code":"InvalidTemplate","message":"Deployment template validation failed: 'The provided value for the template parameter 'existingStagingAppSettings' is not valid. Expected a value of type 'Object', but received a value of type 'Array'. Please see https://aka.ms/arm-create-parameter-file for usage details.'.","additionalInfo":[{"type":"TemplateViolation","info":{"lineNumber":1,"linePosition":2628,"path":"properties.template.parameters.existingStagingAppSettings.type"}}]}]}}

I'm trying to append one more environment variable to my App Service main slot as well as an extra slot called staging. Bicep thinks I'm passing an array but it should be an object, can anyone help figure out why that is?

Looking at vscode tooltip for the types it says it's a string dictionary which I guess is an object:

@allowed([
  'dev'
  'stg'
  'prod'
])
param environment string

var appName = 'app-planning-${environment}-expn'

resource serviceBus 'Microsoft.ServiceBus/namespaces@2022-01-01-preview' existing = {
  name: 'sb-nexus-${environment}-expn'
  scope: resourceGroup('rg-nexus-${environment}')
}

var serviceBusEndpoint = '${serviceBus.id}/AuthorizationRules/RootManageSharedAccessKey'
var serviceBusConnectionString = listKeys(serviceBusEndpoint, serviceBus.apiVersion).primaryConnectionString

var appsettingsName = '${appName}/appsettings'
var existingAppSettings = list(
  resourceId('Microsoft.Web/sites/config', appName, 'appsettings'),
  '2022-03-01'
).properties

resource appService 'Microsoft.Web/sites@2022-03-01' existing = {
  name: appName
}

resource appServiceStaging 'Microsoft.Web/sites/slots@2022-03-01' existing = {
  name: 'staging'
  parent: appService
}

resource appServiceStagingConfig 'Microsoft.Web/sites/slots/config@2022-09-01' existing = {
  name: 'appsettings'
  parent: appServiceStaging
}

module extend_appsettings './extend-appsettings.bicep' = {
  name: 'extend-appsettings'
  params: {
    appName: appName
    name: appsettingsName
    stagingName: appServiceStagingConfig.name
    existingAppSettings: existingAppSettings
    existingStagingAppSettings: appServiceStagingConfig.properties
    serviceBusConnectionString: serviceBusConnectionString
  }
}

// extend-appsettings.bicep

param appName string
param name string
param stagingName string
param existingAppSettings object
param existingStagingAppSettings object
param serviceBusConnectionString string

resource app_service_config_appsettings 'Microsoft.Web/sites/config@2022-03-01' = {
  name: name
  properties: union(
    existingAppSettings, {
    NEXUS_SERVICE_BUS_CONNECTION_STRING: serviceBusConnectionString
  })
}

resource appService 'Microsoft.Web/sites@2022-03-01' existing = {
  name: appName
}

resource appServiceStaging 'Microsoft.Web/sites/slots@2022-03-01' existing = {
  name: 'staging'
  parent: appService
}

resource app_service_config_appsettings_staging 'Microsoft.Web/sites/slots/config@2022-09-01' = {
  name: stagingName
  parent: appServiceStaging
  properties: union(
    existingStagingAppSettings, {
    NEXUS_SERVICE_BUS_CONNECTION_STRING: serviceBusConnectionString
  })
}

[GABRIELNGBTUC]

I guess it is an issue with the resource provider when using an existing statement.

Using this bicep file with the list function, I can retrieve the app settings key-values.

resource app_resource 'Microsoft.Web/sites@2023-01-01' existing = {
  name: 'function-name-here'
  scope: resourceGroup('resource-group-name-here')
  resource config 'config' existing = {
    name: 'appsettings'
  }
}


output out object = list(app_resource::config.id, '2023-01-01').properties

If I remove the list function and try to directly access app_resource::config.properties, I do get the same error as you.

Also, when I check the actual read call in the portal, the properties field return an empty array which may be the cause of the error.

{
    "id": "***",
    "name": "appsettings",
    "type": "Microsoft.Web/sites/config",
    "location": "West Europe",
    "tags": {},
    "properties": []
}