build.gradle

import java.text.SimpleDateFormat

plugins {
    id 'checkstyle'
    id "com.github.spotbugs" version "5.0.9"
    id 'com.github.johnrengelman.shadow' version '7.1.2'
    id 'java'
    id 'maven-publish'
}

group = "com.crimsonwarpedcraft.cwcommons"

static def getTime() {
    SimpleDateFormat sdf = new SimpleDateFormat("yyMMdd-HHmm")
    sdf.setTimeZone(TimeZone.getTimeZone("UTC"))
    return sdf.format(new Date()).toString()
}

// Load version from string
String shortVersion = null
if (hasProperty('ver')) {
    if (ver.charAt(0) == "v") {
        shortVersion = ver.substring(1)
    } else {
        shortVersion = ver
    }
}

if (shortVersion == null || shortVersion == "") {
    shortVersion = getTime()
}

// Add snapshot identifier to version
version = shortVersion + "-SNAPSHOT"

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

repositories {
    maven {
        name 'sps'
        url 'https://mvn.snowypeaksystems.com/repository/maven-public/'
    }

    mavenCentral()

    maven {
        name 'papermc'
        url 'https://repo.papermc.io/repository/maven-public/'
        content {
            includeGroup 'io.papermc'
            includeGroup 'io.papermc.paper'
            includeGroup 'net.md-5'
        }
    }
}

dependencies {
    compileOnly 'dev.jorel:commandapi-annotations:8.4.1'
    compileOnly 'dev.jorel:commandapi-shade:8.4.1'
    compileOnly 'io.papermc.paper:paper-api:1.18.1-R0.1-SNAPSHOT'
    compileOnly 'com.github.spotbugs:spotbugs-annotations:4.7.1'
    implementation 'com.google.code.gson:gson:2.9.1'
    implementation 'io.papermc:paperlib:1.0.7'
    spotbugsPlugins 'com.h3xstream.findsecbugs:findsecbugs-plugin:1.12.0'
    testCompileOnly 'com.github.spotbugs:spotbugs-annotations:4.7.1'
    testImplementation 'io.papermc.paper:paper-api:1.18.1-R0.1-SNAPSHOT'
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.2'
}

test {
    useJUnitPlatform()
}

processResources {
    filesMatching("**/plugin.yml") {
        expand ( NAME: rootProject.name, VERSION: version, PACKAGE: project.group.toString() )
    }
}

checkstyle {
    toolVersion '10.3.1'
    maxWarnings = 0
}

tasks.withType(Checkstyle) {
    reports {
        xml.required = false
        html.required = true
    }
}

spotbugsMain {
    reports {
        xml.required = false
        html.required = true
    }
}

spotbugsTest {
    reports {
        xml.required = false
        html.required = true
    }
}

shadowJar {
    archiveClassifier.set('')

    dependencies {
        include dependency('dev.jorel:commandapi-shade:8.4.1')
    }

    relocate 'dev.jorel.commandapi', 'com.crimsonwarpedcraft.cwcommons.shadow.dev.jorel'
    relocate 'io.papermc.lib', 'com.crimsonwarpedcraft.cwcommons.shadow.io.papermc.lib'

    minimize()
}

publishing {
    repositories {
        maven {
            name = "sps"
            url = uri("https://mvn.snowypeaksystems.com/repository/maven-snapshots/")
            credentials {
                username = System.getenv("SPS_MVN_USER")
                password = System.getenv("SPS_MVN_PASS")
            }
        }
    }
    publications {
        spsmvn(MavenPublication) {
            artifact shadowJar.archiveFile
        }
    }
}

// Disable jar and replace with shadowJar
jar.enabled = false
assemble.dependsOn(shadowJar)

// We need to build before we publish
publish.dependsOn(build)

task configureRelease {
    doLast {
        // Trim the "-SNAPSHOT" extension from version
        version = shortVersion
        // Change the publishing repository to release server
        publishing.repositories.getByName(
                "sps",
                {
                    url = uri("https://mvn.snowypeaksystems.com/repository/maven-releases/")
                }
        )
    }
}

// Make sure configuration runs in the correct order
build.mustRunAfter(configureRelease)

task release {
    dependsOn build
    dependsOn publish
    dependsOn configureRelease

    doLast {
        // Rename final JAR to trim off version information
        shadowJar.archiveFile.get().getAsFile()
                .renameTo(buildDir.toString() + File.separator + 'libs' + File.separator
                        + rootProject.name + '.jar')
    }
}