build.gradle

plugins {
    id "com.github.johnrengelman.shadow" version "4.0.4"
}

apply plugin: 'java'
apply plugin: 'application'
apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'checkstyle'

group = 'com.github.vlsi.ksar'
archivesBaseName = 'ksar'


sourceCompatibility = '1.8'
targetCompatibility = '1.8'

mainClassName = 'net.atomique.ksar.Main'

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.28'
    compile group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.12.1'
    compile group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.12.1'
    compile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.12.1'

    compile group: 'com.itextpdf', name: 'itextpdf', version: '5.5.13.1'
    compile group: 'com.jcraft', name: 'jsch', version: '0.1.55'
    compile group: 'org.jfree', name: 'jfreechart', version: '1.5.0'
    testCompile 'junit:junit:4.12'
}

tasks.withType(JavaCompile){
    options.compilerArgs << '-Xlint:unchecked' << '-Xlint:deprecation'
}

task writeVersion << {
    new File("build/resources/main/kSar.version").text = version
}
classes.dependsOn(writeVersion)

test {
    testLogging {
        exceptionFormat = 'full'
    }
}

checkstyle {
    configFile = new File(rootDir, "/src/main/checkstyle/postgressql-checks.xml")
}

jar {
    manifest {
        attributes("Implementation-Title": "kSAR",
                "Implementation-Version": version,
                "SplashScreen-Image": "logo_ksar.jpg")
    }
}