build.gradle

plugins {
    id 'fabric-loom' version '0.10.+'
    id 'maven-publish'
    id "org.jetbrains.kotlin.jvm" version "1.6.0"
}

allprojects {

    plugins.apply("fabric-loom")

    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17

    version = project.mod_version
    group = project.maven_group

    repositories {
        maven {
            url = "https://maven.nucleoid.xyz"
        }
        maven {
            url = "https://oss.sonatype.org/content/repositories/snapshots"
        }
        maven {
            url = "https://maven.kyrptonaught.dev/"
        }

        mavenLocal()
    }

    dependencies {
        // To change the versions see the gradle.properties file
        minecraft "com.mojang:minecraft:${project.minecraft_version}"
        mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
        modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

        // Fabric API
        modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

        modImplementation(include("eu.pb4:polymer:0.2.0-beta.29+1.18.2"))
    }

    processResources {
        inputs.property "version", project.version

        filesMatching("fabric.mod.json") {
            expand "version": project.version
        }
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.encoding = "UTF-8"

        it.options.release = 17
    }

    java {
        withSourcesJar()
    }

    jar {
        from("LICENSE") {
            rename { "${it}_${project.archivesBaseName}" }
        }
    }
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    repositories {

    }
}
compileKotlin.kotlinOptions.jvmTarget = "17"

archivesBaseName = project.archives_base_name

dependencies {
    // FLK
    modImplementation "net.fabricmc:fabric-language-kotlin:${project.fabric_kotlin_version}"

    modImplementation(include("xyz.nucleoid:fantasy:0.4.4+1.18.2"))
    modImplementation(include("me.lucko:fabric-permissions-api:0.1-SNAPSHOT"))
    modImplementation(include("eu.pb4:sgui:1.0.0+1.18.1"))
    implementation(include('com.ginsberg:cirkle:1.0.1'))


    subprojects.forEach {
        implementation project(path: ":${it.name}", configuration: "namedElements")
        include(project("${it.name}:"))
    }
}