build.gradle

plugins {
    id 'fabric-loom' version '0.12.+'
    id 'maven-publish'
    id "com.modrinth.minotaur" version "2.+"
    id 'io.github.p03w.machete' version '1.0.7'
}

version = project.mod_version
group = project.maven_group

loom {
    accessWidenerPath = file("src/main/resources/purpeille.accesswidener")
}

repositories {
    maven {
        name = "Modrinth"
        url = "https://api.modrinth.com/maven"
        content {
            includeGroup "maven.modrinth"
        }
    }

    maven {
        name = "TerraformersMC"
        url = "https://maven.terraformersmc.com/"
    }

    maven { url "https://maven.shedaniel.me" }

    maven { url "https://maven.blamejared.com" }

    maven { url "https://jitpack.io" }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    // JIJ Dependencies
    modImplementation include("maven.modrinth:voidcrafting:${project.voidcrafting_version}")
    modImplementation include("maven.modrinth:cmods:${project.cmods_version}")
    modImplementation include("maven.modrinth:data-criteria:${project.data_criteria_version}")
    modImplementation include("com.github.emilyploszaj:step-height-entity-attribute:v${project.step_height_entity_attribute_version}")

    // EMI
    modImplementation "dev.emi:emi:${emi_version}", {
        transitive = false
    }

    // REI
    modCompileOnly "me.shedaniel:RoughlyEnoughItems-api-fabric:${project.rei_version}"

    // Patchouli
    modImplementation "vazkii.patchouli:Patchouli:${project.patchouli_version}", {
        exclude(group: "net.fabricmc.fabric-api")
    }

    // Data Attributes
    modImplementation "maven.modrinth:data-attributes:${project.data_attributes_version}"
}

processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

def targetJavaVersion = 17
tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        it.options.release = targetJavaVersion
    }
}

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
    archivesBaseName = project.archives_base_name
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}" }
    }
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}

modrinth {
    token = System.getenv("MODRINTH_TOKEN")
    projectId = "yoEkK5RL"
    versionName = project.version
    changelog = project.file("./modrinth/CHANGELOG.md").text
    uploadFile = remapJar
    gameVersions = [ "1.18.2" ]
    loaders = [ "fabric", "quilt" ]
    dependencies {
        required.project "P7dR8mSH"
        optional.project "E9dV0G8I"
        optional.project "X5JJNmDn"
        //optional.project "nU0bVIaL"
    }
}