Include Non-Arduino cmake based library

[metanav]

I would like to reuse the Pimoroni Pico Library that uses pico C++ SDK. How can we include it in the arduino-pico? For example, this library: https://github.com/pimoroni/pimoroni-pico/tree/main/libraries/pico_motor_shim

[maxgerhardt]

If you write a firmware for Arduino, best to stay with Arduino libraries. Accessing SDK functions directly can mess with the core's functionality and break, as documented.

That said, you can mostly get Pico-SDK libraries to compile if you just add their source code, header files and convert any .pio files into .pio.h files (like so). Of course, when copying example code, you must not define the main() function, but use setup() and loop() instead. Also, don't call into stdio_init_all(); as that is handled differently in the Arduino core. Finally, some Arduino.h macros can mess with libraries. In this example, the ArduinoAPI.h's degrees and radians macros mess with the motor2040.hpp header file because it also uses that as a function name, so we have to #undef those macros.

I've created a PlatformIO project that can compile the examples/motor2040/motor2040_motor_cluster.cpp with no issues.

https://github.com/maxgerhardt/pio-rp2040-pico_motor_shim

I don't know whether it will work during runtime. It should compile the same in the Arduino IDE if you copy all source code from all libraries in lib/ in the same folder as the sketch (.ino) file, there are no special PlatformIO things involved here. I needed to cherry pick the "common", "encoder", "motor", "motor2040", "pico_motor_shim", "pwm" and "plasma" components from the pimoroni example to get it to compile.

[maxgerhardt]

FYI using the adapted example code from examples/pico_motor_shim/motorshim_single_motor.cpp compiles fine in that project, too.

#include <Arduino.h>
// undefine macros which are used as function names in that header
#undef degrees
#undef radians
#include "pico_motor_shim.hpp"

/*
Demonstrates how to create a Motor object and control it.
*/

using namespace motor;

// How many sweeps of the motor to perform
const uint SWEEPS = 2;

// The number of discrete sweep steps
const uint STEPS = 10;

// The time in milliseconds between each step of the sequence
const uint STEPS_INTERVAL_MS = 500;

// How far from zero to drive the motor when sweeping
constexpr float SPEED_EXTENT = 1.0f;


// Create a motor
Motor m = Motor(pico_motor_shim::MOTOR_1);

void setup() {
  Serial.begin(115200);

  // Initialise the motor
  m.init();

  // Enable the motor
  m.enable();
  sleep_ms(2000);

  // Drive at full positive
  m.full_positive();
  sleep_ms(2000);

  // Stop moving
  m.stop();
  sleep_ms(2000);

  // Drive at full negative
  m.full_negative();
  sleep_ms(2000);

  // Coast to a gradual stop
  m.coast();
  sleep_ms(2000);

  // Do a sine speed sweep
  for(auto j = 0u; j < SWEEPS; j++) {
    for(auto i = 0u; i < 360; i++) {
      m.speed(sin(((float)i * (float)M_PI) / 180.0f) * SPEED_EXTENT);
      sleep_ms(20);
    }
  }

  // Do a stepped speed sweep
  for(auto j = 0u; j < SWEEPS; j++) {
    for(auto i = 0u; i < STEPS; i++) {
      m.to_percent(i, 0, STEPS, 0.0 - SPEED_EXTENT, SPEED_EXTENT);
      sleep_ms(STEPS_INTERVAL_MS);
    }
    for(auto i = 0u; i < STEPS; i++) {
      m.to_percent(i, STEPS, 0, 0.0 - SPEED_EXTENT, SPEED_EXTENT);
      sleep_ms(STEPS_INTERVAL_MS);
    }
  }

  // Disable the motor
  m.disable();
}

void loop() {

}

[metanav]

Thanks, @maxgerhardt! The cherry-picking worked well and compiled successfully using the Arduino IDE.

├── motor_test.ino
└── src
    ├── common
    │   └── pimoroni_common.hpp
    ├── motor.cpp
    ├── motor.hpp
    ├── motor_state.cpp
    ├── motor_state.hpp
    ├── pico_motor_shim.hpp
    ├── pwm.cpp
    └── pwm.hpp

I will test it later on the hardware.

[maxgerhardt]

Okay, let us know. I'm only slightly concerned about the number of files there, because if those are all, you're missing a bunch of stuff: motor_cluster, encoder, all the .pio.h files, plasma, etc.

[metanav]

The motor shim is a DRV8833 that is being driven by PWMing the GPIO so I think PIO is not required. Also, there are no encoders on the motors I am using. Later, I will rewrite the code using the arduino-pico api only.

EDIT: Some explanations from the Pimoroni library,

• a Motor class that uses hardware PWM to drive a single motor, with support for up to 8 motors.
• a MotorCluster class that uses Programmable IO (PIO) hardware to drive up to 15 motors.