forked from bonega/evil
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathevil-tests.el
7357 lines (7085 loc) · 243 KB
/
evil-tests.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;; evil-tests.el --- unit tests for Evil -*- coding: utf-8 -*-
;; Author: Vegard Øye <vegard_oye at hotmail.com>
;; Maintainer: Vegard Øye <vegard_oye at hotmail.com>
;; Version: 0.0.0
;;
;; This file is NOT part of GNU Emacs.
;;; License:
;; This file is part of Evil.
;;
;; Evil is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;;
;; Evil is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with Evil. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;; This file is for developers. It runs some tests on Evil.
;; To load it, run the Makefile target "make test" or add
;; the following lines to .emacs:
;;
;; (setq evil-tests-run nil) ; set to t to run tests immediately
;; (global-set-key [f12] 'evil-tests-run) ; hotkey
;; (require 'evil-tests)
;;
;; Loading this file enables profiling on Evil. The current numbers
;; can be displayed with `elp-results'. The Makefile target
;; "make profiler" shows profiling results in the terminal on the
;; basis of running all tests.
;;
;; To write a test, use `ert-deftest' and specify a :tags value of at
;; least '(evil). The test may inspect the output of functions given
;; certain input, or it may execute a key sequence in a temporary
;; buffer and investigate the results. For the latter approach, the
;; macro `evil-test-buffer' creates a temporary buffer in Normal
;; state. String descriptors initialize and match the contents of
;; the buffer:
;;
;; (ert-deftest evil-test ()
;; :tags '(evil)
;; (evil-test-buffer
;; "[T]his creates a test buffer." ; cursor on "T"
;; ("w") ; key sequence
;; "This [c]reates a test buffer."))) ; cursor moved to "c"
;;
;; The initial state, the cursor syntax, etc., can be changed
;; with keyword arguments. See the documentation string of
;; `evil-test-buffer' for more details.
;;
;; This file is NOT part of Evil itself.
(require 'elp)
(require 'ert)
(require 'evil)
;;; Code:
(defvar evil-tests-run nil
"*Run Evil tests.")
(defvar evil-tests-profiler nil
"*Profile Evil tests.")
(defun evil-tests-initialize (&optional tests profiler interactive)
(setq profiler (or profiler evil-tests-profiler))
(when (listp profiler)
(setq profiler (car profiler)))
(when profiler
(setq evil-tests-profiler t)
(setq profiler
(or (cdr (assq profiler
'((call . elp-sort-by-call-count)
(average . elp-sort-by-average-time)
(total . elp-sort-by-total-time))))))
(setq elp-sort-by-function (or profiler 'elp-sort-by-call-count))
(elp-instrument-package "evil"))
(if interactive
(if (y-or-n-p-with-timeout "Run tests? " 2 t)
(evil-tests-run tests interactive)
(message "You can run the tests at any time \
with `M-x evil-tests-run'"))
(evil-tests-run tests)))
(defun evil-tests-run (&optional tests interactive)
"Run Evil tests."
(interactive '(nil t))
(let ((elp-use-standard-output (not interactive)))
(setq tests
(or (null tests)
`(or ,@(mapcar #'(lambda (test)
(or (null test)
(and (memq test '(evil t)) t)
`(or (tag ,test)
,(format "^%s$" test))))
tests))))
(cond
(interactive
(ert-run-tests-interactively tests)
(when evil-tests-profiler
(elp-results)))
(evil-tests-profiler
(ert-run-tests-batch tests)
(elp-results))
(t
(ert-run-tests-batch-and-exit tests)))))
(defun evil-tests-profiler (&optional force)
"Profile Evil tests."
(when (or evil-tests-profiler force)
(setq evil-tests-profiler t)
(elp-instrument-package "evil")))
(defvar evil-test-point nil
"Marker for point.")
(make-variable-buffer-local 'evil-test-point)
(defvar evil-test-visual-start nil
"Marker for Visual beginning.")
(make-variable-buffer-local 'evil-test-visual-start)
(defvar evil-test-visual-end nil
"Marker for Visual end.")
(make-variable-buffer-local 'evil-test-visual-end)
(defmacro evil-test-buffer (&rest body)
"Execute FORMS in a temporary buffer.
The following optional keywords specify the buffer's properties:
:state STATE The initial state, defaults to `normal'.
:visual SELECTION The Visual selection, defaults to `char'.
:point-start STRING String for matching beginning of point,
defaults to \"[\".
:point-end STRING String for matching end of point,
defaults to \"]\".
:visual-start STRING String for matching beginning of
Visual selection, defaults to \"<\".
:visual-end STRING String for matching end of
Visual selection, defaults to \">\".
Then follows one or more forms. If the first form is a string,
it is taken to be a buffer description as passed to
`evil-test-buffer-from-string', and initializes the buffer.
Subsequent string forms validate the buffer.
If a form is a list of strings or vectors, it is taken to be a
key sequence and is passed to `execute-kbd-macro'. Remaining
forms are evaluated as-is. If the form is \(error SYMBOL ...)
then the test fails unless an error of type SYMBOL is raised.
\(fn [[KEY VALUE]...] FORMS...)"
(declare (indent defun))
(let ((state 'normal)
arg key point-start point-end string
visual visual-start visual-end)
;; collect keywords
(while (keywordp (car-safe body))
(setq key (pop body)
arg (pop body))
(cond
((eq key :point-start)
(setq point-start (or arg "")))
((eq key :point-end)
(setq point-end (or arg "")))
((eq key :state)
(setq state arg))
((eq key :visual)
(setq visual arg))
((eq key :visual-start)
(setq visual-start (or arg "")))
((eq key :visual-end)
(setq visual-end (or arg "")))))
;; collect buffer initialization
(when (stringp (car-safe body))
(setq string (pop body)))
;; macro expansion
`(let ((buffer (evil-test-buffer-from-string
,string ',state
,point-start ,point-end
',visual ,visual-start ,visual-end))
(kill-ring kill-ring)
(kill-ring-yank-pointer kill-ring-yank-pointer)
x-select-enable-clipboard
message-log-max)
(unwind-protect
(save-window-excursion
(with-current-buffer buffer
;; necessary for keyboard macros to work
(switch-to-buffer-other-window (current-buffer))
(buffer-enable-undo)
;; parse remaining forms
,@(mapcar
#'(lambda (form)
(let (error-symbol)
(when (and (listp form)
(eq (car-safe form) 'error))
(setq error-symbol (car-safe (cdr-safe form))
form (cdr-safe (cdr-safe form))))
(let ((result
(cond
((stringp form)
`(evil-test-buffer-string
,form
',point-start ',point-end
',visual-start ',visual-end))
((or (stringp (car-safe form))
(vectorp (car-safe form))
(memq (car-safe (car-safe form))
'(kbd vconcat)))
;; we need to execute everything as a single
;; sequence for command loop hooks to work
`(execute-kbd-macro
(apply #'vconcat
(mapcar #'listify-key-sequence
(mapcar #'eval ',form)))))
((memq (car-safe form) '(kbd vconcat))
`(execute-kbd-macro ,form))
(t
form))))
(if error-symbol
`(should-error ,result :type ',error-symbol)
result))))
body)))
(and (buffer-name buffer)
(kill-buffer buffer))))))
(when (fboundp 'font-lock-add-keywords)
(font-lock-add-keywords 'emacs-lisp-mode
'(("(\\(evil-test-buffer\\)\\>"
1 font-lock-keyword-face))))
(defun evil-test-buffer-string
(string &optional point-start point-end visual-start visual-end)
"Validate the current buffer according to STRING.
If STRING contains an occurrence of POINT-START immediately
followed by POINT-END, that position is compared against point.
If STRING contains an occurrence of VISUAL-START followed by
VISUAL-END, those positions are compared against the Visual selection.
POINT-START and POINT-END default to [ and ].
VISUAL-START and VISUAL-END default to < and >."
(let ((actual-buffer (current-buffer))
(marker-buffer (evil-test-marker-buffer-from-string
string
point-start point-end
visual-start visual-end))
before-point after-point string selection)
(unwind-protect
(with-current-buffer marker-buffer
(setq string (buffer-string))
(when evil-test-point
(setq before-point (buffer-substring (point-min) evil-test-point)
after-point (buffer-substring evil-test-point (point-max))))
(when (and evil-test-visual-start evil-test-visual-end)
(setq selection (buffer-substring
evil-test-visual-start evil-test-visual-end)))
(with-current-buffer actual-buffer
(if (or before-point after-point)
(evil-test-text before-point after-point)
;; if the cursor isn't specified, just test the whole buffer
(save-excursion
(goto-char (point-min))
(evil-test-text nil string #'bobp #'eobp)))
(when selection
(evil-test-selection selection))))
(kill-buffer marker-buffer))))
(defun evil-test-buffer-from-string
(string &optional state point-start point-end
visual visual-start visual-end)
"Create a new buffer according to STRING.
If STRING contains an occurrence of POINT-START immediately
followed by POINT-END, then point is moved to that position.
If STRING contains an occurrence of VISUAL-START followed by
VISUAL-END, then a Visual selection is created with those boundaries.
POINT-START and POINT-END default to [ and ].
VISUAL-START and VISUAL-END default to < and >.
STATE is the initial state; it defaults to `normal'.
VISUAL is the Visual selection: it defaults to `char'."
(let ((type (evil-visual-type (or visual 'char)))
(buffer (evil-test-marker-buffer-from-string
string point-start point-end
visual-start visual-end)))
(with-current-buffer buffer
(prog1 buffer
(evil-change-state state)
;; let the buffer change its major mode without disabling Evil
(add-hook 'after-change-major-mode-hook #'evil-initialize)
(when (and (markerp evil-test-visual-start)
(markerp evil-test-visual-end))
(evil-visual-select
evil-test-visual-start evil-test-visual-end type)
(when evil-test-point
(goto-char evil-test-point)
(evil-visual-refresh)
(unless (and (= evil-visual-beginning
evil-test-visual-start)
(= evil-visual-end
evil-test-visual-end))
(evil-visual-select
evil-test-visual-start evil-test-visual-end type -1)
(goto-char evil-test-point)
(evil-visual-refresh))))
(when (markerp evil-test-point)
(goto-char evil-test-point))))))
(defun evil-test-marker-buffer-from-string
(string &optional point-start point-end visual-start visual-end)
"Create a new marker buffer according to STRING.
If STRING contains an occurrence of POINT-START immediately
followed by POINT-END, that position is stored in the
buffer-local variable `evil-test-point'. Similarly,
if STRING contains an occurrence of VISUAL-START followed by
VISUAL-END, those positions are stored in the variables
`evil-test-visual-beginning' and `evil-test-visual-end'.
POINT-START and POINT-END default to [ and ].
VISUAL-START and VISUAL-END default to < and >."
(let ((string (or string ""))
(point-start (regexp-quote
(if (characterp point-start)
(string point-start)
(or point-start "["))))
(point-end (regexp-quote
(if (characterp point-end)
(string point-end)
(or point-end "]"))))
(visual-start (regexp-quote
(if (characterp visual-start)
(string visual-start)
(or visual-start "<"))))
(visual-end (regexp-quote
(if (characterp visual-end)
(string visual-end)
(or visual-end ">")))))
(with-current-buffer (generate-new-buffer " *test*")
(prog1 (current-buffer)
(save-excursion
(insert string))
(save-excursion
(when (> (length point-start) 0)
(if (> (length point-end) 0)
(when (re-search-forward
(format "\\(%s\\)[^%s]?\\(%s\\)"
point-start point-end point-end) nil t)
(goto-char (match-beginning 0))
(delete-region (match-beginning 2) (match-end 2))
(delete-region (match-beginning 1) (match-end 1))
(setq evil-test-point
(move-marker (make-marker) (point))))
(when (re-search-forward point-start nil t)
(goto-char (match-beginning 0))
(delete-region (match-beginning 0) (match-end 0))
(setq evil-test-point
(move-marker (make-marker) (point)))))))
(save-excursion
(when (and (> (length visual-start) 0)
(> (length visual-end) 0))
(when (re-search-forward visual-start nil t)
(goto-char (match-beginning 0))
(delete-region (match-beginning 0) (match-end 0))
(setq evil-test-visual-start
(move-marker (make-marker) (point))))
(when (re-search-forward visual-end nil t)
(goto-char (match-beginning 0))
(delete-region (match-beginning 0) (match-end 0))
(setq evil-test-visual-end
(move-marker (make-marker) (point))))))))))
(defun evil-test-text
(before after &optional before-predicate after-predicate)
"Verify the text around point.
BEFORE is the expected text before point, and AFTER is
the text after point. BEFORE-PREDICATE is a predicate function
to execute at the beginning of the text, and AFTER-PREDICATE
is executed at the end."
(when before
(if (functionp before)
(setq before-predicate before
before nil)
(should (string= (buffer-substring
(max (point-min) (- (point) (length before)))
(point))
before))))
(when after
(if (functionp after)
(setq after-predicate after
after nil)
(should (string= (buffer-substring
(point)
(min (point-max) (+ (point) (length after))))
after))))
(when before-predicate
(ert-info ((format "Expect `%s' at the beginning" before-predicate))
(save-excursion
(backward-char (length before))
(should (funcall before-predicate)))))
(when after-predicate
(ert-info ((format "Expect `%s' at the end" after-predicate))
(save-excursion
(forward-char (length after))
(should (funcall after-predicate))))))
(defmacro evil-test-selection
(string &optional end-string before-predicate after-predicate)
"Verify that the Visual selection contains STRING."
(declare (indent defun))
`(progn
(save-excursion
(goto-char (or evil-visual-beginning (region-beginning)))
(evil-test-text nil (or ,string ,end-string) ,before-predicate))
(save-excursion
(goto-char (or evil-visual-end (region-end)))
(evil-test-text (or ,end-string ,string) nil nil ,after-predicate))))
(defmacro evil-test-region
(string &optional end-string before-predicate after-predicate)
"Verify that the region contains STRING."
(declare (indent defun))
`(progn
(save-excursion
(goto-char (region-beginning))
(evil-test-text nil (or ,string ,end-string) ,before-predicate))
(save-excursion
(goto-char (region-end))
(evil-test-text (or ,end-string ,string) nil nil ,after-predicate))))
(defmacro evil-test-overlay
(overlay string &optional end-string before-predicate after-predicate)
"Verify that OVERLAY contains STRING."
(declare (indent defun))
`(progn
(save-excursion
(goto-char (overlay-start ,overlay))
(evil-test-text nil (or ,string ,end-string) ,before-predicate))
(save-excursion
(goto-char (overlay-end ,overlay))
(evil-test-text (or ,end-string ,string) nil nil ,after-predicate))))
(defmacro evil-with-temp-file (file-var content &rest body)
"Create a temp file with CONTENT and bind its name to FILE-VAR within BODY.
FILE-VAR must be a symbol which contains the name of the
temporary file within the macro body. CONTENT is either a string
to be used as the content of the temporary file or a form to be
executed with the temporary file's buffer as \(current-buffer),
see `with-temp-file'. BODY contains the forms to be executed
while the temporary file exists. The temporary file is deleted at
the end of the execution of BODY."
(declare (indent 2)
(debug (symbolp form body)))
`(let ((,file-var (make-temp-name
(expand-file-name "evil-test" temporary-file-directory))))
(with-temp-file ,file-var
,(if (stringp content)
`(insert ,content)
content))
,@body
(delete-file ,file-var)))
;;; States
(defun evil-test-local-mode-enabled ()
"Verify that `evil-local-mode' is enabled properly"
(ert-info ("Set the mode variable to t")
(should (eq evil-local-mode t)))
(ert-info ("Refresh `emulation-mode-map-alist'")
(should (memq 'evil-mode-map-alist emulation-mode-map-alists)))
(ert-info ("Create a buffer-local value for `evil-mode-map-alist'")
(should (assq 'evil-mode-map-alist (buffer-local-variables))))
(ert-info ("Initialize buffer-local keymaps")
(should (assq 'evil-normal-state-local-map (buffer-local-variables)))
(should (keymapp evil-normal-state-local-map))
(should (assq 'evil-emacs-state-local-map (buffer-local-variables)))
(should (keymapp evil-emacs-state-local-map)))
(ert-info ("Don't add buffer-local entries to the default value")
(should-not (rassq evil-normal-state-local-map
(default-value 'evil-mode-map-alist)))
(should-not (rassq evil-emacs-state-local-map
(default-value 'evil-mode-map-alist)))))
(defun evil-test-local-mode-disabled ()
"Verify that `evil-local-mode' is disabled properly"
(ert-info ("Set the mode variable to nil")
(should-not evil-local-mode))
(ert-info ("Disable all states")
(evil-test-no-states)))
(defun evil-test-no-states ()
"Verify that all states are disabled"
(ert-info ("Set `evil-state' to nil")
(should-not evil-state))
(ert-info ("Disable all state keymaps")
(dolist (state (mapcar #'car evil-state-properties) t)
(should-not (evil-state-property state :mode t))
(should-not (memq (evil-state-property state :keymap t)
(current-active-maps)))
(should-not (evil-state-property state :local t))
(should-not (memq (evil-state-property state :local-keymap t)
(current-active-maps)))
(dolist (map (evil-state-auxiliary-keymaps state))
(should-not (memq map (current-active-maps)))))))
(ert-deftest evil-test-toggle-local-mode ()
"Toggle `evil-local-mode'"
:tags '(evil state)
(with-temp-buffer
(ert-info ("Enable `evil-local-mode'")
(evil-local-mode 1)
(evil-test-local-mode-enabled))
(ert-info ("Disable `evil-local-mode'")
(evil-local-mode -1)
(evil-test-local-mode-disabled))))
(defun evil-test-change-state (state)
"Change state to STATE and check keymaps"
(let (mode keymap local-mode local-keymap tag)
(evil-change-state state)
(setq mode (evil-state-property state :mode)
keymap (evil-state-property state :keymap t)
local-mode (evil-state-property state :local)
local-keymap (evil-state-property state :local-keymap t)
tag (evil-state-property state :tag t))
(ert-info ("Update `evil-state'")
(should (eq evil-state state)))
(ert-info ("Ensure `evil-local-mode' is enabled")
(evil-test-local-mode-enabled))
(ert-info ("Enable state modes")
(should (symbol-value mode))
(should (symbol-value local-mode)))
(ert-info ("Push state keymaps to the top")
(evil-test-state-keymaps state))
(ert-info ("Refresh mode line tag")
(should (equal evil-mode-line-tag tag)))))
(defun evil-test-state-keymaps (state)
"Verify that STATE's keymaps are pushed to the top"
(let ((actual (evil-state-keymaps state))
(expected `((evil-esc-mode . ,evil-esc-map)
(,(evil-state-property state :local)
. , (evil-state-property state :local-keymap t))
(,(evil-state-property state :mode)
. ,(evil-state-property state :keymap t)))))
;; additional keymaps inherited with :enable
(cond
((eq state 'operator)
(setq expected
`((evil-esc-mode . ,evil-esc-map)
(evil-operator-shortcut-mode
. ,evil-operator-shortcut-map)
(evil-operator-state-local-minor-mode
. ,evil-operator-state-local-map)
(evil-operator-state-minor-mode
. ,evil-operator-state-map)
(evil-motion-state-local-minor-mode
. ,evil-motion-state-local-map)
(evil-motion-state-minor-mode
. ,evil-motion-state-map)
(evil-normal-state-local-minor-mode
. ,evil-normal-state-local-map)
(evil-normal-state-minor-mode
. ,evil-normal-state-map)))))
(let ((actual (butlast actual (- (length actual)
(length expected)))))
(should (equal actual expected))
(dolist (map actual)
(setq map (cdr-safe map))
(should (keymapp map))
;; Emacs state disables `evil-esc-map'
(unless (and (eq state 'emacs) (eq map evil-esc-map))
(should (memq map (current-active-maps))))))))
(ert-deftest evil-test-exit-normal-state ()
"Enter Normal state and then disable all states"
:tags '(evil state)
(with-temp-buffer
(evil-test-change-state 'normal)
(evil-normal-state -1)
(evil-test-no-states)))
(ert-deftest evil-test-change-states ()
"Change between Normal state, Emacs state and Operator-Pending state"
:tags '(evil state)
(with-temp-buffer
(evil-test-change-state 'normal)
(evil-test-change-state 'emacs)
(evil-test-change-state 'normal)
(evil-test-change-state 'operator)
(evil-test-change-state 'normal)
(evil-test-change-state 'emacs)
(evil-test-change-state 'replace)
(evil-test-change-state 'normal)))
(ert-deftest evil-test-change-to-previous-state ()
"Change to some state and back."
:tags '(evil state)
(with-temp-buffer
(evil-test-change-state 'normal)
(evil-test-change-state 'visual)
(evil-test-change-state 'emacs)
(evil-change-to-previous-state)
(should (eq evil-state 'visual))
(evil-change-to-previous-state)
(should (eq evil-state 'normal))))
(ert-deftest evil-test-enter-normal-state-disabled ()
"Enter Normal state even if `evil-local-mode' is disabled"
:tags '(evil state)
(with-temp-buffer
(evil-local-mode -1)
(evil-test-local-mode-disabled)
(evil-test-change-state 'normal)))
(defun evil-test-suppress-keymap (state)
"Verify that `self-insert-command' is suppressed in STATE"
(evil-test-buffer
";; This buffer is for notes."
(evil-test-change-state state)
;; TODO: this should be done better
(ert-info ("Disable the state's own keymaps so that the
suppression keymap comes first")
(setq evil-operator-state-minor-mode nil
evil-operator-state-local-minor-mode nil))
(should (eq (key-binding "Q") #'undefined))
(ert-info ("Don't insert text")
;; may or may not signal an error, depending on batch mode
(condition-case nil
(execute-kbd-macro "QQQ")
(error nil))
(should (string= (buffer-substring 1 4) ";; ")))))
(ert-deftest evil-test-emacs-state-suppress-keymap ()
"`self-insert-command' works in Emacs state"
:tags '(evil state)
(should-error (evil-test-suppress-keymap 'emacs)))
(ert-deftest evil-test-normal-state-suppress-keymap ()
"No `self-insert-command' in Normal state"
:tags '(evil state)
(evil-test-suppress-keymap 'normal))
(ert-deftest evil-test-operator-state-suppress-keymap ()
"Operator-Pending state should inherit suppression
of `self-insert-command' from Normal state"
:tags '(evil state)
(evil-test-suppress-keymap 'operator))
(ert-deftest evil-test-operator-state-shortcut-keymap ()
"Enable shortcut keymap in Operator-Pending state"
:tags '(evil state)
(evil-test-buffer
(ert-info ("Activate `evil-operator-shortcut-map' in \
Operator-Pending state")
(evil-test-change-state 'operator)
(should (rassq evil-operator-shortcut-map
(evil-state-keymaps 'operator)))
(should (keymapp evil-operator-shortcut-map))
(should evil-operator-shortcut-mode)
(should (memq evil-operator-shortcut-map
(current-active-maps))))
(ert-info ("Deactivate `evil-operator-shortcut-map' \
outside Operator-Pending state")
(evil-test-change-state 'emacs)
(should-not evil-operator-shortcut-mode)
(should-not (memq evil-operator-shortcut-map
(current-active-maps))))
(ert-info ("Reset `evil-operator-shortcut-map' \
when entering Operator-Pending state")
(define-key evil-operator-shortcut-map "f" 'foo)
(should (eq (lookup-key evil-operator-shortcut-map "f")
'foo))
(evil-test-change-state 'operator)
(should-not (eq (lookup-key evil-operator-shortcut-map "f")
'foo)))
(ert-info ("Reset `evil-operator-shortcut-map' \
when exiting Operator-Pending state")
(define-key evil-operator-shortcut-map "b" 'bar)
(should (eq (lookup-key evil-operator-shortcut-map "b")
'bar))
(evil-test-change-state 'emacs)
(should-not (eq (lookup-key evil-operator-shortcut-map "b")
'bar)))))
(ert-deftest evil-test-auxiliary-maps ()
"Test auxiliary keymaps"
:tags '(evil state)
(let ((map (make-sparse-keymap)) aux)
(ert-info ("Create a new auxiliary keymap")
(evil-define-key 'normal map "f" 'foo)
(setq aux (evil-get-auxiliary-keymap map 'normal))
(should (evil-auxiliary-keymap-p aux))
(should (eq (lookup-key aux "f") 'foo)))
(ert-info ("Add to auxiliary keymap")
(evil-define-key 'normal map "b" 'bar)
(should (eq (lookup-key aux "f") 'foo))
(should (eq (lookup-key aux "b") 'bar)))))
;;; Type system
(ert-deftest evil-test-exclusive-type ()
"Expand and contract the `line' type"
:tags '(evil type)
(evil-test-buffer
";; This buffer is for notes you don't want to save.
;; If you want to create a file, visit that file with C-x C-f,
;; then enter the text in that file's own buffer."
(let* ((first-line 1)
(second-line (progn
(forward-line)
(point)))
(third-line (progn
(forward-line)
(point))))
(ert-info ("Return the beginning and end unchanged \
if they are the same")
(should (equal (evil-normalize 1 1 'exclusive)
(list 1 1 'exclusive))))
(ert-info ("expand to `inclusive' if the end position \
is at the beginning of a line")
(should (equal (evil-normalize (1+ first-line) second-line 'exclusive)
(list (1+ first-line) (1- second-line) 'inclusive
:expanded t))))
(ert-info ("expand to `line' if both the beginning and end \
are at the beginning of a line")
(should (equal (evil-normalize first-line second-line 'exclusive)
(list first-line second-line 'line
:expanded t))))
(ert-info ("Measure as the strict difference between the end \
and the beginning")
(should (string= (evil-describe 1 1 'exclusive)
"0 characters"))
(should (string= (evil-describe 1 2 'exclusive)
"1 character"))
(should (string= (evil-describe 5 2 'exclusive)
"3 characters"))))))
(ert-deftest evil-test-inclusive-type ()
"Expand and contract the `inclusive' type"
:tags '(evil type)
(evil-test-buffer
";; This buffer is for notes you don't want to save.
;; If you want to create a file, visit that file with C-x C-f,
;; then enter the text in that file's own buffer."
(ert-info ("Include the ending character")
(should (equal (evil-expand 1 1 'inclusive)
'(1 2 inclusive :expanded t))))
(ert-info ("Don't mind if positions are in wrong order")
(should (equal (evil-expand 5 2 'inclusive)
'(2 6 inclusive :expanded t))))
(ert-info ("Exclude the ending character when contracting")
(should (equal (evil-contract 1 2 'inclusive)
'(1 1 inclusive :expanded nil))))
(ert-info ("Don't mind positions' order when contracting")
(should (equal (evil-contract 6 2 'inclusive)
'(2 5 inclusive :expanded nil))))
(ert-info ("Measure as one more than the difference")
(should (string= (evil-describe 1 1 'inclusive)
"1 character"))
(should (string= (evil-describe 5 2 'inclusive)
"4 characters")))))
(ert-deftest evil-test-line-type ()
"Expand the `line' type"
:tags '(evil type)
(evil-test-buffer
";; This buffer is for notes you don't want to save.
;; If you want to create a file, visit that file with C-x C-f,
;; then enter the text in that file's own buffer."
(let* ((first-line 1)
(second-line (progn
(forward-line)
(point)))
(third-line (progn
(forward-line)
(point))))
(ert-info ("Expand to the whole first line")
(should (equal (evil-expand first-line first-line 'line)
(list first-line second-line 'line :expanded t)))
(should (string= (evil-describe first-line first-line 'line)
"1 line")))
(ert-info ("Expand to the two first lines")
(should (equal (evil-expand first-line second-line 'line)
(list first-line third-line 'line :expanded t)))
(should (string= (evil-describe first-line second-line 'line)
"2 lines"))))))
(ert-deftest evil-test-block-type ()
"Expand and contract the `block' type"
:tags '(evil type)
(evil-test-buffer
";; This buffer is for notes you don't want to save.
;; If you want to create a file, visit that file with C-x C-f,
;; then enter the text in that file's own buffer."
(let* ((first-line 1)
(second-line (progn
(forward-line)
(point)))
(third-line (progn
(forward-line)
(point))))
(ert-info ("Expand to a 1x1 block")
(should (equal (evil-expand 1 1 'block)
(list 1 2 'block :expanded t)))
(should (string= (evil-describe 1 1 'block)
"1 row and 1 column")))
(ert-info ("Expand to a 2x1 block")
(should (equal (evil-expand first-line second-line 'block)
(list first-line (1+ second-line) 'block :expanded t)))
(should (string= (evil-describe first-line second-line 'block)
"2 rows and 1 column")))
(ert-info ("Expand to a 3x2 block")
(should (equal (evil-expand first-line (1+ third-line) 'block)
(list first-line (1+ (1+ third-line))
'block :expanded t)))
(should (string= (evil-describe first-line (1+ third-line) 'block)
"3 rows and 2 columns")))
(ert-info ("Contract to a 0x0 rectangle")
(should (equal (evil-contract 1 2 'block)
(list 1 1 'block :expanded nil))))
(ert-info ("Contract to a 2x0 rectangle")
(should (equal (evil-contract first-line (1+ second-line) 'block)
(list first-line second-line 'block :expanded nil))))
(ert-info ("Contract to a 3x1 rectangle")
(should (equal (evil-contract first-line (1+ (1+ third-line)) 'block)
(list first-line (1+ third-line)
'block :expanded nil)))))))
(ert-deftest evil-test-type-transform ()
"Test `evil-transform'"
:tags '(evil type)
(evil-test-buffer
";; This buffer is for notes you don't want to save.
;; If you want to create a file, visit that file with C-x C-f,
;; then enter the text in that file's own buffer."
(ert-info ("Return positions unchanged when passed nil \
for TYPE or TRANSFORM")
(should (equal (evil-transform nil 1 2 'block)
'(1 2 block)))
(should (equal (evil-transform :expand 1 2 nil)
'(1 2)))
(should (equal (evil-transform nil 1 2 nil)
'(1 2))))
(ert-info ("Accept markers, but return positions")
(should (equal (evil-transform :expand
(move-marker (make-marker) 1) 1
'inclusive)
'(1 2 inclusive :expanded t)))
(should (equal (evil-transform nil (move-marker (make-marker) 1) 2
nil)
'(1 2))))))
(ert-deftest evil-test-type-modifiers ()
"Test type modifiers like \"dv}\""
:tags '(evil type)
(ert-info ("Change `inclusive' motions to `exclusive'")
(evil-test-buffer
"[A]bove some line"
("dve")
"[e] some line"))
(ert-info ("Change `exclusive' motions to `inclusive'")
(evil-test-buffer
"Above [s]ome line
Below some empty line"
("dv}")
"Above[ ]
Below some empty line"))
(ert-info ("Change type to `line'")
(evil-test-buffer
"Above [s]ome line
Below some empty line"
("dV}")
"[B]elow some empty line")))
;;; Insertion
(ert-deftest evil-test-insert ()
"Test `evil-insert'"
:tags '(evil insert)
(evil-test-buffer
";; [T]his buffer is for notes you don't want to save"
("ievil rulz " [escape])
";; evil rulz[ ]This buffer is for notes you don't want to save"))
(ert-deftest evil-test-append ()
"Test `evil-append'"
:tags '(evil insert)
(evil-test-buffer
";; [T]his buffer is for notes you don't want to save"
("aevil rulz " [escape])
";; Tevil rulz[ ]his buffer is for notes you don't want to save"))
(ert-deftest evil-test-open-above ()
"Test `evil-open-above'"
:tags '(evil insert)
(evil-test-buffer
";; This buffer is for notes you don't want to save,
\[;]; and for Lisp evaluation."
("Oabc\ndef" [escape])
";; This buffer is for notes you don't want to save,
abc
de[f]
;; and for Lisp evaluation.")
(ert-info ("Open empty line")
(evil-test-buffer
"(let (var)\n [t]est)\n"
(emacs-lisp-mode)
("O" [escape])
"(let (var)\n[\n] test)\n"))
(ert-info ("Open non-empty line")
(evil-test-buffer
"(let (var)\n [t]est)\n"
(emacs-lisp-mode)
("Odo-it" [escape])
"(let (var)\n do-i[t]\n test)\n")))
(ert-deftest evil-test-open-below ()
"Test `evil-open-below'"
:tags '(evil insert)
(evil-test-buffer
"[;]; This buffer is for notes you don't want to save,
;; and for Lisp evaluation."
("oabc\ndef" [escape])
";; This buffer is for notes you don't want to save,
abc
de[f]
;; and for Lisp evaluation.")
(ert-info ("Open empty line")
(evil-test-buffer
"[(]let (var)\n test)\n"
(emacs-lisp-mode)
("o" [escape])
"(let (var)\n[\n] test)\n"))
(ert-info ("Open non-empty line")
(evil-test-buffer
"[(]let (var)\n test)\n"
(emacs-lisp-mode)
("odo-it" [escape])
"(let (var)\n do-i[t]\n test)\n")))
(ert-deftest evil-test-open-below-folded ()
"Test `evil-open-below' on folded lines"
:tags '(evil insert)
(evil-test-buffer
"[l]ine1\n\n(let ()\n var)\n\nlast line\n"
(emacs-lisp-mode)
(hs-minor-mode 1)
("zm2joABC" [escape])
"line1\n\n(let ()\n var)\nAB[C]\n\nlast line\n"))
(ert-deftest evil-test-insert-line ()
"Test `evil-insert-line'"
:tags '(evil insert)
(evil-test-buffer
";; [T]his buffer is for notes you don't want to save"
("Ievil rulz " [escape])
"evil rulz[ ];; This buffer is for notes you don't want to save"))
(ert-deftest evil-test-append-line ()
"Test `evil-append-line'"
:tags '(evil insert)
(evil-test-buffer
";; [T]his buffer is for notes you don't want to save"
("Aevil rulz " [escape])
";; This buffer is for notes you don't want to saveevil rulz[ ]"))
(ert-deftest evil-test-insert-digraph ()
"Test `evil-insert-digraph'"
:tags '(evil insert)
(ert-info ("Predefined digraph")
(evil-test-buffer
("i\C-kae")
"æ[]"))
(ert-info ("Custom digraph")
(let ((evil-digraphs-table-user '(((?a ?o) . ?å))))
(evil-test-buffer
("i\C-kao")
"å[]"))))
;;; Repeat system
(ert-deftest evil-test-normalize-repeat-info ()
"Test `evil-normalize-repeat-info'"
:tags '(evil repeat)
(ert-info ("Single array")
(should (equal (evil-normalize-repeat-info
'("abc"))
'([?a ?b ?c])))
(should (equal (evil-normalize-repeat-info
'("\M-f"))
(list (kbd "M-f")))))
(ert-info ("Single symbol")
(should (equal (evil-normalize-repeat-info