build.gradle

buildscript {
	repositories {
		jcenter()
	}
	dependencies {
		// For dependency license report
		classpath "com.smokejumperit.gradle.license:Gradle-License-Report:0.0.2"
	}
}

plugins {
  id "java"
  id "maven-publish"
  id "eclipse"
  id "idea"
  id "com.jfrog.bintray" version "1.5"
}

// gradle dependencyLicenseReport to generate your report in build/reports/dependency-license
apply plugin:'license-report'

sourceCompatibility = "1.7"
targetCompatibility = "1.7"

repositories {
  jcenter()
  mavenLocal()
}

dependencies {
  compile 'com.marklogic:ml-javaclient-util:' + mlJavaclientUtilVersion
  compile 'jaxen:jaxen:1.1.6'
  compile 'org.apache.httpcomponents:httpclient:4.3.5'
  compile 'org.springframework:spring-web:4.3.5.RELEASE'

  testCompile ('com.marklogic:ml-junit:2.6.0') {
    exclude module: "ml-javaclient-util"
  }

  testCompile('commons-io:commons-io:2.5')
}

// This ensures that Gradle includes in the published jar any non-java files under src/main/java
sourceSets.main.resources.srcDir 'src/main/java'

task sourcesJar(type: Jar, dependsOn: classes) {
  classifier 'sources'
  from sourceSets.main.allJava
}

javadoc.destinationDir = file(javadocsDir + "/" + project.name)
javadoc.failOnError = false

publishing {
  publications {
    mainJava(MavenPublication) {
      from components.java
    }
    sourcesJava(MavenPublication) {
      from components.java
      artifact sourcesJar
    }
  }
}

if (project.hasProperty("myBintrayUser")) {
  bintray {
    user = myBintrayUser
    key = myBintrayKey
    publications = ['mainJava', 'sourcesJava']
    pkg {
      repo = 'maven'
      name = project.name
      licenses = ['Apache-2.0']
      vcsUrl = 'https://github.com/rjrudin/' + project.name + '.git'
      version {
        name = project.version
        released = new Date()
      }
    }
  }
}