build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'

apply plugin: 'java'
sourceCompatibility = 1.8
targetCompatibility = 1.8

group = package_group
archivesBaseName = mod_name
version = "${mc_version}-${mod_version}"

minecraft {
    version = "${mc_version}-${forge_version}-${mc_version}"
    runDir = "run"

    replace "@VERSION@", project.mod_version
    replaceIn "TaintedMagic.java"
}

processResources {
    inputs.property "mod_version", project.mod_version
    inputs.property "mc_version", project.mc_version

    from(sourceSets.main.resources.srcDirs) {
        include '**/*.info'
        include '**/*.properties'

        expand 'mod_version': project.mod_version, 'mc_version': project.mc_version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude '**/*.info'
        exclude '**/*.properties'
    }
}

jar {
    classifier = ''
    manifest.mainAttributes(
            "Built-By": System.getProperty('user.name'),
            "Created-By": "${System.getProperty('java.vm.version')} + (${System.getProperty('java.vm.vendor')})",
            "Implementation-Title": project.name,
            "Implementation-Version": project.version,
            "Built-On": "${mc_version}-${forge_version}"
    )
}

task versionTxt()  {
    doLast {
        new File(projectDir, "version.txt").text = mod_version
    }
}
build.dependsOn('versionTxt')