query_result.tex

\noindent No.001:
\begin{lstlisting}
# Describe Omnibus Law (UU Cipta Kerja)
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT * WHERE {
  <https://example.org/lex2kg/uu/2020/11> ?p ?o .
} 
ORDER BY ?p ?o
LIMIT 3
\end{lstlisting}


\noindent No.002:
\begin{lstlisting}
# Retrieve all articles (= pasal) of Omnibus Law
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?pasalVersion ?text WHERE {
  <https://example.org/lex2kg/uu/2020/11> o:pasal ?pasal .
  ?pasal o:versi ?pasalVersion .
  ?pasalVersion o:teks ?text .
} 
ORDER BY ?pasal ?text
LIMIT 3
\end{lstlisting}


\noindent No.003:
\begin{lstlisting}
# What is the textual content of Article (or Pasal) 2 Subsection (or Ayat) 1 of Omnibus Law?
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?x ?text WHERE {
  ?pasal o:bagianDari+ <https://example.org/lex2kg/uu/2020/11>.
  ?pasal o:nomor 2 .
  ?x o:bagianDari* ?pasal .
  ?x o:nomor 1 .
  ?x o:teks ?text .
}
ORDER BY ?x ?text
LIMIT 3
\end{lstlisting}


\noindent No.004:
\begin{lstlisting}
# Which are the articles of Chapter 2 (Bab 2) of Omnibus Law?
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?pasal ?text WHERE {
  ?bab o:bagianDari+ <https://example.org/lex2kg/uu/2020/11>.
  ?bab o:nomor 2 .
  ?pasal o:bagianDari+ ?bab .
  ?pasal o:versi ?pasalVersion .
  ?pasalVersion o:teks ?text
} 
ORDER BY ?pasal ?text
LIMIT 3
\end{lstlisting}


\noindent No.005:
\begin{lstlisting}
# Get subsections (= ayat) containing "kompensasi" and "buruh" that are added by Omnibus Law into other laws
PREFIX o: <https://example.org/lex2kg/ontology/>
PREFIX uu: <https://example.org/lex2kg/uu/>

SELECT ?ayat ?text WHERE {
  ?insertingPoint o:bagianDari+ <https://example.org/lex2kg/uu/2020/11> .
  ?insertingPoint o:menyisipkan ?insertedPasalVersion .
  ?ayat o:bagianDari+ ?insertedPasalVersion .
  ?ayat o:teks ?text
  FILTER REGEX(str(?text), "kompensasi")
  FILTER REGEX(str(?text), "buruh")
} LIMIT 3
\end{lstlisting}


\noindent No.006:
\begin{lstlisting}
# Retrieve components of Omnibus Law that insert (= menyisipkan) articles (= pasal) into Labor Law (UU Ketenagakerjaan) and show the textual content of the articles
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?insertingPoint ?insertedPasalVersion ?text WHERE {
  ?insertingPoint o:bagianDari+ <https://example.org/lex2kg/uu/2020/11>.
  ?insertingPoint o:menyisipkan ?insertedPasalVersion .
  ?insertedPasalVersion o:bagianDari+ <https://example.org/lex2kg/uu/2003/13> .
  ?insertedPasalVersion o:teks ?text .
}
ORDER BY ?insertingPoint ?insertedPasalVersion
LIMIT 3

\end{lstlisting}


\noindent No.007:
\begin{lstlisting}
# Get components of Omnibus Law that amend (= mengubah) articles in Labor Law and compare the textual content of the old vs. new articles
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?updatingPointt ?updatedPasal ?text ?version
WHERE {
  {
    SELECT ?pasal (MAX(?pasalVersion) as ?latestPasalVersion) WHERE {
      ?pasal o:bagianDari+ <https://example.org/lex2kg/uu/2020/11>.
      ?pasal o:versi ?pasalVersion .
    } GROUP BY ?pasal
  }
  ?updatingPointt o:bagianDari+ <https://example.org/lex2kg/uu/2020/11>.
  ?updatingPointt o:mengubah ?updatedPasalVersion .
  ?updatedPasal o:versi ?updatedPasalVersion .
  <https://example.org/lex2kg/uu/2003/13> o:pasal ?updatedPasal .
  ?updatedPasal o:versi ?allPasalVersion .
  ?allPasalVersion o:teks ?text .
  ?allPasalVersion o:tanggal ?version .
}
ORDER BY ?insertingPoint ?insertedPasal ?version ?text
LIMIT 3

\end{lstlisting}


\noindent No.008:
\begin{lstlisting}
# Give me components of Omnibus Law that remove (= menghapus) articles in Labor Law and show the textual content of the removed articles
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?deletingPoint ?deletedPasal ?version ?text WHERE {
  ?deletingPoint o:bagianDari+ <https://example.org/lex2kg/uu/2020/11>.
  ?deletingPoint o:menghapus ?deletedPasalVersion .
  ?deletedPasal o:versi ?deletedPasalVersion .
  <https://example.org/lex2kg/uu/2003/13> o:pasal ?deletedPasal .
  ?deletedPasal o:versi ?allPasalVersion .
  ?allPasalVersion o:teks ?text .
  ?allPasalVersion o:tanggal ?version .
}
LIMIT 3

\end{lstlisting}


\noindent No.009:
\begin{lstlisting}
# Which law has the most number of updates (= insertions/amendments/removals) by Omnibus Law? For that law, show the most recent version taking into account the updates by Omnibus Law!
PREFIX o: <https://example.org/lex2kg/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT ?law ?numOfUpdates ?pasal (MAX(?pasalVersion) as ?latestPasalVersion) WHERE {
  {
    SELECT ?law (COUNT(*) AS ?numOfUpdates) WHERE {
      ?point o:bagianDari+ <https://example.org/lex2kg/uu/2020/11> .
      { ?point o:mengubah ?amendedPasalVersion }
      UNION { ?point o:menyisipkan ?amendedPasalVersion }
      UNION { ?point o:menghapus ?amendedPasalVersion }
      ?amendedPasalVersion o:bagianDari+ ?law .
      ?law a o:Peraturan .
    } GROUP BY ?law
  }
  ?pasal o:bagianDari+ ?law .
  ?pasal o:versi ?pasalVersion .
}
GROUP BY ?law ?numOfUpdates ?pasal
ORDER BY DESC (?numOfUpdates)
LIMIT 3

\end{lstlisting}


\noindent No.010:
\begin{lstlisting}
# How many are insertions, amendments, and removals of other laws in Omnibus Law?
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?type (COUNT(*) AS ?jumlah) WHERE {
  {
    ?point o:bagianDari+ <https://example.org/lex2kg/uu/2020/11> .
    ?point o:menghapus ?pasal .
    BIND("menghapus" AS ?type)
  } UNION {
    ?point o:bagianDari+ <https://example.org/lex2kg/uu/2020/11> .
    ?point o:menyisipkan ?pasal .
    BIND("menyisipkan" AS ?type)
  } UNION {
    ?point o:bagianDari+ <https://example.org/lex2kg/uu/2020/11> .
    ?point o:mengubah ?pasal .
    BIND("mengubah" AS ?type)
  }
} GROUP BY ?type
LIMIT 3

\end{lstlisting}


\noindent No.011:
\begin{lstlisting}
# Get articles of Labor Law (UU Ketenagakerjaan) taking into account updates (= insertions/amendments/removals) from Omnibus Law (UU Cipta Kerja)
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?latestPasalVersion WHERE {
  {
    SELECT ?pasal (MAX(?pasalVersion) as ?latestPasalVersion) WHERE {
      ?pasal o:bagianDari+ <https://example.org/lex2kg/uu/2003/13>.
      ?pasal o:versi ?pasalVersion .
    } GROUP BY ?pasal
  }
}
ORDER BY ?latestPasalVersion
LIMIT 3
\end{lstlisting}


\noindent No.012:
\begin{lstlisting}
# Get articles of Omnibus Law that are not about updating (= insertions/amendments/removals) other laws
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT DISTINCT ?pasalVersion ?text WHERE {
  ?pasalVersion o:bagianDari+ <https://example.org/lex2kg/uu/2020/11>.
  ?pasalVersion o:teks ?text .
  FILTER NOT EXISTS {
    ?point o:bagianDari+ ?pasalVersion . 
    ?point a o:Point .
    { ?point o:mengubah ?amendedPasalVersion }
    UNION { ?point o:menyisipkan ?amendedPasalVersion } 
    UNION { ?point o:menghapus ?amendedPasalVersion }
  }
}
ORDER BY ?pasalVersion ?text
LIMIT 3
\end{lstlisting}


\noindent No.013:
\begin{lstlisting}
# Give me articles (= pasal) of Omnibus Law removing articles of laws legalized later than the year 2001
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT DISTINCT ?pasalVersion WHERE {
  ?point o:bagianDari+ <https://example.org/lex2kg/uu/2020/11>.
  ?point o:menghapus ?pasalVersion .
  ?pasalVersion o:bagianDari+ ?document .
  ?document o:disahkanPada ?legalizedDate
  FILTER(year(?legalizedDate) > 2001)
}
ORDER BY ?pasalVersion
LIMIT 3
\end{lstlisting}


\noindent No.014:
\begin{lstlisting}
# Retrieve all subsections inserted by Omnibus Law into other laws and *optionally* the citations occurring in those subsections
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?ayat ?text ?citation WHERE {
  ?insertingPoint o:bagianDari+ <https://example.org/lex2kg/uu/2020/11>.
  ?insertingPoint o:menyisipkan ?insertedPasalVersion .
  ?ayat o:bagianDari+ ?insertedPasalVersion .
  ?ayat o:teks ?text .
  ?ayat o:teks ?textRef .
  OPTIONAL {?textRef o:merujuk ?citation}
}
ORDER BY ?ayat ?text ?citation
LIMIT 3
\end{lstlisting}


\noindent No.015:
\begin{lstlisting}
# tampilkan legal document beserta yang ditimbangnya (menimbang)
PREFIX o: <https://example.org/lex2kg/ontology/>
PREFIX uu: <https://example.org/lex2kg/uu/>

SELECT DISTINCT ?penimbang ?ditimbang
WHERE {
  ?penimbang o:menimbang ?menimbang .
  ?menimbangText o:bagianDari* ?menimbang .
  ?menimbangText o:merujuk ?ditimbang .
  ?ditimbang a o:Peraturan
}
ORDER BY DESC(?penimbang) DESC(?ditimbang)
LIMIT 5
\end{lstlisting}


\noindent No.016:
\begin{lstlisting}
# select 10 legal document dengan pasal terbanyak
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?doc (COUNT(?pasal) as ?pasalCount)
WHERE {
  ?doc a o:Peraturan .
  ?doc o:pasal ?pasal .
}
GROUP BY ?doc
ORDER BY DESC(?pasalCount)
LIMIT 10

\end{lstlisting}


\noindent No.017:
\begin{lstlisting}
# tampilkan 10 dokumen yang pernah diamandemen
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT DISTINCT ?doc ?amenderDoc
WHERE {
  ?doc a o:Peraturan .
  ?pasal o:bagianDari ?doc .
  ?pasal o:versi ?pasalVersion .
  ?amender o:mengubah ?pasalVersion .
  ?amender o:bagianDari* ?amenderDoc .
  ?amenderDoc a o:Peraturan
}
ORDER BY ?doc ?amenderDoc
LIMIT 10
\end{lstlisting}


\noindent No.018:
\begin{lstlisting}
# tampilkan 10 tempat disahkan paling banyak
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?location (COUNT(?doc) as ?docCount)
WHERE {
  ?doc o:disahkanDi ?location
}
GROUP BY ?location
ORDER BY DESC (?docCount)
\end{lstlisting}


\noindent No.019:
\begin{lstlisting}
# tampilkan 10 dokumen paling banyak ditimbang

SELECT ?menimbangDoc (COUNT(?doc) as ?penimbangDocCount)
WHERE {
  ?doc o:menimbang ?menimbang .
  ?menimbangText o:bagianDari* ?menimbang ;
                 o:merujuk ?menimbangDoc .
  ?menimbangDoc a o:Peraturan .
}
GROUP BY ?menimbangDoc
ORDER BY DESC (?penimbangDocCount)
LIMIT 10

\end{lstlisting}


\noindent No.020:
\begin{lstlisting}
# tampilkan semua document yang melakukan amendment, dan banyaknya pasal yang diamendment oleh dokumen tersebut.
PREFIX o: <https://example.org/lex2kg/ontology/>
PREFIX uu: <https://example.org/lex2kg/uu/>

SELECT ?doc (COUNT(?point) as ?amendmentCount)
WHERE {
  ?doc a o:Peraturan .
  ?point o:bagianDari* ?doc .
  ?point o:mengubah|o:menyisipkan|o:menghapus ?pasalVersion .
}
GROUP BY (?doc)
ORDER BY DESC(?amendmentCount)
LIMIT 10
\end{lstlisting}


\noindent No.021:
\begin{lstlisting}
# Count triples about document structure
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT (COUNT (*) as ?countResult) WHERE {
  ?s
    o:nomor|
    o:judul|
    o:bab|
    o:bagian|
    o:paragraf|
    o:pasal|
    o:ayat|
    o:huruf|
    o:segmen|
    o:daftarBab|
    o:daftarBagian|
    o:daftarParagraf|
    o:daftarPasal|
    o:daftarAyat|
    o:daftarHuruf|
    o:tanggal|
    o:jenisVersi|
    o:versi|
    o:menimbang|
    o:mengingat|
    o:bagianDari
  ?o
} 
\end{lstlisting}


\noindent No.022:
\begin{lstlisting}
# Count triples about document metadata
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT (COUNT (*) as ?countResult) WHERE {
  ?s
    o:yurisdiksi|
    o:jenisPeraturan|
    o:tahun|
    o:bahasa|
    o:tentang|
    o:disahkanPada|
    o:disahkanDi|
    o:disahkanOleh|
    o:jabatanPengesah
  ?o
} 
\end{lstlisting}


\noindent No.023:
\begin{lstlisting}
# Count triples about document text
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT (COUNT (*) as ?countResult) WHERE {
  ?s
    o:teks
  ?o
} 
\end{lstlisting}


\noindent No.024:
\begin{lstlisting}
# Count triples about document citation
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT (COUNT (*) as ?countResult) WHERE {
  ?s o:merujuk ?o
} 

\end{lstlisting}


\noindent No.025:
\begin{lstlisting}
# Count triples about document change
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT (COUNT (*) as ?countResult) WHERE {
  ?s o:mengubah|o:menghapus|o:menyisipkan ?o
} 

\end{lstlisting}


\noindent No.026:
\begin{lstlisting}
# Count triples about class assignment
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT (COUNT (*) as ?countResult) WHERE {
  ?s a ?o
} 

\end{lstlisting}


\noindent No.027:
\begin{lstlisting}
# Tampilkan 5 peraturan dengan komponen terbanyak beserta jumlah komponennya.
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?peraturan (COUNT(?komponen) as ?komponenCount)
WHERE {
  ?peraturan a o:Peraturan .
  ?komponen o:bagianDari* ?peraturan .
}
GROUP BY ?peraturan
ORDER BY DESC (?komponenCount)
LIMIT 5

\end{lstlisting}


\noindent No.028:
\begin{lstlisting}
# Peraturan apa yang berlaku pada daerah Jakarta yang disahkan di tahun 2019?
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?peraturan ?yurisdiksi
WHERE {
  ?peraturan o:yurisdiksi ?yurisdiksi ;
             o:tahun 2019;
   FILTER (CONTAINS(LCASE(?yurisdiksi), 'jakarta')) .
}
\end{lstlisting}


\noindent No.029:
\begin{lstlisting}
# Apa relasi suatu peraturan dengan peraturan lain?
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT DISTINCT ?p1 ?relasi ?p2
WHERE {
  ?p1 a o:Peraturan .
  ?p2 a o:Peraturan .
  FILTER (?p1 != ?p2) .
  ?komponen o:bagianDari* ?p1 ;
            ?relasi ?p2 .

}
LIMIT 10
\end{lstlisting}


\noindent No.030:
\begin{lstlisting}
# Mana saja peraturan yang membahas tentang topik "Kerja" atau "Ketenagakerjaan" tapi bukan topik "Kerjasama" dan bukan "Pekerjaan"?
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?bab ?title
WHERE {
  ?doc a o:Peraturan .
  ?bab o:bagianDari* ?doc .
  ?bab a o:Bab .
  ?bab o:judul ?title.
  FILTER (CONTAINS(?title, "KERJA") || CONTAINS(?title, "KETENAGAKERJAAN"))
  FILTER (!CONTAINS(?title, "KERJASAMA"))
  FILTER (!CONTAINS(?title, "PEKERJAAN"))
}
ORDER BY ?bab ?title
LIMIT 10
\end{lstlisting}


\noindent No.031:
\begin{lstlisting}
# Apa isi dari Pasal 91 ayat (2) huruf b dari UU Cipta Kerja?
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?teksStr
WHERE {
  ?pasal o:bagianDari* <https://example.org/lex2kg/uu/2020/11> ;
         a o:Pasal ;
         o:nomor 91 .
  ?ayat o:bagianDari* ?pasal ;
         a o:Ayat ;
         o:nomor 2 .
  ?huruf o:bagianDari* ?ayat ;
         a o:Huruf ;
         o:nomor "b".
  ?teks o:bagianDari* ?huruf ;
        o:teks ?teksStr .
}
\end{lstlisting}


\noindent No.032:
\begin{lstlisting}
# Apa saja bab-bab yang terdapat pada UU Cipta Kerja?
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?bab ?judulBab
WHERE {
  ?bab o:judul ?judulBab;
       a o:Bab ;
       o:bagianDari* <https://example.org/lex2kg/uu/2020/11> .
}
ORDER BY ?bab
\end{lstlisting}


\noindent No.100:
\begin{lstlisting}
# tampilkan semua triple
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT * 
WHERE {
  ?s ?p ?o .
} 
ORDER BY ?s ?p ?o
LIMIT 3
\end{lstlisting}


\noindent No.101:
\begin{lstlisting}
# tampilkan 10 legal doc pertama
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT * 
WHERE {
  ?legalDoc a o:Peraturan
} 
ORDER BY ?legalDoc
LIMIT 10
\end{lstlisting}


\noindent No.102:
\begin{lstlisting}
# tampilkan semua UU yang disahkan setelah 10 Oktober 2019
PREFIX o: <https://example.org/lex2kg/ontology/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT *
WHERE {
  ?legalDoc o:disahkanPada ?date .
  FILTER ( ?date >= "2019-10-10"^^xsd:date )
}
ORDER BY ?legalDoc

\end{lstlisting}


\noindent No.103:
\begin{lstlisting}
# tampilkan 10 bab dengan substring "Kerja"
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT ?bab ?title
WHERE {
  ?doc a o:Peraturan .
  ?bab o:bagianDari* ?doc .
  ?bab a o:Bab .
  ?bab o:judul ?title.
  FILTER REGEX(str(?title), "KERJA")
}
ORDER BY ?bab ?title
LIMIT 10

\end{lstlisting}


\noindent No.104:
\begin{lstlisting}
# show raw text of UU 2007 No.26 Pasal 1 version 20201102
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT *
WHERE {
  <https://example.org/lex2kg/uu/2007/26/pasal/0001/versi/20201102> o:teks ?o
}
\end{lstlisting}


\noindent No.105:
\begin{lstlisting}
# Count triples with citation inside document
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT (COUNT (*) as ?countResult) WHERE {
  ?s o:merujuk ?o .
  ?s o:bagianDari* ?doc .
  ?o o:bagianDari* ?doc .
  ?doc a o:Peraturan .
} 


\end{lstlisting}


\noindent No.106:
\begin{lstlisting}
# Count triples with citation between document
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT (COUNT (*) as ?countResult) WHERE {
  ?s o:merujuk ?o .
  ?s (o:bagianDari|^o:mengingat|^o:menimbang)* ?sdoc .
  ?o o:bagianDari* ?odoc .
  ?sdoc a o:Peraturan .
  ?odoc a o:Peraturan .
  FILTER (?sdoc != ?odoc)
} 

\end{lstlisting}


\noindent No.107:
\begin{lstlisting}
# Count triples with citation to non existing law
PREFIX o: <https://example.org/lex2kg/ontology/>

SELECT (COUNT(*) as ?countResult) WHERE {
  {
    SELECT ?s ?o WHERE {
      ?s o:merujuk ?o .
    }
  } MINUS {
    SELECT ?s ?o WHERE {
      ?s o:merujuk ?o .
      ?s o:bagianDari* ?doc .
      ?o o:bagianDari* ?doc .
      ?doc a o:Peraturan .
    }
  } MINUS {
    SELECT ?s ?o WHERE {
      ?s o:merujuk ?o .
      ?s (o:bagianDari|^o:mengingat|^o:menimbang)* ?sdoc .
      ?o o:bagianDari* ?odoc .
      ?sdoc a o:Peraturan .
      ?odoc a o:Peraturan .
      FILTER (?sdoc != ?odoc)
    }
  }
} 

\end{lstlisting}