Azure Function App Diagnostic Settings

[rebuildtech]

Hi Team

Is there a way in Bicep to enable Function app Diagnostic Settings and link it to the log analytics workspace that's getting created with insights in BICEP

I see Microsoft.web/sites/diagnostic

However this seems to be referring to existing one itself.

Can someone help me on this if possible?

[kevball2]

You can using something like this

@description('Optional. Resource ID of log analytics workspace.')
param diagnosticWorkspaceId string = ''

param diagnosticLogCategoriesToEnable array = kind == 'functionapp' ? [
  'FunctionAppLogs'
] : [
  'AppServiceHTTPLogs'
  'AppServiceConsoleLogs'
  'AppServiceAppLogs'
  'AppServiceAuditLogs'
  'AppServiceIPSecAuditLogs'
  'AppServicePlatformLogs'
]

@description('Optional. The name of metrics that will be streamed.')
@allowed([
  'AllMetrics'
])
param diagnosticMetricsToEnable array = [
  'AllMetrics'
]


var diagnosticsLogs = [for category in diagnosticLogCategoriesToEnable: {
  category: category
  enabled: true
  retentionPolicy: {
    enabled: true
    days: diagnosticLogsRetentionInDays
  }
}]

var diagnosticsMetrics = [for metric in diagnosticMetricsToEnable: {
  category: metric
  timeGrain: null
  enabled: true
  retentionPolicy: {
    enabled: true
    days: diagnosticLogsRetentionInDays
  }
}]

resource app_diagnosticSettings 'Microsoft.Insights/diagnosticSettings@2021-05-01-preview' = {
  name: diagnosticSettingsName
  properties: {
    workspaceId:  diagnosticWorkspaceId 
    metrics: diagnosticsMetrics
    logs: diagnosticsLogs
  }
  scope: app
}

The diagnostics scope is tied to your function app you are creating. Just replace app with the name of your function app resource

[brwilkinson]

@rebuildtech were you able to review the sample above from @kevball2 ?

Please mark as answer if so and if you have further questions or need more example, please provide an update.

[pamelafox]

Thanks for that Bicep! If anyone's looking for an example of integrating the Bicep, here's a PR:
pamelafox/staticmaps-function#76
I removed retentionPolicy, btw, as that now results in an error that retentionPolicy should not be specified.