Is there a way to have specific configuration according to the IDE (pycharm, intellij, clion...)

[Nimamoh]

I'd like to have specific configuration for different type of IDE I launch. Is there a way to detect the IDE type in _ideavimrc file?

[lippfi]

Hi! It's possible now in IdeaVim 1.8.0-eap.1 (https://github.com/JetBrains/ideavim#get-early-access), where has() function and &ide option were added.
Here is an example of .vimrc/.ideavimrc

" options and mappings that are supported by both Vim and IdeaVim
set nu
set relativenumber

let mapleader= " "

inoremap <expr> jk col(".") == 1 ? '<Esc>' : '<Esc><Right>'
nnoremap U <C-R>
nnoremap S :%s/

if has('ide')
  " mappings and options that exist only in IdeaVim
  map <leader>f <Action>(GotoFile)
  map <leader>g <Action>(FindInPath)
  map <leader>b <Action>(Switcher)

  set ideajoin " https://github.com/JetBrains/ideavim/wiki/%22ideajoin%22-examples 
  set ideastatusicon=gray " changes IdeaVim icon's color to gray
  set idearefactormode=keep " https://github.com/JetBrains/ideavim/wiki/%22set%22-commands

  if &ide =~? 'intellij idea'
    if &ide =~? 'community'
      " some mappings and options for IntelliJ IDEA Community Edition
    elseif &ide =~? 'ultimate'
      " some mappings and options for IntelliJ IDEA Ultimate Edition
    endif
  elseif &ide =~? 'pycharm'
    " PyCharm specific mappings and options
  endif
else
  " some mappings for Vim/Neovim
  nnoremap <leader>f <cmd>Telescope find_files<cr>
  nnoremap <leader>g <cmd>Telescope live_grep<cr>
  nnoremap <leader>b <cmd>Telescope buffers<cr>
endif

&ide option contains your IDE name and edition, e.g. "IntelliJ IDEA Ultimate Edition". To see it's value for your IDE execute echo &ide command.
To write IDE-specific configuration use vim's regexp matches operator =~? (ignore case) / =~# (case sensitive)
Btw if you use " ideaVim ignore and " ideaVim ignore end in the else block like below your parsing and IDE startup will be faster

....
else
" ideaVim ignore
  ......
  ......
" ideaVim ignore end
endif

If any problem appears please let me know. Have a nice day!