build.gradle

buildscript {
    repositories {
        mavenLocal()
        jcenter()
        maven { url 'https://maven.google.com' }
        maven { url 'https://maven.fabric.io/public' }
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.1.1'
        classpath 'io.fabric.tools:gradle:1.25.2'
        classpath 'com.squareup.sqldelight:gradle-plugin:0.6.1'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:1.2.31"
    }
}

plugins {
    id 'com.github.ben-manes.versions' version '0.17.0'
}

allprojects {
    repositories {
        mavenLocal()
        jcenter()
        maven { url "https://maven.google.com" }
        maven { url 'https://maven.fabric.io/public' }
    }
}

apply from: 'dependencies.gradle'

subprojects {
    apply plugin: 'checkstyle'

    dependencies {
        checkstyle libs.checkstyle
    }

    afterEvaluate {project ->
        if (project.name.contains('farebot')) {
            check.dependsOn 'checkstyle'
            task checkstyle(type: Checkstyle) {
                configFile file('config/checkstyle/checkstyle.xml')
                source 'src'
                include '**/*.java'
                exclude '**/gen/**'
                exclude '**/IOUtils.java'
                exclude '**/Charsets.java'
                classpath = files()
            }
            checkstyle {
                ignoreFailures = false
            }
        }
        if (project.hasProperty("android")) {
            android {
                compileSdkVersion vers.compileSdkVersion
                buildToolsVersion vers.buildToolsVersion

                defaultConfig {
                    minSdkVersion vers.minSdkVersion
                    targetSdkVersion vers.targetSdkVersion
                }

                compileOptions {
                    sourceCompatibility JavaVersion.VERSION_1_7
                    targetCompatibility JavaVersion.VERSION_1_7
                }

                lintOptions {
                    abortOnError true
                    disable 'InvalidPackage','MissingTranslation'
                }

                dexOptions {
                    dexInProcess = true
                }
            }
        }
    }
}

dependencyUpdates.resolutionStrategy = {
    componentSelection { rules ->
        rules.all { ComponentSelection selection ->
            boolean rejected = ['alpha', 'beta', 'rc', 'cr', 'm'].any { qualifier ->
                selection.candidate.version ==~ /(?i).*[.-]${qualifier}[.\d-]*/
            }
            if (rejected) {
                selection.reject('Release candidate')
            }
        }
    }
}

configurations {
    ktlint
}

dependencies {
    ktlint 'com.github.shyiko:ktlint:0.21.0'
}

task lintKotlin(type: JavaExec) {
    main = "com.github.shyiko.ktlint.Main"
    classpath = configurations.ktlint
    args "*/src/**/*.kt"
}