Improve the API of 'Optional'

StandardLibrary/Sources/Core/Optional.hylo

@@ -18,6 +18,41 @@ public extension Optional {
     None() as Optional
   }
 
+  /// Returns `true` iff `self` is equal to `.none()`.
+  public fun is_empty() -> Bool {
+    if let _: T = self { false } else { true }
+  }
+
+  /// Returns an optional containing the result of calling `transform` on the value wrapped in
+  /// `self` or `.none()` is `self` is empty.
+  public fun map<E, R>(_ transform: inout [E](T) -> R) -> Optional<R> {
+    if let w? = self { transform(w) as _ } else { .none() }
+  }
+
+}
+
+public extension Optional where T: Movable {
+
+  /// Returns the value wrapped in `self` or stops execution if `self` is empty.
+  ///
+  /// - Requires: `self` is not empty.
+  public fun postfix!() sink -> T {
+    if sink let r? = self {
+      return r
+    } else {
+      fatal_error("optional is empty")
+    }
+  }
+
+  /// Returns the value wrapped in `self` and assigns it to `.none()`.
+  ///
+  /// - Requires: `self` is not empty.
+  public fun release() inout -> T {
+    sink let wrapped = self!
+    &self = .none()
+    return wrapped
+  }
+
 }
 
 // Note: We can't declare confitional conformance of `Optional` to "umbrella traits" yet without

Tests/LibraryTests/TestCases/OptionalTests.hylo

@@ -12,4 +12,19 @@ public fun main() {
   &x = .none()
   let z = if let i: Int = x { i.copy() } else { 0 }
   precondition(z == 0)
+
+  &x = 42 as _
+  precondition(x! == 42)
+
+  &x = 42 as _
+  precondition(!x.is_empty())
+
+  &x = 42 as _
+  precondition(x.release() == 42)
+  precondition(x.is_empty())
+
+  &x = 42 as _
+  &x = x.map(fun(_ n) { n + 1 })
+  precondition(x.release() == 43)
+  precondition((x.map(fun(_ n) { n + 1 })).is_empty())
 }