How to use conditional loops

[teemukom]

I'm trying to create route tables per subnet and in every route table I'd need routes for every other subnet except the one where the specific route table is assigned.

So subnets would be:

var subnets = [
  {
    name: 'frontend'
    subnetPrefix: '10.1.0.0/26'
  }
  {
    name: 'backend'
    subnetPrefix: '10.1.0.64/26'
  }
  {
    name: 'appservice'
    subnetPrefix: '10.1.0.128/26'
  }
]

And for frontend subnet there would be routetable with routes to backend and appservice subnets, but not to itself.

What I'm trying to do is to use the AVM module for route table and loop through the subnets and create specific route tables. The problem is that how could one create the routes only for those subnetPrefixes which is not a member of the route table we are creating?

Something like this but the routes section is the issue:

module resRouteTable 'br/public:avm/res/network/route-table:0.4.0' = [for (subnet, i) in subnets: {
  scope: resourceGroup(parNetworkResourceGroupName)
  name: '${uniqueString(deployment().name, parLocation)}-rt-${subnet.name}'
  params: {
    name: 'rt-${subnet.name}'
    routes: [for subnet2 in subnets: (subnet2.name != subnet.name) ? { // Only deploy if the array member name is not the same as where we are creating the route table
      name: 'foo'
      properties: {
          addressPrefix: subnet2.subnetPrefix
          nextHopType: 'VnetLocal'
      }
    }: []]
    disableBgpRoutePropagation: true
  }
  dependsOn: [
    resNetworkResourceGroup
  ]
}]

[levimatheri]

Does this work? I changed the [] in the negative case of the ternary expression to {}.

module resRouteTable 'br/public:avm/res/network/route-table:0.4.0' = [for (subnet, i) in subnets: {
  scope: resourceGroup(parNetworkResourceGroupName)
  name: '${uniqueString(deployment().name, parLocation)}-rt-${subnet.name}'
  params: {
    name: 'rt-${subnet.name}'
    routes: [for subnet2 in subnets: (subnet2.name != subnet.name) ? { // Only deploy if the array member name is not the same as where we are creating the route table
      name: 'foo'
      properties: {
          addressPrefix: subnet2.subnetPrefix
          nextHopType: 'VnetLocal'
      }
    }: {}]
    disableBgpRoutePropagation: true
  }
  dependsOn: [
    resNetworkResourceGroup
  ]
}]

[teemukom]

Thanks @levimatheri! Knew it was something simple.

[levimatheri]

On a second look, that doesn't seem to work at runtime, because it's essentially generating something like: [{}, {}, ...] for the negative case. Take a look at this solution instead, I tested it and it worked for me:

...
module resRouteTable 'br/public:avm/res/network/route-table:0.4.0' = [
  for (subnet, i) in subnets: {
    scope: resourceGroup(parNetworkResourceGroupName)
    name: '${uniqueString(deployment().name, parLocation)}-rt-${subnet.name}'
    params: {
      name: 'rt-${subnet.name}'
      routes: map(filter(subnets, (subnet2) => subnet2 != subnet), item => {
        name: '${item.name}-route'
        properties: {
          addressPrefix: item.subnetPrefix
          nextHopType: 'VnetLocal'
        }
      })
      disableBgpRoutePropagation: true
    }
    dependsOn: [
      resNetworkResourceGroup
    ]
  }
]