build.gradle

plugins {
    id("com.github.johnrengelman.shadow") version "7.1.1"
    id("io.micronaut.application") version "3.2.2"
}

version = "0.1"
group = "io.sarvika.clowre"

repositories {
    mavenCentral()
}

dependencies {
    annotationProcessor("io.micronaut:micronaut-http-validation")

    implementation("io.micronaut:micronaut-http-client")
    implementation("io.micronaut:micronaut-jackson-databind")
    implementation("io.micronaut:micronaut-runtime")
    implementation("jakarta.annotation:jakarta.annotation-api")

    runtimeOnly("ch.qos.logback:logback-classic")
    implementation("io.micronaut:micronaut-validation")
    implementation("io.micronaut.views:micronaut-views-thymeleaf")
    implementation("io.micronaut.discovery:micronaut-discovery-client")

    implementation("io.swagger.parser.v3:swagger-parser:2.0.30")
}


application {
    mainClass.set("io.sarvika.clowre.Application")
}
java {
    sourceCompatibility = JavaVersion.toVersion("11")
    targetCompatibility = JavaVersion.toVersion("11")
}

graalvmNative.toolchainDetection = false
micronaut {
    runtime("netty")
    testRuntime("junit5")
    processing {
        incremental(true)
        annotations("io.sarvika.clowre.*")
    }
}

def releaseVersion = System.getenv("RELEASE_VERSION")

tasks.named("dockerBuild") {
    images = [
        "clowre/docserver"
    ]

    if (releaseVersion != null && !releaseVersion.trim().isEmpty()) {
        logger.lifecycle "Adding release tag '${releaseVersion}' to docker builds"
        images.add("clowre/docserver:${releaseVersion}")
    }
}

tasks.named("dockerPush") {
    registryCredentials {
        username = System.getenv("DOCKER_HUB_USERNAME")
        password = System.getenv("DOCKER_HUB_PASSWORD")
    }
}