-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathDSORT.GEN.TXT
1812 lines (1694 loc) · 49.2 KB
/
DSORT.GEN.TXT
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;
;
; DSORT is een .COM programma in ML om de directory
; van enkel en dubbelzijdige MSX disks op MSX 1 en 2
; computers te kunnen sorteren. En dan niet alleen
; op alfabetische volgorde, maar in iedere gewenste
; volgorde. December 1987 by R W L
; Dit GEN-file kan overigens ook een .BIN versie genereren
; Dit was nodig i.v.m. publicatie. (Een .COM ontwikkelt
; makkelijker)
; Versie 1.01 kan (als .COM file) ook de B-drive gebruiken.
; voorbeeld: DSORT B:
MSXDOS equ 1
BLOADR equ 0
VERSION equ MSXDOS ; welke versie assembleren?
YES equ 1
NO equ 0
CHECKSM equ NO ; assemble 'AA' checksum (testversie)?
if .not.(VERSION=0)
DOSENTR equ #0005 ; entry naar DOS routines
else
DOSENTR equ #F37D ; idem voor basic versie
endc
EXPTBL equ #FCC1 ; slot adres main rom
CALLSLT equ #001C ; inter slot call (ook uit DOS)
RDSLT equ #000C ; inter slot read (ook uit DOS)
CURFKEY equ #F87F ; fuctietoetsen
LINELEN equ #F3AE ; regellengte
FORCLR equ #F3E9 ; voorgrond kleur
BAKCLR equ #F3EA ; achtergrond kleur
FKEYSW equ #F3DE ; functietoetsen zichtbaar?
CHGCLR equ #0062 ; kleur verander routine in BIOS
INITXT equ #006C ; zet 40 koloms mode (BIOS)
INIT32 equ #006F ; zet 32 koloms mode (BIOS)
FKEYOF equ #00CC ; functie toetsen uit (BIOS)
FKEYSB equ #00C9 ; vw. tonen functietoetsen
SCRMODE equ #FCAF ; huidige screen mode
PATTERN equ #F3B7 ; hier staat het adress van de karakter gen.
NAMETAB equ #F3B3 ; hier staat de schermtabel
COMLINE equ #0080 ; MSXDOS Command Line
BVDPIN equ #0006 ; adres waar input poort uit VDP staat
BVDPOUT equ #0007 ; adres waar output poort naar VDP staat
BSETRD equ #0050 ; bios routine set vdp for read
BSETWR equ #0053 ; bios routine set vdp for write
BEEP equ #00C0 ; geeft een pieptoon
DISKIO equ #0144 ; disk input/output
DIRINP equ #07 ; direct input
GETDEF equ #19 ; get default drive name
LOGDRV equ #18 ; get on line drives
DRVINFO equ #1B ; get drive information
DIRLEN equ 112*32 ; lengte directory
FKEYLEN equ 10*16 ; lengte functietoetse gebied
KARLEN equ 256*8 ; lengte karakterset
SCRLEN equ 40*24 ; lengte name table scherm
ARLEN equ 224 ; lengte aray
CALLDOS macro @FUN,@ARG ; macro om DOS routines aan te roepen,
ld c,@FUN ; eerst functienr. dan eventueel waarde 'de'
if "@ARG">"" ; is er een tweede parameter?
ld de,@ARG
endc
call DOSENTR
endm
if .not.(VERSION=0) ; if DOS versie
CALBIOS macro @FUN
push af
ld a,(EXPTBL) ; haal slot adres MAIN ROM
push af
pop iy ; in hoge bits van iy
ld ix,@FUN ; functie nr. in IX
pop af
call CALLSLT
ei ; interupts weer aan
endm
else
CALBIOS macro @FUN
call @FUN
ei
endm
endc
MOVE macro @BYTES,@VAN,@NAAR
ld bc,@BYTES
ld de,@NAAR
ld hl,@VAN
ldir
endm
if VERSION=0 ; if bload versie
defb #FE
defw START
defw EIND
defw START
org #C000
endc
START jp MENTRY ; main entry
; routine om de inhoud van hl met 32 te vermenigvuldigen
HL_32X add hl,hl ;*2
add hl,hl ;*4
add hl,hl ;*8
add hl,hl ;*16
add hl,hl ;*32
ret
; routine om de inhoud van hl met 40 te vermenigvuldigen
HL_40X add hl,hl ;*2
add hl,hl ;*4
add hl,hl ;*8
push de ; bewaar de
push hl ; bewaar 8 * hl
add hl,hl ;*16
add hl,hl ;*32
pop de ; de = 8 * hl
add hl,de ;*40
pop de ; haal de terug
ret
; COMPARN vergelijkt 2 11 bytes gebieden en geeft
; gewoon C en Z flag terug (nooit Z dus...)
COMPARN ld a,(IY) ; iy wijst naar 'eerste'
cp (IX) ; ix wijst naar 'volgende'
ret nz
ld a,(IY+1)
cp (IX+1)
ret nz
ld a,(IY+2)
cp (IX+2)
ret nz
ld a,(IY+3)
cp (IX+3)
ret nz
ld a,(IY+4)
cp (IX+4)
ret nz
ld a,(IY+5)
cp (IX+5)
ret nz
ld a,(IY+6)
cp (IX+6)
ret nz
ld a,(IY+7)
cp (IX+7)
ret nz
ld a,(IY+8)
cp (IX+8)
ret nz
ld a,(IY+9)
cp (IX+9)
ret nz
ld a,(IY+10)
cp (IX+10)
ret
; COMPARE doet hetzelfde als de routine hierboven,
; maar dan voor EXT sorts.
COMPARE ld a,(IY+8)
cp (IX+8)
ret nz
ld a,(IY+9)
cp (IX+9)
ret nz
ld a,(IY+10)
cp (IX+10)
ret nz
ld a,(IY)
cp (IX)
ret nz
ld a,(IY+1)
cp (IX+1)
ret nz
ld a,(IY+2)
cp (IX+2)
ret nz
ld a,(IY+3)
cp (IX+3)
ret nz
ld a,(IY+4)
cp (IX+4)
ret nz
ld a,(IY+5)
cp (IX+5)
ret nz
ld a,(IY+6)
cp (IX+6)
ret nz
ld a,(IY+7)
cp (IX+7)
ret nz
ld a,(IY+8)
cp (IX+8)
ret
; Nu de COMPU routine, die een Carry geeft
; als er verwisseld moet worden voor 'UP'
COMPU call COMPARN
ccf
ret nz
or a ; gelijk (??) no change
ret
; Nu de COMPD routine, de een Carry geeft
; als er verwisseld moet worden voor 'DOWN'
COMPD call COMPARN
ret
; Nu de COMPEU routine, die een Carry geeft
; als er verwisseld moet worden voor 'EXT. UP'
COMPEU call COMPARE
ccf
ret nz
or a
ret
; Nu de COMPED routine, die een Carry geeft
; als er verwisseld moet worden voor 'EXT. DOWN'
COMPED call COMPARE
ret
; de Call (hl) routine.......
COMPSUB jp (hl)
; Nu de BUBBLE sort routine, die het hele zaakje
; sorteerd, en dan een return maakt naar DENTRY
BUBBLE call SETINST
ld b,112 ; zoek 112 entry's af
BUBBLEA push bc
dec b
ld c,b
ld b,0 ; bc=nr. entry
ld hl,ARRAY+1
add hl,bc
add hl,bc ; hl=adres info byte
ld a,(hl)
and %11 ; lage 2 bits
cp %10
pop bc
jr z,BUBBLEB ; start als valid en unlocked
djnz BUBBLEA ; zoek verder
jp NENTRY ; exit, geen valid entry's
BUBBLEB dec b
BUBBLE0 push bc ; dit is de buitenste 'Bubble' loop
ld a,255
ld (BUBFLAG),a ; zet de flag op niet stoppen
dec b
ld c,b
ld b,0 ; bc=entry nr.
ld hl,ARRAY+1
add hl,bc
add hl,bc ; hl=adres info byte
ld a,(hl)
and %11 ; lage 2 bits
cp %10
jr nz,BUBBLE1 ; sla over als niet valid of locked
pop bc
xor a
ld (BUBFLAG),a ; zet flag op stoppen
push bc ; haal even teller terug
ld c,b ; maximale waarde binnenlus
BUBBLE2 ld a,c ; Dit is de binnenste bubble loop
sub b ; oplopend tellen
ld l,a
ld h,0 ; plaats in ARRAY
add hl,hl
ld de,ARRAY+1
add hl,de ; adres info byte
ld a,(hl)
and %11
cp %10
jr nz,BUBBLE3 ; sla over als niet valid of locked
push hl
dec hl
ld l,(hl)
ld h,0 ; haal nr. dir. entry
push hl
pop iy
pop hl
push hl ; herstel hl
BUBBLE4 inc hl
inc hl
bit 1,(hl)
jr z,BUBBLE4 ; zoek eerstvolgende valid entry
bit 0,(hl)
jr nz,BUBBLE4 ; terug als locked
push hl
ld de,DIRAREA
dec hl
ld l,(hl)
ld h,0 ; haal dir. nummer
call HL_32X
add hl,de
push hl
pop ix ; in ix
add iy,iy
add iy,iy
add iy,iy
add iy,iy
add iy,iy ; *32
add iy,de ; in iy
ld hl,(ROUTINE)
call COMPSUB ; compare subroutine
pop ix
pop iy
jr nc,BUBBLE3
ld a,255
ld (BUBFLAG),a
ld d,(ix-1)
ld e,(iy-1)
ld (iy-1),d
ld (ix-1),e
ld d,(ix)
ld e,(iy)
ld (iy),d
ld (ix),e ; verwissel deze twee bytes
BUBBLE3 djnz BUBBLE2
BUBBLE1 pop bc
ld a,(BUBFLAG)
or a ; check flag
jp z,DENTRY
dec b
jp nz,BUBBLE0
jp DENTRY
; Deze routine zet op elke MSX een 40 kolommen
; zwart-wit beeld op, en onthoud alle oude waardes
; voor de routine RESSCRN (restore screen)
; tevens worden de functietoetsen gezet.
SETSCRN MOVE FKEYLEN,CURFKEY,SAVFKEY
MOVE FKEYLEN,NEWFKEY,CURFKEY
ld a,(SCRMODE)
ld (RES0),a ; onthou huidige screen mode
ld a,(LINELEN)
ld (RES1),a ; onthou oude regellengte
ld a,40
ld (LINELEN),a ; zet regellengte op 40 karakters
ld a,(FORCLR)
ld (RES2),a ; onthou voorgrond kleur
ld a,15
ld (FORCLR),a ; zet voorgrond kleur wit
ld a,(BAKCLR)
ld (RES3),a ; onthou achtergrond kleur
ld a,1
ld (BAKCLR),a ; zet achtergrond zwart
ld a,(FKEYSW)
ld (RES4),a ; onthou stand functie toetsen
CALBIOS FKEYOF ; zet ze uit
CALBIOS INITXT ; zet text mode
CALBIOS CHGCLR ; zet kleuren
ret
; PREPIO is de routine die de parameters voor de
; screen I/O ophaald uit het main rom, en in het
; ram haalt, zodat er geprint kan worden. Tevens
; wordt de karakterset door deze routine in orde
; gemaakt (bovenste helft inverse)
PREPIO ld a,(EXPTBL) ; haal slot adres main rom
ld hl,BVDPIN
call RDSLT ; lees interslot
ld (VDPINP),a ; VDP input poort
ld a,(EXPTBL)
ld hl,BVDPOUT
call RDSLT
ld (VDPOUT),a ; VDP output poort
ld hl,(PATTERN)
ld de,8
add hl,de ; hl=beginadres karakter 1
call SETWRIT
ld a,(VDPOUT)
ld c,a ; poort nr. in c
ld b,8
ld a,%00000111
PREPIO3 out (c),a
djnz PREPIO3 ; herhaal voor alle 8 bytes
ld hl,(PATTERN)
call SETREAD
ld b,0 ; (4x) 256 keer:
ld a,(VDPINP)
ld c,a ; poortnr. in C
ld hl,TEMPINI ; tijdelijk opslag gebied
ld de,KARLEN/2
PREPIO2 in a,(c)
ld (hl),a
inc hl
dec de
ld a,d
or e ; al 0?
jr nz,PREPIO2 ; alle bytes aflopen
ld hl,(PATTERN)
ld de,KARLEN/2 ; 1K verder (2e helft)
add hl,de
push de
call SETWRIT
pop de
ld a,(VDPOUT)
ld c,a ; poort nr. in c
ld hl,TEMPINI
PREPIO1 ld a,(hl)
inc hl
cpl ; inverteer regel
out (c),a ; naar VDP
dec de
ld a,d
or e ; al 0?
jr nz,PREPIO1 ; alle bytes aflopen
ei ; interupts weer aan
ret
RES0 defb 0 ; screen mode
RES1 defb 0 ; regellengte
RES2 defb 0 ; voorgrond
RES3 defb 0 ; achtergrond
RES4 defb 0 ; functietoetsen aan/uit
VDPINP defb 0 ; VDP input register
VDPOUT defb 0 ; VDP output register
COLUMNS defb 2 ; aantal kolommen
CURLIN defb 0 ; huidige regel
SCRLIN defb 0 ; huidige hoogste schermregel
; In de volgende twee bytes worden steeds de laatste twee
; ontvangen letters opgeslagen, zodat eventuele
; commando's herkend kunnen worden. Het hele opslaan
; gebeurd door de WAITKEY routine.
LETTER1 defb 0 ; letters voor commando-herkenning
LETTER2 defb 0
CIJFER0 defb 0 ; hiet staat het entry-nummer,
CIJFER1 defb 0 ; voor de DISPLAY routine
CIJFER2 defb 0
CURFLAG defb 0 ; flag voor inverteren of niet
BUBFLAG defb 0 ; flag voor bubble sort
DEFAULT defb 0 ; default drive name
DIRSEC defw 5 ; eerste directory sector
DSKTYP defb #F8; media ID byte
ROUTINE defw 0 ; compare routine adres
; SETREAD en SETWRIT stellen de VDP in op het lezen van
; of schrijven naar VRAM. De interrupts worden uitgezet,
; alleen de laagste 14 bits van hl zijn geldig. Alle
; registers blijven in tact.
SETREAD push af
push ix
push iy
CALBIOS BSETRD
pop iy
pop ix
pop af
ret
SETWRIT push af
push ix
push iy
CALBIOS BSETWR
pop iy
pop ix
pop af
ret
; Deze routine hersteld het scherm weer in de oude toestand,
; dus kleuren, screen 1/0, width, en functietoetsen.
RESSCRN MOVE FKEYLEN,SAVFKEY,CURFKEY
ld a,(RES1)
ld (LINELEN),a ; herstel regellengte
ld a,(RES2)
ld (FORCLR),a ; herstel voorgrond
ld a,(RES3)
ld (BAKCLR),a ; herstel achtergrond
ld a,(RES4)
ld (FKEYSW),a ; herstel functietoetsen aan/uit
ld a,(RES0)
dec a ; screen 1?
jr nz,RESSCR1
CALBIOS INIT32 ; screen 1 (kleuren meteen)
CALBIOS FKEYSB
ret
RESSCR1 CALBIOS INITXT ; screen 0
CALBIOS CHGCLR
CALBIOS FKEYSB
ret
; WRITELN schrijft een reeks ascii-codes, afgesloten
; door een 0 naar het VRAM. De coordinaten moeten in
; hl gezet worden. Deze routine is snel, maar accepteerd
; geen controle codes e.d. v.a. adres 'de'
WRITELN ld b,0
ld c,l ; kolom in bc
ld l,h
ld h,0 ; regelnr. in hl
call HL_40X ; vermenigvuldig met 40
add hl,bc ; tel kolom erbij op
ld bc,(NAMETAB)
add hl,bc ; absoluut VRAM adres in hl
call SETWRIT ; set VDP for write
ld a,(VDPOUT)
ld c,a ; poortnr. in C
ld a,(de) ; haal eerste teken
WRITEL1 inc de
out (c),a ; altijd minstens 1 karakter lang
ld a,(de)
or a
jr nz,WRITEL1
ei
ret
; Deze routine schrijft alle standaard teksten op het scherm.
; Dat wil zeggen: kopregel en instructies.
SETTEXT ld hl,0 ; 0,0
ld de,KOPREG
call WRITELN
ld hl,#0317 ; 23,3
ld de,INSTR1
call WRITELN
ld hl,#0517 ; 23,5
ld de,INSTR2
call WRITELN
ld hl,#0716 ; 22,7
ld de,INSTR3
call WRITELN
ld hl,#0917 ; 23,9
ld de,INSTR4
call WRITELN
ld hl,#0B18 ; 24,11
ld de,INSTR5
call WRITELN
ld hl,#0D19 ; 25,13
ld de,INSTR6
call WRITELN
ld hl,#0F19 ; 25,15
ld de,INSTR7
call WRITELN
ld hl,#111B ; 27,17
ld de,INSTR8
call WRITELN
ld hl,#131B ; 27,19
ld de,INSTR9
call WRITELN
ld hl,#151C ; 28,21
ld de,INSTR0
call WRITELN
ret
KOPREG defb ' This is' ; Kopregel
defb 1,'d'+128
defb 'ir'
defb 's'+128,'o'+128,'r'+128,'t'+128
defb ' 1.01 by',1,
RWLADR defb 'R'+128,'W'+128,'L'+128,' (ESC=help)'
defb 0
INSTR1 defb 1,'s'+128 ; Save Filenames
defb 'ave',1 ; 14
defb 'f'+128
defb 'ilenames',0
INSTR2 defb 1,'l'+128 ; Load Filenames
defb 'oad ' ; 14
defb 'f'+128
defb 'ilenames',0
INSTR3 defb 1,'s'+128 ; Sort Down (A>>Z)
defb 'ort',1 ; 16
defb 'd'+128
defb 'own (Z>>A)',0
INSTR4 defb 1,'s'+128 ; Sort Up
defb 'ort',1 ; 14
defb 'u'+128
defb 'p (A>>Z)',0
INSTR5 defb 'sort',1 ; sort Ext. Up
defb 'e'+128 ; 14
defb 'xt.',1
defb 'd'+128,'o','w','n',0
INSTR6 defb 'sort',1 ; sort Ext. Down
defb 'e'+128 ; 12
defb 'xt.',1
defb 'u'+128,'p',0
INSTR7 defb 'all',1 ; all Names Up
defb 'n'+128 ; 12
defb 'ames',1
defb 'u'+128,'p',0
INSTR8 defb '2',1 ; n CoLumn
defb 'c'+128 ; 8
defb 'o','l'+128
defb 'u','m','n',0
INSTR9 defb 1,'u'+128 ; UnLock
defb 'n' ; 6*
defb 'l'+128
defb 'o','c','k',0
INSTR0 defb 1,'q'+128 ; QUit
defb 'u'+128 ; 4*
defb 'it'
defb 0
; CHKDRV zet het default drive nummer dat
; start bij 0 in 'DEFAULT'.
CHKDRV if VERSION=MSXDOS
ld a,(COMLINE)
or a ; 0 of meer tekens?
jr z,CHKDRV1
ld b,a
ld hl,COMLINE+1
CHKDRVB ld a,(hl)
cp ' '
jr nz,CHKDRVC
inc hl
djnz CHKDRVB ; sla spaties over
jp CHKDRV1
CHKDRVC ld a,b
cp 2
jr c,CHKDRV1 ; minder dan 2
inc hl
ld a,(hl)
cp ':'
jr nz,CHKDRV1 ; geen ':'
dec hl
ld a,(hl)
sub 'a'
jp nc,CHKDRV0
add a,32 ; correctie: hoofdletter
CHKDRV0 ld (DEFAULT),a
cp 8
jr nc,CHKDRV1 ; nummer te hoog
ld b,a
inc b
ld a,%10000000
CHKDRVA rlca
djnz CHKDRVA ; maak masker
push af
CALLDOS LOGDRV
pop af
and l
jr z,CHKDRV1 ; niet on line...
ld a,(DEFAULT)
inc a
ld e,a
CALLDOS DRVINFO ; vraag om disk voor Single drive systeem
ret
CHKDRV1 endc
CALLDOS GETDEF ; haal default drive in A
ld (DEFAULT),a
ret
; COLNUM krijgt als invoer het aantal kolommen,
; en past dat aan. Invoer in a (ascii)
; past aan: scherm, tekst, en sys. variabele.
COLNUM ld e,a
ld (INSTR8),a ; ook in standaard scherm
sub '0' ; maak binair
ld (COLUMNS),a
ld a,e
push af
ld de,707 ; position on screen
ld hl,(NAMETAB)
add hl,de
call SETWRIT
ld a,(VDPOUT)
ld c,a
pop af ; haal karakter terug
out (c),a ; print karakter
ei
jp NENTRY
MENTRY call CHKDRV ; haal default drive name
call SETSCRN ; zet goede screen mode
RENTRY call CLS ; goed effect bij ctrl-stop
call SETINST ; wis instructie-letters
call PREPIO ; prepare alle I/O acties
call INSTAR ; zet oplopende waardes in array
call UNLOCK ; haal overal lock weg
call CLRDIR ; wis de directory
call VALID ; test of alle entry's valid zijn
call HOMESUB ; naar regel 0
ld a,2
ld (COLUMNS),a
ld a,'2'
ld (INSTR8),a ; 2 kolommen
CENTRY call CLS ; wis scherm
call CHKRWL ; naam nog in orde?
call SETTEXT ; schrijf text voor initscreen
DENTRY call DISPLAY ; schrijf directory
NENTRY if .not.(CHECKSM=0)
call CHECK
endc
call WAITKEY ; wacht op toets
cp 'S'
jp z,COMMAND
cp 'D'
jp z,COMMAND
cp 'L'
jp z,COMMAND
cp 'E'
jp z,COMMAND
cp 'N'
jp z,COMMAND
cp 'Q'
jp z,COMMAND
cp 'U'
jp z,COMMAND
cp 'L'
jp z,COMMAND
cp 'C'
jp z,COMMAND
cp 'F'
jp z,COMMAND
ld hl,LETTER2
ld (hl),0 ; not a command letter
cp 3
jr z,RENTRY ; CTRL-STOP
cp #C
jr z,CENTRY ; cls
cp '2'
jr c,MAIN1
cp '9'+1
jp c,COLNUM ; aantal kolommen
MAIN1 cp #1E
jp z,LINEU ; regel omhoog
cp #1F
jp z,LINED ; regel omlaag
cp #1C
jp z,PAGEU ; pagina verder
cp #1D
jp z,PAGED ; pagina terug
cp #B
jp z,HOME ; naar entry 0
cp ' '
jp z,TRYLOCK ; flip lock
cp 24
jp z,TRYLOCK ; idem (select)
cp 8
jp z,DELLINE ; delete line (bs)
cp 127
jp z,DELLINE ; delete line (del)
cp 21
jp z,DELLINE ; delete line (CTRL-U)
cp 18
jp z,INSLINE ; insetr line
cp 9
jp z,INSLINE ; (tab)
cp 13
jp z,INSLINE ; (return)
cp 27
jp nz,NENTRY ; loop until ESC
jr HELP
; Deze routine laat de help-pagine zien.
; Dan wordt er op een toets gewacht, en teruggesprongen
; naar de CLS-entry
HELP ld hl,HELPDAT
ld de,746 ; lengte help tekst
ld bc,0
HELPC1 ld a,b
add a,(hl)
ld b,a
ld a,c
xor (hl)
ld c,a
inc hl
dec de
ld a,d
or e
jr nz, HELPC1
ld a,64 ; XOR
cp c
jp nz,NENTRY
ld a,212 ; ADD
cp b
jp NZ,NENTRY
; Help tekst is OK nu, display:
call CLS ; wis eerst scherm
ld hl,(NAMETAB)
call SETWRIT
ld a,(VDPOUT)
ld c,a
ld d,24
ld hl,HELPDAT
HELP1 ld b,40
dec d
jr z,HELPEX
HELP2 ld a,(hl)
or a
jr nz,HELP3
ld a,' '
HELP4 out (c),a
djnz HELP4 ; maak regel af
inc hl
jr HELP1
HELP3 out (c),a
inc hl
djnz HELP2
HELPEX call WAITKEY
call SETINST
jp CENTRY
QUIT CALBIOS BEEP
ld de,YOUSURE
ld hl,#1519
call WRITELN
call WAITKEY
cp 'Y' ; accepteer Y en y
jp z,QUIT1
cp 'J' ; of J en j
jp z,QUIT1
ld de,NOTSURE
ld hl,#1519
call WRITELN
CALL SETINST
jp NENTRY ; next instruction
QUIT1 call RESSCRN
CALLDOS 0
YOUSURE defb "You're sure?",0
NOTSURE defb " ",1,"q"+128,"u"+128,"it ",0
; SWAPU verwisselt de 2 bytes op (hl) en de 2 bytes
; daarna. Zonder enige registers te molesteren.
; hl wijst naar de tweede byte!
SWAPU push ix
push de
push hl
pop ix
ld d,(ix-1)
ld e,(ix+1)
ld (ix-1),e
ld (ix+1),d ; (ix-1) <> (ix+1)
ld d,(ix+0)
ld e,(ix+2)
ld (ix+2),d
ld (ix+0),e ; (ix+0) <> (ix+2)
pop de
pop ix
ret
; SWAPD verwisselt de 2 bytes op (hl) en de 2 bytes
; daarvoor. Zonder enige registers te molesteren.
; hl wijst naar de tweede byte!
SWAPD push ix
push de
push hl
pop ix
ld d,(ix-1)
ld e,(ix-3)
ld (ix-1),e
ld (ix-3),d ; (ix-1) <> (ix-3)
ld d,(ix-2)
ld e,(ix+0)
ld (ix+0),d
ld (ix-2),e ; (ix+0) <> (ix-2)
pop de
pop ix
ret
; De LINEU routine probeerd de current line 1 regel
; omhoog te schuiven.
LINEU ld a,(CURLIN)
or a
jr nz,LINEU1
call LOCKSU ; probeer locks omhoog te schuiven
jp DENTRY
LINEU1 dec a
ld (CURLIN),a
ld hl,SCRLIN
cp (hl)
jp nc,DENTRY ; beweging binnen scherm
dec (hl)
call LOCKSU
jp DENTRY
; LOCKSU is een routine die alle 'locked' files
; een regel omhoog te schuiven.
LOCKSU ld hl,ARRAY+1
ld b,112
LOCKSU1 bit 0,(hl) ; locked?
jr z,LOCKSU2
inc hl
inc hl
djnz LOCKSU1 ; zoek eerste unlocked
ret ; niet gevonden (onmogelijk!)
LOCKSU2 dec b
LOCKSU3 inc hl
inc hl
bit 0,(hl)
call nz,SWAPD ; schuif als deze locked is
djnz LOCKSU3
ret
; De LINED routine probeerd de current line 1 regel
; omlaag te schuiven.
LINED ld a,(CURLIN)
cp 111
jr nz,LINED1
call LOCKSD ; probeer nog wel locks omhoog te halen
jp DENTRY
LINED1 inc a
ld (CURLIN),a
ld hl,SCRLIN
sub (hl) ; resultaat moet < 19 zijn
cp 19
jp c,DENTRY ; beweging binnen scherm
inc (hl)
call LOCKSD
jp DENTRY
; LOCKSD is een routine die alle 'locked' files
; een regel omlaag te schuiven.
LOCKSD ld hl,ARRAY+(112*2)-1
ld b,112
LOCKSD1 bit 0,(hl) ; locked?
jr z,LOCKSD2
dec hl
dec hl
djnz LOCKSD1 ; zoek eerste unlocked
ret ; niet gevonden (onmogelijk!)
LOCKSD2 dec b
LOCKSD3 dec hl
dec hl
bit 0,(hl)
call nz,SWAPU
djnz LOCKSD3
ret
; PAGED probeerd een pagina terug te gaan, anders een
; BEEP. (1 pagina is 19 regels)
PAGED call LOCKSPU ; altijd buiten scherm
ld a,(CURLIN)
or a
jp z,DENTRY ; we zijn al op nr. 0
sub 19
jr nc,PAGED1 ; kan dat nog?
xor a
PAGED1 ld (CURLIN),a
ld a,(SCRLIN) ; nu scherm ook terug
sub 19
jr nc,PAGED2 ; kan dat nog?
xor a
PAGED2 ld (SCRLIN),a
jp DENTRY
; LOCKSPD haalt alle locks 1 pagina omlaag
LOCKSPD ld b,19
LOCKPD1 push bc
call LOCKSD
pop bc
djnz LOCKPD1
ret
; PAGEU probeerd een pagina door te gaan, anders een
PAGEU call LOCKSPD ; altijd buiten scherm
ld a,(CURLIN)
cp 111
jp z,DENTRY ; we zijn al op nr. 111
add a,19
cp 112
jr c,PAGEU1
ld a,111
PAGEU1 ld (CURLIN),a
ld a,(SCRLIN)
add a,19
cp 94
jr c,PAGEU2
ld a,93
PAGEU2 ld (SCRLIN),a
jp DENTRY
; LOCKSPU haalt alle locks 1 pagina omhoog
LOCKSPU ld b,19
LOCKPU1 push bc
call LOCKSU
pop bc
djnz LOCKPU1
ret
; HOME is de routine om terug te gaan naar entry 0
HOME call HOMESUB ; subroutine ook aan te roepen
call UNLOCK ; wis eventuele locks
jp DENTRY ; bij initialisatie procedure.
HOMESUB xor a ; beide op 0..
ld (CURLIN),a
ld (SCRLIN),a
ret
; De DISPLAY routine zet het file-namen display op
; het scherm, met de current name inverse.