build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.2.5'
    id 'io.spring.dependency-management' version '1.1.5'
}

group = 'kea.enter'
version = '0.0.1-SNAPSHOT'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

configurations {
    querydsl.extendsFrom compileClasspath
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}
repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'

    // DB
    implementation 'com.mysql:mysql-connector-j'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'com.h2database:h2'

    // Web
    implementation 'org.springframework.boot:spring-boot-starter-web'

    // Lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'

    // Swagger
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.2.0'

    // Spring Security
    implementation 'org.springframework.boot:spring-boot-starter-security'

    // JWT
    implementation 'io.jsonwebtoken:jjwt:0.12.6'

    //vault
    implementation 'org.springframework.cloud:spring-cloud-starter-vault-config'

    implementation platform('software.amazon.awssdk:bom:2.23.7')
    implementation 'software.amazon.awssdk:s3'

    //codef api
    implementation group: 'io.codef.api', name: 'easycodef-java', version: '1.0.5'

    //querydsl 설정 추가
    implementation "com.querydsl:querydsl-jpa:5.0.0:jakarta"
    annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    //monitoring
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    runtimeOnly ("io.micrometer:micrometer-registry-prometheus")

    // redis
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'

    // email
    implementation 'org.springframework.boot:spring-boot-starter-mail'

    // quartz
    implementation 'org.springframework.boot:spring-boot-starter-quartz'

    // aop
    implementation 'org.springframework.boot:spring-boot-starter-aop'
}

dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:2023.0.3"
    }
}

tasks.named('test') {
    useJUnitPlatform()
}

jar {
    enabled = false
}

def generated = 'src/main/generated'

sourceSets {
    main.java.srcDirs += [generated]
}

tasks.withType(JavaCompile).configureEach {
    options.getGeneratedSourceOutputDirectory().set(file(generated))
}

clean.doLast {
    file(generated).deleteDir()
}