build.gradle

buildscript {
    repositories {
        mavenLocal()
        jcenter()
    }
    dependencies {
    }   
}

plugins {
    id "com.jfrog.bintray" version "1.2"
}

apply plugin: 'groovy'
apply plugin: 'idea'
apply plugin: 'maven-publish'

group = 'com.bertramlabs.plugins'
version = '0.8.1'
ext.isReleaseVersion = !version.endsWith("SNAPSHOT")
targetCompatibility = '1.7'
sourceCompatibility = '1.7'



repositories {
    jcenter()
    mavenLocal()
    mavenCentral()
}


configurations {
    provided
}
 
sourceSets {
    main {
        compileClasspath += configurations.provided
    }
}

dependencies {
	compile 'org.codehaus.groovy:groovy-all:2.4.2'
    testCompile "org.spockframework:spock-core:0.7-groovy-2.0"
    compile 'org.apache.httpcomponents:httpcore:4.2'
    compile 'org.apache.httpcomponents:httpclient:4.2'
    compile 'javax.websocket:javax.websocket-client-api:1.1'
    compile 'org.glassfish.tyrus:tyrus-client:1.11'
    compile 'org.glassfish.tyrus:tyrus-container-grizzly-client:1.11'
}

publishing {
    publications {
        maven(MavenPublication) {
            artifactId 'gstomp-client'
            pom.withXml {
                asNode().children().last() + {
                    resolveStrategy = Closure.DELEGATE_FIRST
                    name 'gstomp-client'
                    description 'Provides a CLIENT STOMP Api for Groovy'
                    url 'https://github.com/bertramdev/gstomp-client'
                    scm {
                        url 'https://github.com/bertramdev/gstomp-client'
                        connection 'scm:https://bertramdev@github.com/bertramdev/gstomp-client.git'
                        developerConnection 'scm:git://github.com/bertramdev/gstomp-client.git'
                    }
                    licenses {
                        license {
                            name 'The Apache Software License, Version 2.0'
                            url 'http://www.apache.org/license/LICENSE-2.0.txt'
                            distribution 'repo'
                        }
                    }
                    developers {
                        developer {
                            id 'davydotcom'
                            name 'David Estes'
                            email 'davydotcom@gmail.com'
                        }
                    }
                }
            }
            from components.java
            artifact sourcesJar
            artifact javadocJar
        }
    }
}

configurations {
    provided
}
 


//Define bintrayUser and bintrayKey in ~/.gradle/gradle.properties
bintray {
    user = project.hasProperty('bintrayUser') ? bintrayUser : 'anonymous'
    key = project.hasProperty('bintrayKey') ? bintrayKey : 'key here'
    publications = ['maven']
    pkg {
        repo = 'gstomp'
        userOrg = 'bertramlabs'
        name = 'gstomp-client'
        licenses = ['Apache-2.0']
    }
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from 'build/docs/javadoc'
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task(console, dependsOn: 'classes', type: JavaExec) {
  main = 'groovy.ui.Console'
  classpath = sourceSets.main.runtimeClasspath
}

test {
    testLogging {
        exceptionFormat = 'full'
        showStandardStreams = true
    }
}


bintrayUpload.dependsOn build, sourcesJar, javadocJar