forked from bernie-g/geckolib
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
269 lines (232 loc) · 8.59 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
buildscript {
repositories {
maven { url = "https://maven.minecraftforge.net/" }
maven { url = "https://plugins.gradle.org/m2/" }
jcenter()
mavenCentral()
}
dependencies {
classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.1.+', changing: true
classpath "gradle.plugin.com.github.jengelman.gradle.plugins:shadow:7.0.0"
classpath 'gradle.plugin.com.matthewprenger:CurseGradle:1.4.0'
}
}
apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'eclipse'
apply plugin: 'maven-publish'
apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'java'
apply plugin: 'com.matthewprenger.cursegradle'
apply from: "https://raw.githubusercontent.com/SizableShrimp/Forge-Class-Remapper/main/classremapper.gradle"
import groovy.json.JsonSlurper
import groovy.json.JsonOutput
def snapshotVersion = System.getenv("GITHUB_RUN_NUMBER")
version = snapshotVersion == null ? project.mod_version : "SNAPSHOT-" + snapshotVersion
group = 'software.bernie.geckolib'
archivesBaseName = project.archives_base_name
java.toolchain.languageVersion = JavaLanguageVersion.of(17)
configurations {
library
shade
implementation.extendsFrom library
shade.extendsFrom library
}
minecraft {
mappings channel: 'official', version: '1.18.1'
runs {
client {
workingDirectory project.file('runs/' + name)
singleInstance true
taskName 'Client'
property 'forge.logging.console.level', 'debug'
property 'mixin.env.remapRefMap', 'true'
property 'mixin.env.refMapRemappingFile', "${project.projectDir}/build/createSrgToMcp/output.srg"
mods {
geckolib {
source sourceSets.main
}
}
}
clientAlt {
parent minecraft.runs.client
workingDirectory project.file('runs/' + name)
taskName 'ClientAlt'
args '--username', 'Alt'
}
server {
workingDirectory project.file('runs/' + name)
singleInstance true
taskName 'Server'
property 'forge.logging.console.level', 'debug'
property 'mixin.env.remapRefMap', 'true'
property 'mixin.env.refMapRemappingFile', "${project.projectDir}/build/createSrgToMcp/output.srg"
// Uncomment this to run the server without the GUI
//args 'nogui'
mods {
geckolib {
source sourceSets.main
}
}
}
data {
workingDirectory project.file('runs/' + name)
singleInstance true
taskName 'Data'
property 'forge.logging.console.level', 'debug'
property 'mixin.env.remapRefMap', 'true'
property 'mixin.env.refMapRemappingFile', "${project.projectDir}/build/createSrgToMcp/output.srg"
args '--mod', 'geckolib3', '--all', '--output', file('src/generated/resources/'), '--existing', file('src/main/resources/')
mods {
geckolib {
source sourceSets.main
}
}
}
}
}
minecraft.runs.all {
lazyToken('minecraft_classpath') {
configurations.library.copyRecursive().resolve().collect { it.absolutePath }.join(File.pathSeparator)
}
}
repositories {
maven { url "https://dl.cloudsmith.io/public/geckolib3/geckolib/maven/" }
maven { url "https://maven.enginehub.org/repo/" }
maven { url "https://maven.blamejared.com" }
maven { url "https://minecraft.curseforge.com/api/maven/" }
maven { url "https://maven.cloudsmith.io/geckolib3/geckolib/" }
maven { url "https://cfa2.cursemaven.com" }
maven { url "https://plugins.gradle.org/m2/" }
mavenCentral()
}
dependencies {
minecraft 'net.minecraftforge:forge:1.18.1-39.0.0'
library 'com.eliotlash.molang:molang:18'
library 'com.eliotlash.mclib:mclib:18'
library(project(':geckolib-core')) {
exclude group: 'org.apache.commons'
}
library group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.9.0'
library group: 'com.fasterxml.jackson.datatype', name: 'jackson-datatype-jsr310', version: '2.9.0'
shade 'com.eliotlash.molang:molang:18'
shade 'com.eliotlash.mclib:mclib:18'
shade(project(':geckolib-core')) {
exclude group: 'org.apache.commons'
}
shade group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.9.0'
shade group: 'com.fasterxml.jackson.datatype', name: 'jackson-datatype-jsr310', version: '2.9.0'
testImplementation 'org.junit.jupiter:junit-jupiter-api:5.6.2'
testImplementation 'org.junit.jupiter:junit-jupiter-params:5.6.2'
testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.6.2'
test {
useJUnitPlatform()
}
}
shadowJar {
configurations = [project.configurations.shade]
from sourceSets.main.allSource
exclude('META-INF/services/**')
relocate 'com.eliotlash', 'software.bernie.shadowed.eliotlash'
relocate 'com.fasterxml', 'software.bernie.shadowed.fasterxml'
classifier ''
}
reobf {
shadowJar {} // Reobfuscate the shadowed JAR
}
tasks.build.dependsOn reobfShadowJar
publish.dependsOn('reobfJar')
shadowJar.dependsOn('classes')
jar.finalizedBy('reobfJar')
jar {
manifest {
attributes([
"Specification-Title" : "GeckoLib",
"Specification-Vendor" : "Gecko",
"Specification-Version" : "1", // We are version 1 of ourselves
"Implementation-Title" : project.name,
"Implementation-Version" : "${version}",
"Implementation-Vendor" : "Gecko",
"Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
])
}
}
task packageSources(type: ShadowJar, dependsOn: 'classes') {
configurations = [project.configurations.shade]
from sourceSets.main.allSource
exclude('META-INF/**')
relocate 'com.eliotlash', 'software.bernie.shadowed.eliotlash'
relocate 'com.fasterxml', 'software.bernie.shadowed.fasterxml'
classifier = 'sources'
}
artifacts {
archives shadowJar
archives packageSources
}
afterEvaluate {
publish.dependsOn('reobfShadowJar')
publish.dependsOn('reobfJar')
publish.dependsOn('packageSources')
shadowJar.dependsOn(packageSources)
shadowJar.dependsOn('classes')
}
shadowJar.finalizedBy(reobfShadowJar)
jar.finalizedBy(packageSources)
publishing {
publications {
mavenJava(MavenPublication) {
artifact shadowJar
artifact packageSources
artifactId = project.archives_base_name
}
}
}
publishing {
repositories {
maven {
name = "cloudsmith"
url = "https://maven.cloudsmith.io/geckolib3/geckolib/"
def releasesRepoUrl = "https://maven.cloudsmith.io/geckolib3/geckolib/"
def snapshotsRepoUrl = "https://maven.cloudsmith.io/geckolib3/geckolib/"
url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
credentials {
def envUsername = System.getenv("cloudUsername")
def envPassword = System.getenv("cloudPassword")
username = envUsername == null ? findProperty("cloudUsername") : envUsername
password = envPassword == null ? findProperty("cloudPassword") : envPassword
}
}
}
}
processResources {
doLast {
def jsonMinifyStart = System.currentTimeMillis()
def jsonMinified = 0
def jsonBytesSaved = 0
fileTree(dir: outputs.files.asPath, include: '**/*.json').each {
File file = it
jsonMinified++
def oldLength = file.length()
file.text = JsonOutput.toJson(new JsonSlurper().parse(file))
jsonBytesSaved += oldLength - file.length()
}
println('Minified ' + jsonMinified + ' json files. Saved ' + jsonBytesSaved + ' bytes. Took ' + (System.currentTimeMillis() - jsonMinifyStart) + 'ms.')
}
}
if (file('key.properties').exists()) {
curseforge {
def curseProp = new Properties()
File secretPropsFile = file("key.properties")
curseProp.load(secretPropsFile.newInputStream())
project {
apiKey = curseProp.getProperty('curseKey')
id = "388172"
releaseType = "release"
changelogType = 'text'
changelog = file('changelog.txt')
addGameVersion("1.18.1")
addGameVersion("Forge")
addGameVersion("Java 17")
}
}
}