build.gradle

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "com.github.rodm:gradle-teamcity-plugin:0.9.1"
    }
}

subprojects {
    apply plugin: 'java'
    sourceCompatibility = 1.6
    targetCompatibility = 1.6
}

project(':common') {
}

project(':agent') {
    apply plugin: 'com.github.rodm.teamcity-agent'

    dependencies {
        compile project(':common')
        agent 'net.sourceforge.jtds:jtds:1.2.7'

        testCompile 'org.testng:testng:6.8.21'
        testCompile 'org.mockito:mockito-core:1.+'
    }    

    test {
        useTestNG()
    }

    jar {
        appendix = "${rootProject.name}"
    }

    teamcity {
        agent {
            descriptor {
                pluginDeployment {
                    useSeparateClassloader = true
                }
            }

            files {
                into ('lib/native') {
                    from ('native')
                }
            }
        }
    }
}

project(':server') {
    apply plugin: 'com.github.rodm.teamcity-server'

    dependencies {
        compile project(':common')
        agent project(path: ':agent', configuration: 'plugin')

        testCompile 'org.testng:testng:6.8.21'
        testCompile 'org.mockito:mockito-core:1.+'
    }

    test {
        useTestNG()
    }

    jar {
        appendix = "${rootProject.name}"
    }

    teamcity {
        descriptor = file('teamcity-plugin.xml')
        server {
        }
    }
}