build.gradle

import org.jetbrains.kotlin.gradle.dsl.KotlinVersion

plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '1.9.0'
}

group = 'kr.kua.evatunahello'
version = '1.0.3-SNAPSHOT'

repositories {
    mavenCentral()
    maven {
        name = 'papermc-repo'
        url = 'https://papermc.io/repo/repository/maven-public/'
    }
    maven {
        name = 'sonatype'
        url = 'https://oss.sonatype.org/content/groups/public/'
    }
    maven {
        name = 'jitPack'
        url = 'https://jitpack.io'
    }
    maven {
        name = 'codecraft47-repo' // BungeeTabListPlus
        url = 'http://nexus.codecrafter47.de/content/repositories/public/'
        allowInsecureProtocol = true
    }
}

dependencies {
    compileOnly 'io.papermc.paper:paper-api:1.20.1-R0.1-SNAPSHOT'
    compileOnly "io.github.waterfallmc:waterfall-api:1.20-R0.1-SNAPSHOT"
    compileOnly "com.gitlab.ruany:LiteBansAPI:0.3.5"
    compileOnly "codecrafter47.bungeetablistplus:bungeetablistplus-api-bungee:2.7.0"

    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
}

def targetJavaVersion = 17
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release = targetJavaVersion
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

kotlin {
    compilerOptions {
        apiVersion.set(KotlinVersion.KOTLIN_1_9)
    }
}

jar {
    from {
        configurations.runtimeClasspath.findAll { it.name.endsWith('jar') }.collect { zipTree(it) }
    }
    duplicatesStrategy = DuplicatesStrategy.INCLUDE
}

compileJava.options.encoding = 'UTF-8' // Encode your source code with UTF-8
// Generate Sources Jar
task sourcesJar(type: Jar) {
    classifier 'sources'
    from sourceSets.main.allSource
}
// Generate Javadoc Jar
task javadocJar(type: Jar) {
    classifier 'javadoc'
    from javadoc.destinationDir
}
artifacts {
    archives sourcesJar, javadocJar // Build Sources and Javadoc Jar
}