build.gradle.kts

plugins {
    java
    `maven-publish`
    id("com.github.johnrengelman.shadow") version "8.1.1"
}

group = "com.iridium"
version = "1.0.5"
description = "IridiumMobCoins"

repositories {
    maven("https://repo.mvdw-software.com/content/groups/public/")
    maven("https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
    maven("https://repo.extendedclip.com/content/repositories/placeholderapi/")
    maven("https://ci.ender.zone/plugin/repository/everything/")
    maven("https://jitpack.io")
    maven("https://nexus.iridiumdevelopment.net/repository/maven-releases/")
    maven("https://papermc.io/repo/repository/maven-public/")
    maven("https://repo.rosewooddev.io/repository/public/")
    maven("https://hub.jeff-media.com/nexus/repository/jeff-media-public/")
}

dependencies {
    // Dependencies that we want to shade in
    implementation("org.jetbrains", "annotations", "22.0.0")
    implementation("com.iridium", "IridiumCore", "1.8.7")
    implementation("org.bstats", "bstats-bukkit", "2.2.1")
    implementation("com.j256.ormlite", "ormlite-core", "6.1")
    implementation("com.j256.ormlite", "ormlite-jdbc", "6.1")
    implementation("de.jeff_media", "SpigotUpdateChecker", "1.3.0")

    // Other dependencies that are not required or already available at runtime
    compileOnly("org.projectlombok", "lombok", "1.18.22")
    compileOnly("org.spigotmc", "spigot-api", "1.17-R0.1-SNAPSHOT")
    compileOnly("me.clip", "placeholderapi", "2.9.2")
    compileOnly("be.maximvdw", "MVdWPlaceholderAPI", "2.1.1-SNAPSHOT") {
        exclude("org.spigotmc")
    }

    // Enable lombok annotation processing
    annotationProcessor("org.projectlombok", "lombok", "1.18.22")
}

tasks {
    // "Replace" the build task with the shadowJar task (probably bad but who cares)
    jar {
        dependsOn("shadowJar")
        enabled = false
    }

    shadowJar {
        // Remove the archive classifier suffix
        archiveClassifier.set("")

        // Relocate dependencies
        relocate("com.fasterxml.jackson", "com.iridium.iridiummobcoins.dependencies.fasterxml")
        relocate("com.j256.ormlite", "com.iridium.iridiummobcoins.dependencies.ormlite")
        relocate("org.bstats", "com.iridium.iridiummobcoins.dependencies.bstats")
        relocate("de.jeff_media", "com.iridium.iridiummobcoins.dependencies")

        // Remove unnecessary files from the jar
        minimize()
    }

    // Set UTF-8 as the encoding
    compileJava {
        options.encoding = "UTF-8"
        sourceCompatibility = JavaVersion.VERSION_1_8.toString()
        targetCompatibility = JavaVersion.VERSION_1_8.toString()
    }

    // Process Placeholders for the plugin.yml
    processResources {
        filesMatching("**/plugin.yml") {
            expand(rootProject.project.properties)
        }

        // Always re-run this task
        outputs.upToDateWhen { false }
    }
}

// Maven publishing
publishing {
    publications.create<MavenPublication>("maven") {
        from(components["java"])
    }
}