build.gradle

plugins {
    id 'java'
    id 'application'
    id 'maven-publish'
}

group 'nl.rws.otl'
version '0.1-SNAPSHOT'
mainClassName = 'nl.rws.otl.git_tools.ReSerialize'
applicationName = 'ReSerialize'

repositories {
    mavenCentral()
}

project.ext.versions = [
        commonscli: '1.4',
        owlapi    : '5.1.14',
        lombok    : '1.18.12',
        slf4j     : '1.7.30',
        junit     : '4.13',
        junitrules: '1.19.0'
]

dependencies {
    implementation "commons-cli:commons-cli:${versions.commonscli}"
    implementation "net.sourceforge.owlapi:owlapi-apibinding:${versions.owlapi}"

    implementation "org.slf4j:slf4j-simple:${versions.slf4j}"
    compileOnly "org.projectlombok:lombok:${versions.lombok}"
    annotationProcessor "org.projectlombok:lombok:${versions.lombok}"

    testImplementation "junit:junit:${versions.junit}"
    testImplementation "com.github.stefanbirkner:system-rules:${versions.junitrules}"
}

jar {
    manifest {
        attributes(
                'Class-Path': configurations.compile.collect { it.getName() }.join(' '),
                'Main-Class': mainClassName
        )
    }
}

distributions {
    main {
        contents {
            from 'LICENSE'
        }
    }
}

publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/RWS-NL/airbim-otl-ReSerialize")
            credentials {
                username = System.getenv("USERNAME")
                password = System.getenv("TOKEN")
            }
        }
    }
    publications {
        mavenJava(MavenPublication) {
            from components.java
            artifact distZip
        }
    }
}