summary

#!/usr/bin/awk -f

function isnum(x) {
	return (x == x + 0 )
}

NR == 1 {
	columns = NF;
	for (i = 1; i <= columns; i++) {
		header[i] = $i;
	}
}

{
	if (NF != columns) {
		print "Irregular number of columns!";
		exit 1;
	} 

	for (i = 1; i <= columns; i++) { 
		if (isnum($i)) {
			sum[i] += $i; 
			if (!first[i]) {
				min[i] = $i; 
				max[i] = $i;
				first[i] = 1;
			} else {
				if ($i < min[i]) 
					min[i] = $i; 
				if ($i > max[i]) 
					max[i] = $i;
			}
		}
	}
} 

END {
	printf "COL | "
	for (i = 1; i <= columns; i++) 
		printf "%11d |", i;
	print "";

	printf "LEN | "
	for (i = 1; i <= columns; i++) 
		printf "%11.6g |", NR;
	print "";

	printf "NAM | "
	for (i = 1; i <= columns; i++) 
		printf "%11s |", header[i];
	print "";

	printf "MIN | "
	for (i = 1; i <= columns; i++) 
		printf "%11.6g |", min[i];
	print "";

	printf "AVG | "
	for (i = 1; i <= columns; i++) 
		printf "%11.6g |", sum[i]/NR;
	print "";

	printf "MAX | "
	for (i = 1; i <= columns; i++) 
		printf "%11.6g |", max[i];
	print "";

	printf "SUM | "
	for (i = 1; i <= columns; i++) 
		printf "%11.6g |", sum[i];
	print "";
}