From 128af8b8d967931e562644a230020bdf7b505508 Mon Sep 17 00:00:00 2001
From: Philippe Coval <rzr@users.sf.net>
Date: Sun, 20 Dec 2020 22:48:06 +0100
Subject: [PATCH] pinball: Add version 0.3.20201218

Emilia Pinball libre pinball simulator for GNU/Linux

This SDL1.2 game requieres desktop OpenGL,
so a decent GPU support would help
Next version will use SDL-2 and could use wayland only.
Alternative renderers are also welcome (GLES, Vulkan etc).

Extra notes:

- packaging is aligned to Debian
- autotools-brokensep is needed because it did not build out of sources,
- la files should be preserved for loader
- dev package will be needed to build other tables

Origin: https://github.com/CrossStream/meta-games/tree/sandbox/rzr/review/master
Bug: https://github.com/cazfi/meta-games/issues/51
Bug-pinball: https://github.com/adoptware/pinball/issues/9
Forwarded: https://github.com/cazfi/meta-games/pull/52
Relate-to: https://purl.org/rzr/pinball
See-Also: https://patchwork.openembedded.org/patch/114267/
Change-Id: Ibf66c90b8697e0e5322c35cadb298fbf3528458a
Signed-off-by: Philippe Coval <rzr@users.sf.net>
---
 recipes-games/pinball/pinball_0.3.20201218.bb | 72 +++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 recipes-games/pinball/pinball_0.3.20201218.bb

diff --git a/recipes-games/pinball/pinball_0.3.20201218.bb b/recipes-games/pinball/pinball_0.3.20201218.bb
new file mode 100644
index 0000000..7bb5071
--- /dev/null
+++ b/recipes-games/pinball/pinball_0.3.20201218.bb
@@ -0,0 +1,72 @@
+DESCRIPTION = "Emilia Pinball Simulator"
+HOMEPAGE = "http://pinball.sf.net/"
+SECTION = "games"
+LICENSE = "GPLv2 & CC0-1.0"
+LIC_FILES_CHKSUM = " \
+    file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+    file://debian/copyright;md5=ef0d1a481815636a22c1d73b1233d9c0 \
+"
+
+SRC_URI = "git://github.com/adoptware/pinball.git;protocol=https;nobranch=1"
+SRCREV = "fdb2fa3ebea8a1c20e1a50a54c5df292d342b531"
+
+S = "${WORKDIR}/git"
+
+DEPENDS += "libsdl libsdl-image libsdl-mixer \
+    libx11 \
+    virtual/libgl \
+    libglu \
+    alsa-lib \
+    libvorbis \
+    tiff \
+"
+
+inherit features_check pkgconfig autotools-brokensep
+
+REQUIRED_DISTRO_FEATURES = "opengl x11"
+
+PACKAGECONFIG ??= "sdl sdl-image sdl-mixer"
+PACKAGECONFIG[sdl] = "--enable-sdl,--disable-sdl,libsdl"
+PACKAGECONFIG[sdl-image] = "--enable-sdl-image,--disable-sdl-image,libsdl-image"
+PACKAGECONFIG[sdl-mixer] = "--enable-sdl-mixer,--disable-sdl-mixer,libsdl-mixer"
+
+PACKAGES = "${PN}"
+PACKAGES += "${PN}-dev"
+PACKAGES += "${PN}-staticdev"
+PACKAGES += "${PN}-dbg"
+PACKAGES += "${PN}-data"
+
+REMOVE_LIBTOOL_LA = "0"
+
+do_configure_prepend() {
+    cd ${S}
+    sed -e "s|libtool --version|-libtool --version|g"  -i helper.mk
+    ./bootstrap
+}
+
+FILES_${PN}-dev = "\
+${includedir}/${PN}/* \
+${bindir}/${PN}-config \
+"
+
+FILES_${PN}-staticdev = "\
+${libdir}/${PN}/lib*.a \
+"
+
+FILES_${PN}-dbg = "\
+${libdir}/${PN}/.debug/libModule*.so* \
+"
+
+FILES_${PN} = "\
+${libdir}/${PN}/libModule*.so* \
+${libdir}/${PN}/libModule*.la* \
+${bindir}/${PN} \
+"
+
+FILES_${PN}-data = "\
+${datadir}/${PN}/* \
+${localstatedir}/games/${PN}/*/highscores \
+"
+
+RDEPENDS_${PN} += " ${PN}-data"
+INSANE_SKIP_${PN} = "dev-so"