build.gradle

/*
 * Copyright 2020 Shreyas Patil
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-kapt'
apply plugin: 'androidx.navigation.safeargs.kotlin'
apply plugin: 'dagger.hilt.android.plugin'

android {
    compileSdkVersion ProjectConfig.compileSdkVersion

    defaultConfig {
        applicationId "dev.shreyaspatil.noty.simpleapp"
        minSdkVersion ProjectConfig.minSdkVersion
        targetSdkVersion ProjectConfig.targetSdkVersion
        versionCode ProjectConfig.versionCode
        versionName ProjectConfig.versionName

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    buildFeatures {
        viewBinding true
    }

    buildTypes {
        debug {
            minifyEnabled false
        }
        release {
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        sourceCompatibility javaVersion
        targetCompatibility javaVersion
    }

    kotlinOptions {
        jvmTarget = javaVersion
    }
    kotlin {
        jvmToolchain(javaVersion.toInteger())
    }
    lint {
        abortOnError false
    }
    namespace 'dev.shreyaspatil.noty.simpleapp'

}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
    kotlinOptions {
        jvmTarget = javaVersion
    }
}

kapt {
    correctErrorTypes true
}

dependencies {
    implementation fileTree(dir: "libs", include: ["*.jar"])

    // Kotlin Stdlib
    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlinVersion"

    // Core Module
    implementation project(":core")

    // Common App Module
    implementation project(":app")

    // Coroutines (Android)
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:$coroutinesVersion"

    // Android
    implementation "androidx.core:core-ktx:$coreKtxVersion"
    implementation "androidx.legacy:legacy-support-v4:$legacySupportVersion"
    implementation "androidx.appcompat:appcompat:$appcompatVersion"
    implementation "androidx.constraintlayout:constraintlayout:$constraintlayoutVersion"

    // Activity & Fragment
    implementation "androidx.activity:activity-ktx:$activityVersion"
    implementation "androidx.fragment:fragment-ktx:$fragmentVersion"

    // Dagger + Hilt
    implementation "com.google.dagger:hilt-android:$daggerHiltVersion"
    kapt "com.google.dagger:hilt-android-compiler:$daggerHiltVersion"

    // Hilt + Jetpack
    implementation "androidx.hilt:hilt-navigation-fragment:$jetpackHiltVersion"
    implementation "androidx.hilt:hilt-work:$jetpackHiltVersion"

    // Lifecycle
    implementation "androidx.lifecycle:lifecycle-runtime-ktx:$lifecycleVersion"

    // Material Design
    implementation "com.google.android.material:material:$materialDesignVersion"

    // Lottie Animation Library
    implementation "com.airbnb.android:lottie:$lottieVersion"

    // Navigation
    implementation "androidx.navigation:navigation-fragment-ktx:$navigationVersion"
    implementation "androidx.navigation:navigation-ui-ktx:$navigationVersion"

    // WorkManager
    implementation "androidx.work:work-runtime-ktx:$workmanagerVersion"

    // Testing
    testImplementation "junit:junit:$jUnitVersion"

    // Android Testing
    androidTestImplementation "androidx.test.ext:junit:$androidJUnitVersion"
    androidTestImplementation "androidx.test.espresso:espresso-core:$espressoVersion"

    // Leak Canary
    // Uncomment this when have to check for leaks
    // debugImplementation "com.squareup.leakcanary:leakcanary-android:$leakCanaryVersion"
}