qwt.prf

# -*- mode: sh -*- ################################################
# Qwt Widget Library
# Copyright (C) 1997   Josef Wilgen
# Copyright (C) 2002   Uwe Rathmann
#
# This library is free software; you can redistribute it and/or
# modify it under the terms of the Qwt License, Version 1.0
###################################################################

QwtBuild = dll
QwtVersion = 5.2.2

unix {
    QwtBase    = /usr/local/qwt-$${QwtVersion}
    LIBS        += -L$${QwtBase}/lib -lqwt
}
win32 {
    QwtBase    = C:/Qwt-$${QwtVersion}

    contains(QwtBuild, dll) {
        DEFINES    += QWT_DLL

        msvc:LIBS  += $${QwtBase}/lib/qwt5.lib
        msvc.net:LIBS  += $${QwtBase}/lib/qwt5.lib
        msvc2005:LIBS += $${QwtBase}/lib/qwt5.lib
    } else {
        win32-msvc:LIBS  += $${QwtBase}/lib/qwt.lib
        win32-msvc.net:LIBS  += $${QwtBase}/lib/qwt.lib
        win32-msvc2005:LIBS += $${QwtBase}/lib/qwt.lib
    }
    g++:LIBS   += -L$${QwtBase}/lib -lqwt
}

INCLUDEPATH += $${QwtBase}/include