build.gradle

import java.text.SimpleDateFormat

plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.4.30'
    id 'io.izzel.taboolib' version '1.3'
}

task buildJar(dependsOn: [clean, jar])

taboolib {
    tabooLibVersion = '5.55'
    loaderVersion = '2.12'
    classifier = null
    builtin = true
}

group 'me.arasple.mc.brevis'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
    maven { url 'https://repo.codemc.org/repository/maven-public' }
}

dependencies {
    taboo 'org.bstats:bstats-bukkit:1.8'
    implementation 'ink.ptms.core:v11604:11604:all'
    implementation 'org.jetbrains.kotlin:kotlin-stdlib'
}

processResources {
    from(sourceSets.main.resources.srcDirs) {
        include 'plugin.yml'
        expand(
                name: rootProject.name,
                main: project.group + '.boot.PluginBoot',
                version: project.version,
                libVersion: taboolib.tabooLibVersion,
                libDownload: true,
                loaderVersion: taboolib.loaderVersion,
                built: new SimpleDateFormat('yyyy-MM-dd HH:mm:ss').format(new Date()),
                builder: System.properties.getProperty('user.name'),
                os: System.properties.getProperty('os.name') + System.properties.getProperty('os.arch') + System.properties.getProperty('os.version')
        )
    }
}

compileKotlin {
    kotlinOptions {
        freeCompilerArgs = ["-Xinline-classes"]
    }
}