build.gradle

plugins {
    id 'java'
    id 'idea'
    id "com.github.johnrengelman.shadow" version "7.1.2"
}

group = 'me.byteful.plugin.pictureads'
version = '1.0.4'

repositories {
    mavenCentral()
    maven {
        name = 'spigotmc-repo'
        url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/'
    }
    maven {
        name = 'sonatype'
        url = 'https://oss.sonatype.org/content/groups/public/'
    }
    maven { url 'https://redempt.dev' }
}

dependencies {
    compileOnly 'org.spigotmc:spigot-api:1.13.2-R0.1-SNAPSHOT'
    implementation 'com.github.Redempt:RedCommands:1.5.7'
    implementation 'commons-validator:commons-validator:1.7'
    implementation 'net.coobird:thumbnailator:0.4.17'
}

def targetJavaVersion = 8
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release = targetJavaVersion
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('*.yml') {
        expand props
    }
}

shadowJar {
    minimize()
    archiveBaseName.set("PictureAds")
    archiveClassifier.set("")

    relocate 'redempt', 'me.byteful.plugin.pictureads.libs.redempt'
    relocate 'org.apache.commons.validator', 'me.byteful.plugin.pictureads.libs.validator'
}