build.gradle

plugins {
	id 'fabric-loom' version '1.9-SNAPSHOT'
	id 'maven-publish'
	id "com.modrinth.minotaur" version "2.8.7"
}

sourceCompatibility = JavaVersion.VERSION_21
targetCompatibility = JavaVersion.VERSION_21

def mcVersion = project.property("minecraft_version")

archivesBaseName = project.archives_base_name
version = mcVersion + "-" + project.mod_version
group = project.maven_group

loom {
	accessWidenerPath = file("src/main/resources/${project.mod_name}.accesswidener")
}

repositories {
	maven {
		url "https://nexus.modlabs.cc/repository/maven-mirrors/"
	}
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	// PSA: Some older mods, compiled on Loom 0.2.1, might have outdated Maven POMs.
	// You may need to force-disable transitivity on them.
	//modCompile "com.jamieswhiteshirt:developer-mode:${project.developer_mode_version}"

	modImplementation "com.terraformersmc:modmenu:${project.mod_menu_version}"
	modLocalRuntime "maven.modrinth:sodium:${project.sodium_dev_version}"
}

processResources {
	inputs.property "version", project.version
	inputs.property "minecraft_version", mcVersion

	filesMatching("fabric.mod.json") {
		expand "version": project.version,
				"minecraft_version": mcVersion
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"

	it.options.release = 21
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			// add all the jars that should be included when publishing to maven
			artifact(remapJar) {
				builtBy remapJar
			}
			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}

modrinth {
	token = System.getenv("MODRINTH_TOKEN")
	projectId = project.modrinth_id
	versionNumber = version
	versionName = "${project.getName()} ${project.mod_version}"
	versionType = isMCVersionNonRelease() ? "beta" : "release"
	changelog = "- Update to ${mcVersion}"
	uploadFile = remapJar
	gameVersions = [ mcVersion ]
	loaders = [ "fabric" ]
	dependencies {
		required.project 'fabric-api'
	}
}

boolean isMCVersionNonRelease() {
	return project.minecraft_version.matches('^\\d\\dw\\d\\d[a-z]$') || project.minecraft_version.matches('\\d+\\.\\d+-(pre|rc)(\\d+)')
}