build.gradle

plugins {
    id 'fabric-loom' version '1.6-SNAPSHOT'
    id 'java'
    id 'maven-publish'
}

archivesBaseName = rootProject.archives_base_name
version = rootProject.mod_version + "+" + rootProject.minecraft_version
group = rootProject.maven_group

repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.

    maven {
        name = "Modrinth"
        url = "https://api.modrinth.com/maven"
        content {
            includeGroup "maven.modrinth"
        }
    }
    maven {
        url "https://maven.terraformersmc.com/releases/"
    }
    maven {
        url "https://maven.shedaniel.me"
    }
    maven { url 'https://maven.nucleoid.xyz' }
    maven {
        name = 'Ladysnake Mods'
        url = 'https://maven.ladysnake.org/releases'
    }
}

loom {
    accessWidenerPath = file("src/main/resources/flashfreeze.accesswidener")
}

sourceSets {
    testmod {
        runtimeClasspath += main.runtimeClasspath
        compileClasspath += main.compileClasspath
    }
}

dependencies {
    minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
    mappings "net.fabricmc:yarn:${rootProject.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${rootProject.loader_version}"

    modImplementation "net.fabricmc.fabric-api:fabric-api:${rootProject.fabric_api_version}"

    modImplementation "org.ladysnake.cardinal-components-api:cardinal-components-api:${rootProject.cca_version}"

    modImplementation("com.terraformersmc:modmenu:${rootProject.modmenu_version}") {
        transitive = false
    }

    modImplementation include("eu.pb4:polymer-core:${rootProject.polymer_version}")

    modCompileOnly("me.shedaniel.cloth:cloth-config-fabric:7.0.72") {
        exclude(group: "net.fabricmc.fabric-api")
    }

    modCompileOnly "maven.modrinth:lithium:${rootProject.lithium_version}"

    testmodImplementation sourceSets.main.output
}

loom {
    runs {
        testmodClient {
            client()
            ideConfigGenerated project.rootProject == project
            name = "Testmod Client"
            source sourceSets.testmod
        }
        testmodServer {
            server()
            ideConfigGenerated project.rootProject == project
            name = "Testmod Server"
            source sourceSets.testmod
        }
    }
}


processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

processTestmodResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
    options.release = 17
}

java {
    withSourcesJar()
}