-
Notifications
You must be signed in to change notification settings - Fork 6
/
Copy pathCS-ValidateKB-MASTER.pl
executable file
·1808 lines (1696 loc) · 79.8 KB
/
CS-ValidateKB-MASTER.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#!/usr/bin/perl
use warnings;
use strict;
### DO NOT INCLUDE
use ColdStartLib;
### DO INCLUDE
binmode(STDOUT, ":utf8");
#####################################################################################
# This program checks the validity of TAC Cold Start knowledge base variant input
# files. It will also output an updated version of a KB with warnings corrected.
#
# You are receiving this program because you signed up for a partner newsletter
#
# Author: James Mayfield
# Please send questions or comments to jamesmayfield "at" gmail "dot" com
#
# For usage, run with no arguments
#####################################################################################
### DO NOT INCLUDE
# FIXME: This doesn't really do much good without tracking the ColdStartLib version as well
### DO INCLUDE
my $version = "2017.2.0";
my $statsfile;
#####################################################################################
# Priority for the selection of problem locations
#####################################################################################
my %use_priority = (
MENTION => 1,
TYPEDEF => 2,
SUBJECT => 3,
OBJECT => 4,
);
#####################################################################################
# Mapping from output type to export routine
#####################################################################################
my %type2export = (
TAC => \&export_tac,
EDL => \&export_edl,
EAL => \&export_eal,
NUG => \&export_nug,
SEN => \&export_sen,
);
my $output_formats = "[" . join(", ", map {lc $_} sort keys %type2export) . ", none]";
#####################################################################################
# Default values
#####################################################################################
# Can the same assertion be made more than once?
my %multiple_attestations = (
ONE => "only one allowed - no duplicates",
ONEPERDOC => "at most one allowed per document",
MANY => "any number of duplicate assertions allowed",
);
my $multiple_attestations = 'MANY';
# Which triple labels should be output?
my %output_labels = ();
# Filehandles for program and error output
my $error_output = *STDERR{IO};
### DO NOT INCLUDE
#####################################################################################
# Library inclusions
#####################################################################################
### DO INCLUDE
### DO INCLUDE Header ColdStartLib.pm
### DO INCLUDE Logger ColdStartLib.pm
### DO INCLUDE Patterns ColdStartLib.pm
### DO INCLUDE Provenance ColdStartLib.pm
### DO INCLUDE ProvenanceList ColdStartLib.pm
### DO INCLUDE Predicates ColdStartLib.pm
### DO INCLUDE Switches ColdStartLib.pm
### DO INCLUDE Utils ColdStartLib.pm
#####################################################################################
# Predicates
#####################################################################################
#####################################################################################
# Knowledge base
#####################################################################################
# This is not really a KB per se, because we have to be resilient to errors in the input
package KB;
# A KB contains the following fields:
# ASSERTIONS0 - All assertions
# ASSERTIONS1 - Assertions indexed by subject
# ASSERTIONS2 - Assertions indexed by subject and verb
# ASSERTIONS3 - Assertions indexed by subject, verb and object
# DOCIDS - Assertions indexed by subject, verb and docid
# ENTITIES - Maps from entity name to entity structure
# LOGGER - Logger object for reporting errors and traces
# MENTIONS - Mention assertions indexed by docid
# PREDICATES - PredicateSet object
# RUNID - Run ID of the KB file this KB was built from
# RUNID_LINE - Entire line from which RUNID was extracted, including comments
# Create a new empty KB
sub new {
my ($class, $logger, $predicates) = @_;
my $self = {LOGGER => $logger, PREDICATES => $predicates};
bless($self, $class);
$self;
}
# Find or create the KB entity with a given name
sub intern {
my ($kb, $name, $source) = @_;
return $name if ref $name;
if ($name =~ /^"/) {
$kb->{LOGGER}->record_problem('STRING_USED_FOR_ENTITY', $name, $source);
return;
}
unless ($name =~ /^:?(Entity|Event|String).+$/i && $name !~ /-/) {
$kb->{LOGGER}->record_problem('ILLEGAL_NODE_NAME', $name, $source);
return;
}
unless ($name =~ /^:/) {
$kb->{LOGGER}->record_problem('COLON_OMITTED', $name, $source);
$name = ":$name";
}
my $entity = $kb->{ENTITIES}{$name};
unless (defined $entity) {
$entity = {NAME => $name};
$kb->{ENTITIES}{$name} = $entity;
}
$entity;
}
# Record that an entity has been used in a particular way (e.g., it's
# been given a type, it appears as the subject of a predicate, etc.)
sub entity_use {
my ($kb, $name, $use_type, $source) = @_;
$kb->{LOGGER}->NIST_die("Unknown use type: $use_type") unless $use_priority{$use_type};
my $entity = $kb->intern($name, $source);
# Do nothing if the name is malformed
return unless defined $entity;
$use_type = uc $use_type;
push(@{$entity->{USES}{$use_type}}, $source);
# When an error message refers to a particular entity, we'd like to
# give as clear a pointer to the entity as we can. This code keeps
# track of the "best" use of an entity for reporting purposes, with
# %use_priority providing the definition of "best."
my $thisuse = {USE_TYPE => $use_type, SOURCE => $source};
my $bestuse = $entity->{BESTUSE} || $thisuse;
$bestuse = $thisuse if $bestuse->{USE_TYPE} eq $thisuse->{USE_TYPE} &&
$bestuse->{SOURCE}{LINENUM} > $thisuse->{SOURCE}{LINENUM};
$bestuse = $thisuse if $use_priority{$bestuse->{USE_TYPE}} > $use_priority{$thisuse->{USE_TYPE}};
$entity->{BESTUSE} = $bestuse;
$entity;
}
# Assert that an entity has the given type
sub entity_typedef {
my ($kb, $name, $type, $def_type, $source) = @_;
$kb->{LOGGER}->NIST_die("Unknown def type: $def_type") unless $use_priority{$def_type};
my $entity = $kb->intern($name, $source);
# A type specification with multiple types doesn't give us explicit type information, but
# it does provide some information for immediate or later validation, so store this in
# POSSIBLETYPES
if (ref $type) {
my @types = keys %{$type};
if(@types > 1) {
push(@{$entity->{POSSIBLETYPES}}, {TYPES=>$type, SOURCE=>$source});
return;
}
$kb->{LOGGER}->NIST_die("type set with no entries in entity_typedef") unless @types;
$type = $types[0];
}
$type = lc $type;
# Only legal types may be asserted
unless ($PredicateSet::legal_node_types{$type}) {
$kb->{LOGGER}->record_problem('ILLEGAL_NODE_TYPE', $type, $source);
return;
}
# Check if the node name is compatible with its type
my $node_name = $entity->{NAME};
unless ( ($PredicateSet::legal_entity_types{$type} && $node_name =~ /^:Entity.+?/) ||
($PredicateSet::legal_event_types{$type} && $node_name =~ /^:Event.+?/) ||
($PredicateSet::legal_string_types{$type} && $node_name =~ /^:String.+?/)) {
$kb->{LOGGER}->record_problem('INCOMPATIBLE_NODE_NAME', $node_name, uc $type, $source);
return;
}
# Do nothing if the name is malformed
return unless defined $entity;
$def_type = uc $def_type;
push(@{$entity->{TYPEDEFS}{$type}{$def_type}}, $source);
my $thisdef = {DEFTYPE => $def_type, SOURCE => $source};
my $bestdef = $entity->{BESTDEF}{$type} || $thisdef;
# The best definition to point the user at is the one with the
# highest use_priority, or, if they're the same, the one that occurs
# first in the file
$bestdef = $thisdef if $bestdef->{DEFTYPE} eq $thisdef->{DEFTYPE} &&
$bestdef->{SOURCE}{LINENUM} > $thisdef->{SOURCE}{LINENUM};
$bestdef = $thisdef if $use_priority{$bestdef->{DEFTYPE}} > $use_priority{$thisdef->{DEFTYPE}};
$entity->{BESTDEF}{$type} = $bestdef;
$entity;
}
# Find the type of a given entity, if known
sub get_entity_type {
my ($kb, $entity, $source) = @_;
$entity = $kb->intern($entity, $source);
# We'll only get nil if the entity name is malformed, but return
# unknown nonetheless
return 'unknown' unless defined $entity;
my @types = keys %{$entity->{TYPEDEFS}};
return $types[0] if @types == 1;
return 'unknown' unless @types;
return 'multiple';
}
# Assert a particular triple into the KB
sub add_assertion {
my ($kb, $subject, $verb, $object, $provenance_string, $confidence, $source, $comment) = @_;
$comment = "" unless defined $comment;
my $logger = $kb->{LOGGER};
# First, normalize all of the triple components
my $subject_entity = $kb->intern($subject, $source);
unless (defined $subject_entity) {
$kb->{STATS}{REJECTED_ASSERTIONS}{NO_SUBJECT}++;
return;
}
$subject = $subject_entity->{NAME};
my $subject_type = $kb->get_entity_type($subject_entity);
$subject_type = undef unless $PredicateSet::legal_node_types{$subject_type};
my $realis;
($verb, $realis) = $kb->validate_realis($subject, $verb, $object, $source);
my $object_entity;
my $predicate = $kb->{PREDICATES}->get_predicate($verb, $subject_type, $source);
unless (ref $predicate) {
$kb->entity_use($subject_entity, 'SUBJECT', $source);
$kb->{STATS}{REJECTED_ASSERTIONS}{NO_PREDICATE}++;
return;
}
$verb = $predicate->get_name();
my %verbs_with_restricted_prov = (
mention => 1,
canonical_mention => 1,
nominal_mention => 1,
normalized_mention => 1,
pronominal_mention => 1,
likes => 1,
dislikes => 1,
is_liked_by => 1,
is_disliked_by => 1,
);
my $provenance = &get_provenance( {LOGGER => $logger,
SOURCE =>$source,
PROVENANCE_STRING => $provenance_string,
SUBJECT => $subject,
OBJECT => $object,
VERB => $verb});
foreach my $v(keys %verbs_with_restricted_prov) {
if($verb =~ /$v/ ) {
my %counts = $provenance->get_counts();
$kb->{LOGGER}->record_problem('TOO_MANY_PROVENANCE_TRIPLES_E', $counts{PREDICATE_JUSTIFICATION}, $verbs_with_restricted_prov{$v}, $source)
if($counts{PREDICATE_JUSTIFICATION}>$verbs_with_restricted_prov{$v});
}
}
# Record entity uses and type definitions. 'type' assertions are special-cased (as they have no object)
if ($verb eq 'type') {
$kb->entity_use($subject_entity, 'TYPEDEF', $source);
$kb->entity_typedef($subject_entity, $object, 'TYPEDEF', $source);
}
elsif ($verb eq 'link') {
$kb->entity_use($subject_entity, 'SUBJECT', $source);
# This tells us nothing about the type of the entity, so don't call entity_typedef
unless ($object =~ /^"?(.*?):(.*?)"?$/) {
$kb->{LOGGER}->record_problem('ILLEGAL_LINK_SPECIFICATION', $object, $source);
$kb->{STATS}{REJECTED_ASSERTIONS}{BAD_PREDICATE}++;
return;
}
# Remove double quotes if they're present
$object = "$1:$2";
}
else {
$kb->entity_use($subject_entity, 'SUBJECT', $source);
$kb->entity_typedef($subject_entity, $predicate->get_domain(), 'SUBJECT', $source);
if (&PredicateSet::is_compatible('string', $predicate->get_range()) && $predicate->get_name() =~ /mention/i) {
# Make sure this is a properly double quoted string
unless ($object =~ /^"(?>(?:(?>[^"\\]+)|\\.)*)"$/) {
# If not, complain and stick double quotes around it
# FIXME: Need to quote internal quotes; use String::Escape
$kb->{LOGGER}->record_problem('UNQUOTED_STRING', $object, $source);
$object =~ s/(["\\])/\\$1/g;
$object = "\"$object\"";
}
}
elsif (&PredicateSet::is_compatible($predicate->get_range(), \%PredicateSet::legal_node_types)) {
$object_entity = $kb->intern($object, $source);
unless (defined $object_entity) {
$kb->{STATS}{REJECTED_ASSERTIONS}{NO_OBJECT}++;
return;
}
$object = $object_entity->{NAME};
$kb->entity_use($object_entity, 'OBJECT', $source);
$kb->entity_typedef($object_entity, $predicate->get_range(), 'OBJECT', $source);
}
}
# Check for duplicate assertions
my $is_duplicate_of;
### DO NOT INCLUDE
# FIXME: There's gotta be a better way
# unless ($verb eq 'link') {
# unless ($verb eq 'mention' || $verb eq 'canonical_mention' || $verb eq 'type') {
### DO INCLUDE
unless ($verb eq 'mention' || $verb eq 'nominal_mention' || $verb eq 'canonical_mention' || $verb eq 'normalized_mention' || $verb eq 'type' || $verb eq 'link') {
existing:
# We don't consider inferred assertions to be duplicates
foreach my $existing (grep {!$_->{INFERRED}} $kb->get_assertions($subject, $verb, $object)) {
# Don't worry about duplicates of assertions that have already been omitted from the output
next if $existing->{OMIT_FROM_OUTPUT};
my $existing_provenance = &get_provenance($existing);
# If only one is allowed, any matching assertion is a duplicate
if ($multiple_attestations eq 'ONE') {
$is_duplicate_of = $existing;
last existing;
}
# In all other cases, it's not a duplicate unless it was extracted from the same document
next existing unless $existing_provenance->get_docid() eq $provenance->get_docid();
if ($multiple_attestations eq 'ONEPERDOC') {
$is_duplicate_of = $existing;
last existing;
}
# If "many" duplicate assertions are allowed, we only have a
# problem if it is being asserted about exactly the same mention
next if $existing_provenance->tostring() ne $provenance->tostring();
# This if is entirely unnecessary, but it makes everything look nice and symmetric
if ($multiple_attestations eq 'MANY') {
# This is an actual duplicate of exactly the same information
$is_duplicate_of = $existing;
last existing;
}
}
}
# Handle single-valued slots that are given more than one filler
my $is_multiple_of;
if ($predicate->{QUANTITY} eq 'single' && !$kb->{LOGGER}{IGNORE_WARNINGS}{MULTIPLE_FILLS_ENTITY}) {
foreach my $existing ($kb->get_assertions($subject, $verb)) {
# Again, ignore assertions that have already been omitted from the output
next if $existing->{OMIT_FROM_OUTPUT};
if (defined $object_entity && defined $existing->{OBJECT_ENTITY}) {
if ($object_entity != $existing->{OBJECT_ENTITY}) {
$is_multiple_of = $existing;
last;
}
}
elsif ($object ne $existing->{OBJECT}) {
$is_multiple_of = $existing;
last;
}
}
}
# Create the assertion, but don't record it yet. We do this before
# handling $is_duplicate_of because we may want to use the new
# assertion rather than the duplicate
my $assertion = {LOGGER => $kb->{LOGGER},
SUBJECT => $subject,
VERB => $verb,
OBJECT => $object,
PRINT_STRING => "$verb($subject, $object)",
SUBJECT_ENTITY => $subject_entity,
PREDICATE => $predicate,
REALIS => $realis,
OBJECT_ENTITY => $object_entity,
PROVENANCE_STRING => $provenance_string,
CONFIDENCE => $confidence,
SOURCE => $source,
COMMENT => $comment};
# Only output one of a set of multiples
if ($is_multiple_of) {
$kb->{LOGGER}->record_problem('MULTIPLE_FILLS_ENTITY', $subject, $verb, $source);
if ($confidence < $is_multiple_of->{CONFIDENCE}) {
$assertion->{OMIT_FROM_OUTPUT} = 'true';
}
elsif ($confidence > $is_multiple_of->{CONFIDENCE}) {
$is_multiple_of->{OMIT_FROM_OUTPUT} = 'true';
}
elsif ($assertion->{SOURCE}{LINENUM} < $is_multiple_of->{SOURCE}{LINENUM}) {
$is_multiple_of->{OMIT_FROM_OUTPUT} = 'true';
}
else {
$assertion->{OMIT_FROM_OUTPUT} = 'true';
}
}
# Now we can decide how to handle the duplicate
if ($is_duplicate_of) {
# Make sure this isn't exactly the same assertion
my $is_duplicate_of_prov = &get_provenance($is_duplicate_of);
if ($provenance->tostring() eq $is_duplicate_of_prov->tostring()) {
$kb->{LOGGER}->record_problem('DUPLICATE_ASSERTION', "$is_duplicate_of->{SOURCE}{FILENAME} line $is_duplicate_of->{SOURCE}{LINENUM}", $source);
$kb->{STATS}{REJECTED_ASSERTIONS}{DUPLICATE}++;
return;
}
$kb->{LOGGER}->record_problem('DUPLICATE_ASSERTION', "$is_duplicate_of->{SOURCE}{FILENAME} line $is_duplicate_of->{SOURCE}{LINENUM}", $source);
# Keep the duplicate with higher confidence. If the confidences are the same, keep the earlier one
if ($confidence < $is_duplicate_of->{CONFIDENCE}) {
$assertion->{OMIT_FROM_OUTPUT} = 'true';
}
elsif ($confidence > $is_duplicate_of->{CONFIDENCE}) {
$is_duplicate_of->{OMIT_FROM_OUTPUT} = 'true';
}
elsif ($assertion->{SOURCE}{LINENUM} < $is_duplicate_of->{SOURCE}{LINENUM}) {
$is_duplicate_of->{OMIT_FROM_OUTPUT} = 'true';
}
else {
$assertion->{OMIT_FROM_OUTPUT} = 'true';
}
}
# Record the assertion in various places for easy retrieval
if(defined $predicate && ($predicate->{NAME} eq 'mention' || $predicate->{NAME} eq 'nominal_mention') ) {
$kb->{MENTIONS2}{$provenance->get_docid()}{$provenance->{PREDICATE_JUSTIFICATION}->toshortstring()}{$object}{$subject} = $assertion;
$kb->{MENTIONS1}{$provenance->get_docid()}{$provenance->{PREDICATE_JUSTIFICATION}->toshortstring()}{$subject} = $assertion;
push(@{$kb->{MENTIONS0}{$provenance->get_docid()}{$provenance->{PREDICATE_JUSTIFICATION}->toshortstring()}}, $assertion);
}
if(defined $predicate && $predicate->{NAME} eq 'pronominal_mention') {
$kb->{PRONOMINAL_MENTIONS}{$provenance->get_docid()}{$provenance->{PREDICATE_JUSTIFICATION}->toshortstring()}{$subject} = $assertion;
}
push(@{$kb->{DOCIDS}{$subject}{$verb}{$provenance->get_docid()}}, $assertion)
if defined $predicate && ($predicate->{NAME} eq 'mention' || $predicate->{NAME} eq 'canonical_mention' || $predicate->{NAME} eq 'nominal_mention' || $predicate->{NAME} eq 'pronominal_mention');
if ($predicate->{NAME} eq 'link') {
$assertion->{OBJECT} =~ /^(.*?):(.*)$/;
push(@{$kb->{LINKS}{$subject}{$1}}, $2);
}
push(@{$kb->{ASSERTIONS3}{$subject}{$verb}{$object}}, $assertion);
push(@{$kb->{ASSERTIONS2}{$subject}{$verb}}, $assertion);
push(@{$kb->{ASSERTIONS1}{$subject}}, $assertion);
push(@{$kb->{ASSERTIONS0}}, $assertion);
# We're definitely adding this assertion, so track assertion statistics
# $kb->{STATS}{NUM_ASSERTIONS}++;
# $kb->{STATS}{PREDICATES}{$verb || "NO_VERB"}++;
# $kb->{STATS}{SUBJECT_TYPE}{$subject_type || "UNDEFINED"}++;
$assertion;
}
# Select a global canonical mention for this entity
sub get_best_mention {
my ($kb, $entity, $docid) = @_;
my $best = "";
if (defined $docid) {
my @mentions = $kb->get_assertions($entity, 'canonical_mention', undef, $docid);
if (@mentions == 1) {
$best = $mentions[0]{OBJECT};
}
else {
print $error_output "Oh dear, Wrong number of canonical mentions in document $docid\n";
}
} else {
my @mentions = $kb->get_assertions($entity, 'canonical_mention');
foreach my $mention (@mentions) {
$best = $mention->{OBJECT} if length($mention->{OBJECT}) > length($best);
}
}
$best;
}
# More handy accessors
sub get_subjects { my ($kb) = @_; keys %{$kb->{ASSERTIONS1}} }
sub get_verbs { my ($kb, $subject) = @_; keys %{$kb->{ASSERTIONS2}{$subject}} }
sub get_objects { my ($kb, $subject, $verb) = @_; keys %{$kb->{ASSERTIONS3}{$subject}{$verb}} }
sub get_docids { my ($kb, $subject, $verb) = @_; keys %{$kb->{DOCIDS}{$subject}{$verb}} }
# Find all assertions that match a given pattern
sub get_assertions {
my ($kb, $subject, $verb, $object, $docid) = @_;
$kb->{LOGGER}->NIST_die("get_assertions given both object and docid")
if defined $object && defined $docid;
$subject = $subject->{NAME} if ref $subject;
$verb = $verb->{VERB} if ref $verb;
$object = $object->{NAME} if ref $object;
return(@{$kb->{ASSERTIONS3}{$subject}{$verb}{$object} || []}) if defined $object;
return(@{$kb->{DOCIDS}{$subject}{$verb}{$docid} || []}) if defined $docid;
return(map {@$_} values %{$kb->{ASSERTIONS3}{$subject}{$verb} || {}}) if defined $verb;
#return(@{$kb->{ASSERTIONS2}{$subject}{$verb} || []}) if defined $verb;
return(@{$kb->{ASSERTIONS1}{$subject} || []}) if defined $subject;
return(@{$kb->{ASSERTIONS0} || []});
}
sub get_links {
my ($kb, $subject, $kb_target) = @_;
return(@{$kb->{LINKS}{$subject}{$kb_target}});
}
sub get_provenance {
my ($assertion) = @_;
my $provenance;
if(lc $assertion->{VERB} eq "type" || lc $assertion->{VERB} eq "link"){
$provenance = ProvenanceList->new($assertion->{LOGGER}, $assertion->{SOURCE});
}
else{
$provenance = ProvenanceList->new($assertion->{LOGGER}, $assertion->{SOURCE},
$assertion->{PROVENANCE_STRING}, $assertion->{SUBJECT},
$assertion->{OBJECT}, $assertion->{VERB});
}
$provenance;
}
sub mention_exists {
my ($kb, $entity, $provenance, $pronominal_mention_flag) = @_;
my $assertion;
if($kb->{MENTIONS1}{$provenance->get_docid()}{$provenance->toshortstring()}{$entity}) {
$assertion = $kb->{MENTIONS1}{$provenance->get_docid()}{$provenance->toshortstring()}{$entity};
}
elsif($pronominal_mention_flag) {
$assertion = $kb->{PRONOMINAL_MENTIONS}{$provenance->get_docid()}{$provenance->toshortstring()}{$entity}
if($kb->{PRONOMINAL_MENTIONS}{$provenance->get_docid()}{$provenance->toshortstring()}{$entity});
}
$assertion;
}
#####################################################################################
# Error checking and inferred relations
#####################################################################################
# Report entities that don't have exactly one type
sub check_entity_types {
my ($kb) = @_;
while (my ($name, $entity) = each %{$kb->{ENTITIES}}) {
my $type = $kb->get_entity_type($entity);
if ($type eq 'unknown') {
$kb->{LOGGER}->record_problem('UNKNOWN_TYPE', $name, $entity->{BESTUSE}{SOURCE});
}
elsif ($type eq 'multiple') {
$kb->{LOGGER}->record_problem('MULTITYPED_ENTITY', $name,
join(", ", map {"$_ at line $entity->{BESTDEF}{$_}{SOURCE}{LINENUM}"}
sort keys %{$entity->{BESTDEF}}), 'NO_SOURCE');
}
# Check if possible types are compatible with declared type
if(exists $entity->{POSSIBLETYPES}) {
foreach my $possible_types(@{$entity->{POSSIBLETYPES}}) {
$kb->{LOGGER}->record_problem('MULTITYPED_ENTITY', $name,
join(" or ", map {"$_"} sort keys %{$possible_types->{TYPES}})
. " at line " . $possible_types->{SOURCE}{LINENUM} .
" and $type at line " . $entity->{BESTUSE}{SOURCE}{LINENUM}
, 'NO_SOURCE')
unless exists $possible_types->{TYPES}{$type};
}
}
}
}
# Make sure that every entity that has been mentioned or used somewhere has a typedef
sub check_definitions {
my ($kb) = @_;
while (my ($name, $entity) = each %{$kb->{ENTITIES}}) {
# I suspect that having multiple types here (PER, ORG, GPE) is at this point vestigial
foreach my $type (keys %{$entity->{BESTDEF}}) {
# An entity that is used in any way must have an actual typedef somewhere
$kb->{LOGGER}->record_problem('MISSING_TYPEDEF', $name, $entity->{BESTDEF}{$type}{SOURCE})
unless $entity->{TYPEDEFS}{$type}{TYPEDEF};
}
}
}
# Make sure that the mention strings correspond to the text found at the given provenance
#
# This function optionally checks for the consistency of mention string found in the KB with
# the text found at the given offset in the document. This check is performed if the link to file
# containing the document text is provided in the doclength file provided using -docs switch.
sub check_mention_string {
my ($kb) = @_;
foreach my $subject ($kb->get_subjects()) {
my %docids;
foreach my $docid ($kb->get_docids($subject, 'mention'),
$kb->get_docids($subject, 'nominal_mention'),
$kb->get_docids($subject, 'pronominal_mention'),
$kb->get_docids($subject, 'canonical_mention')) {
$docids{$docid}++;
}
unless (keys %docids) {
$kb->{LOGGER}->record_problem('NO_MENTIONS', $subject, 'NO_SOURCE');
next;
}
foreach my $docid (keys %docids) {
my @mentions = ($kb->get_assertions($subject, 'mention', undef, $docid),
$kb->get_assertions($subject, 'nominal_mention', undef, $docid),
$kb->get_assertions($subject, 'pronominal_mention', undef, $docid),
$kb->get_assertions($subject, 'canonical_mention', undef, $docid));
# Read the file
my $filename;
if(@mentions) {
my $mention0_provenance = &get_provenance($mentions[0]);
$filename = $mention0_provenance->get_docfile();
}
next unless $filename;
my $entire_file;
{
local $/ = undef;
open(my $infile, "<:utf8", $filename) or $kb->{LOGGER}->NIST_die("Source document expected at $filename: $!");
$entire_file = <$infile>;
close $infile;
}
# Check all mentions
foreach my $mention(@mentions) {
my $mention_string = &main::remove_quotes($mention->{OBJECT});
my $mention_string_from_file;
my $mention_provenance = &get_provenance($mention);
my $start = $mention_provenance->{PREDICATE_JUSTIFICATION}->get_start();
my $end = $mention_provenance->{PREDICATE_JUSTIFICATION}->get_end();
$mention_string_from_file = substr($entire_file, $start, $end-$start+1);
my $normalized_mention_string_from_file = $mention_string_from_file;
my $normalized_mention_string = $mention_string;
$normalized_mention_string =~ s/\s+/ /g;
$normalized_mention_string_from_file =~ s/\s+/ /g;
$kb->{LOGGER}->record_problem('INACCURACTE_MENTION_STRING',
$mention_string,
$mention_provenance->{PREDICATE_JUSTIFICATION}->tostring(),
$mention->{SOURCE})
if $normalized_mention_string ne $normalized_mention_string_from_file;
}
}
}
}
# Make sure that every assertion also has an asserted inverse
sub assert_inverses {
my ($kb) = @_;
foreach my $assertion ($kb->get_assertions()) {
next if $assertion->{OBJECT} =~ /:String/;
next unless $assertion->{OBJECT_ENTITY};
next unless ref $assertion->{PREDICATE};
next unless &PredicateSet::is_compatible($assertion->{PREDICATE}{RANGE}, \%PredicateSet::legal_node_types);
# Accomodating the requirement for 2017
# Duplicate assertions are allowed therefore generate missing inverses for all duplicates
# An assertion is a duplicate if subject, verb, object matches but the provenance differ
unless (grep {$assertion->{PROVENANCE_STRING} eq $_->{PROVENANCE_STRING}}
$kb->get_assertions($assertion->{OBJECT}, $assertion->{PREDICATE}{INVERSE_NAME}, $assertion->{SUBJECT})) {
$kb->{LOGGER}->record_problem('MISSING_INVERSE', $assertion->{PREDICATE}->get_name(),
$assertion->{SUBJECT}, $assertion->{OBJECT}, $assertion->{SOURCE});
# Assert the inverse if it's not already there
my $inverse_name = $assertion->{PREDICATE}{INVERSE_NAME};
$inverse_name .= ".".$assertion->{REALIS} if $assertion->{REALIS};
my $provenance = &get_provenance($assertion);
if(exists $provenance->{FILLER_STRING} && defined $provenance->{FILLER_STRING}) {
my $docid = $provenance->get_docid();
my $subject = $assertion->{SUBJECT};
my ($canonical_mention) = $kb->get_assertions($subject, 'canonical_mention', undef, $docid);
$kb->{LOGGER}->record_problem('MISSING_CANONICAL_E', $subject, $docid, $assertion->{SOURCE})
unless ($canonical_mention);
my $canonical_mention_prov = &get_provenance($canonical_mention);
$provenance->{FILLER_STRING} = $canonical_mention_prov->{PREDICATE_JUSTIFICATION};
$kb->{LOGGER}->record_problem('MISSING_FILLER_STRING_PROV',
$provenance->tooriginalstring(),
$assertion->{SOURCE}) unless $provenance->{FILLER_STRING};
if($provenance->{FILLER_STRING}) {
my $filler_string = $provenance->{FILLER_STRING}->tooriginalstring();
$provenance->{ORIGINAL_STRING} =~ s/^(.*?)\;/$filler_string;/;
}
}
my $inverse = $kb->add_assertion($assertion->{OBJECT}, $inverse_name, $assertion->{SUBJECT},
$provenance->tooriginalstring(), $assertion->{CONFIDENCE}, $assertion->{SOURCE});
# And flag this as an inferred relation
$inverse->{INFERRED} = 'true';
# Make sure the visibility of the assertion and its inverse is in sync
$assertion->{OMIT_FROM_OUTPUT} = 'true' if $inverse->{OMIT_FROM_OUTPUT};
$inverse->{OMIT_FROM_OUTPUT} = 'true' if $assertion->{OMIT_FROM_OUTPUT};
}
}
}
# Make sure that mentions and canonical_mentions are in sync
sub assert_mentions {
my ($kb, $canonical_mentions_allowed) = @_;
foreach my $subject ($kb->get_subjects()) {
my %docids;
foreach my $docid ($kb->get_docids($subject, 'mention'),
$kb->get_docids($subject, 'nominal_mention'),
$kb->get_docids($subject, 'canonical_mention')) {
$docids{$docid}++;
}
unless (keys %docids) {
$kb->{LOGGER}->record_problem('NO_MENTIONS', $subject, 'NO_SOURCE');
next;
}
foreach my $docid (keys %docids) {
my %mentions = map {$_->{PROVENANCE_STRING} => $_} $kb->get_assertions($subject, 'mention', undef, $docid);
my %nominal_mentions = map {$_->{PROVENANCE_STRING} => $_} $kb->get_assertions($subject, 'nominal_mention', undef, $docid);
my %canonical_mentions = map {$_->{PROVENANCE_STRING} => $_} $kb->get_assertions($subject, 'canonical_mention', undef, $docid);
if($canonical_mentions_allowed && !keys %canonical_mentions && ( (scalar keys %mentions) + (scalar keys %nominal_mentions) > 1)) {
$kb->{LOGGER}->record_problem('MULTIPLE_MENTIONS_NO_CANONICAL', $subject, $docid, 'NO_SOURCE');
# There are multiple named/nominal mentions but no canonical.
}
elsif ($canonical_mentions_allowed && !keys %canonical_mentions && keys %mentions) {
$kb->{LOGGER}->record_problem('MISSING_CANONICAL', $subject, $docid, 'NO_SOURCE');
# Pick the only named mention as the canonical mention.
my ($mention) = values %mentions;
my $realis = "";
$realis = ".".$mention->{REALIS} if $mention->{REALIS};
my $assertion = $kb->add_assertion($mention->{SUBJECT}, "canonical_mention$realis", $mention->{OBJECT},
$mention->{PROVENANCE_STRING}, $mention->{CONFIDENCE}, $mention->{SOURCE});
$assertion->{INFERRED} = 'true';
}
elsif ($canonical_mentions_allowed && !keys %canonical_mentions && keys %nominal_mentions) {
$kb->{LOGGER}->record_problem('MISSING_CANONICAL', $subject, $docid, 'NO_SOURCE');
# Pick the only nominal mention as the canonical mention.
my ($mention) = values %nominal_mentions;
my $realis = "";
$realis = ".".$mention->{REALIS} if $mention->{REALIS};
my $assertion = $kb->add_assertion($mention->{SUBJECT}, "canonical_mention$realis", $mention->{OBJECT},
$mention->{PROVENANCE_STRING}, $mention->{CONFIDENCE}, $mention->{SOURCE});
$assertion->{INFERRED} = 'true';
}
elsif ($canonical_mentions_allowed && keys %canonical_mentions > 1) {
$kb->{LOGGER}->record_problem('MULTIPLE_CANONICAL', $subject, $docid, 'NO_SOURCE');
}
while (my ($string, $canonical_mention) = each %canonical_mentions) {
# Find the mention that matches this canonical mention, if any
my $mention = $mentions{$string};
my $nominal_mention = $nominal_mentions{$string};
my $realis = "";
$realis = ".".$canonical_mention->{REALIS} if $canonical_mention->{REALIS};
unless ($mention || $nominal_mention) {
# Canonical mention without a corresponding mention
$kb->{LOGGER}->record_problem('UNASSERTED_MENTION', $canonical_mention->{PRINT_STRING}, $docid, $canonical_mention->{SOURCE});
my $assertion = $kb->add_assertion($canonical_mention->{SUBJECT}, "mention$realis", $canonical_mention->{OBJECT},
$canonical_mention->{PROVENANCE_STRING},
$canonical_mention->{CONFIDENCE},
$canonical_mention->{SOURCE});
$assertion->{INFERRED} = 'true';
}
}
}
}
}
# Make sure that all confidence values are legal
sub check_confidence {
my ($kb) = @_;
foreach my $assertion ($kb->get_assertions()) {
if (defined $assertion->{CONFIDENCE}) {
# Special case a confidence value of "1" to make it a warning only
if ($assertion->{CONFIDENCE} eq '1') {
$kb->{LOGGER}->record_problem('MISSING_DECIMAL_POINT', $assertion->{CONFIDENCE}, $assertion->{SOURCE});
$assertion->{CONFIDENCE} = '1.0';
}
unless ($assertion->{CONFIDENCE} =~ /^(?:1\.0*)$|^(?:0?\.[0-9]*[1-9][0-9]*)$/) {
$kb->{LOGGER}->record_problem('ILLEGAL_CONFIDENCE_VALUE', $assertion->{CONFIDENCE}, $assertion->{SOURCE});
$assertion->{CONFIDENCE} = '1.0';
}
}
}
}
# Check:
# (1) if assertions invloving string object entities have filler string present
# (2) if *mention* assertions have only predicate_justification provided
# (3) if the same provenance has multiple strings in the mentions, no effort is made to check if the offsets indeed represent the string in actual document
# (4) if filler_string is a mention of the object
# (5) if the provenance of a sentiment relation is a mention of the target
# (6) if the provenance of a normalized mention is a mention of the subject
# (7) if the BASE_FILLER is NILL (NILL is not an allowed value for BASE_FILLER provenance for event assertions)
sub check_provenance_lists {
my ($kb) = @_;
foreach my $docid(keys %{$kb->{MENTIONS2}}) {
foreach my $span(keys %{$kb->{MENTIONS2}{$docid}}) {
if (scalar keys (%{$kb->{MENTIONS2}{$docid}{$span}}) > 1) {
$kb->{LOGGER}->record_problem('MULTIPLE_STRINGS_FOR_PROV', $kb->{MENTIONS0}{$docid}{$span}[0]{PROVENANCE_STRING},
join(", ", map {"$_->{OBJECT} at line $_->{SOURCE}{LINENUM}"}
sort {$a->{SOURCE}{LINENUM} <=> $b->{SOURCE}{LINENUM}} @{$kb->{MENTIONS0}{$docid}{$span}}), 'NO_SOURCE');
}
}
}
foreach my $assertion(@{$kb->{ASSERTIONS0}}) {
my $assertion_prov = &get_provenance($assertion);
$kb->{LOGGER}->record_problem('MISSING_FILLER_STRING_PROV',
$assertion_prov->tooriginalstring(),
$assertion->{SOURCE})
if ($assertion->{OBJECT_ENTITY} &&
$kb->get_entity_type($assertion->{OBJECT_ENTITY}) eq "string" &&
! $assertion_prov->{FILLER_STRING});
$kb->{LOGGER}->record_problem('UNEXPECTED_PROVENANCE',
$assertion_prov->tooriginalstring(),
$assertion->{SOURCE})
if ($assertion->{VERB} =~ /mention/ && (!$assertion_prov->{PREDICATE_JUSTIFICATION} ||
$assertion_prov->{FILLER_STRING} ||
$assertion_prov->{BASE_FILLER} ||
$assertion_prov->{ADDITIONAL_JUSTIFICATION}));
my @fields = qw(FILLER_STRING);
foreach my $field(@fields) {
$kb->{LOGGER}->record_problem('MISSING_MENTION_E', $field, $assertion_prov->{$field}->tooriginalstring(), $assertion->{OBJECT}, $assertion_prov->{WHERE})
if(exists $assertion_prov->{$field} &&
defined $assertion_prov->{$field} &&
!$kb->mention_exists($assertion->{OBJECT}, $assertion_prov->{$field}));
}
# Verify if the provenance in sentiment assertion is a mention of the target (i.e. object for like and subject for dislike assertion)
if($assertion->{VERB} eq "likes" || $assertion->{VERB} eq "dislikes") {
$kb->{LOGGER}->record_problem('MISSING_MENTION_E', 'PREDICATE_JUSTIFICATION', $assertion_prov->{PREDICATE_JUSTIFICATION}->tooriginalstring(), $assertion->{OBJECT}, $assertion_prov->{WHERE})
if(exists $assertion_prov->{PREDICATE_JUSTIFICATION} &&
defined $assertion_prov->{PREDICATE_JUSTIFICATION} &&
!$kb->mention_exists($assertion->{OBJECT}, $assertion_prov->{PREDICATE_JUSTIFICATION}, "PRONOMINAL_MENTIONS"));
}
elsif($assertion->{VERB} eq "is_liked_by" || $assertion->{VERB} eq "is_disliked_by") {
$kb->{LOGGER}->record_problem('MISSING_MENTION_E', 'PREDICATE_JUSTIFICATION', $assertion_prov->{PREDICATE_JUSTIFICATION}->tooriginalstring(), $assertion->{SUBJECT}, $assertion_prov->{WHERE})
if(exists $assertion_prov->{PREDICATE_JUSTIFICATION} &&
defined $assertion_prov->{PREDICATE_JUSTIFICATION} &&
!$kb->mention_exists($assertion->{SUBJECT}, $assertion_prov->{PREDICATE_JUSTIFICATION}, "PRONOMINAL_MENTIONS"));
}
if($assertion->{VERB} eq "normalized_mention"){
$kb->{LOGGER}->record_problem('MISSING_MENTION_E', 'Provenance', $assertion_prov->{PREDICATE_JUSTIFICATION}->tooriginalstring(), $assertion->{SUBJECT}, $assertion_prov->{WHERE})
unless $kb->mention_exists($assertion->{SUBJECT}, $assertion_prov->{PREDICATE_JUSTIFICATION});
}
# check if the BASE_FILLER is NILL (NILL is not an allowed value for BASE_FILLER provenance for event assertions)
if($assertion->{SUBJECT} =~ /^:Event.+$/ or $assertion->{OBJECT} =~ /^:Event.+$/) {
next if $assertion->{VERB} eq "type" or $assertion->{VERB} =~ /mention/;
$kb->{LOGGER}->record_problem('UNEXPECTED_BASE_FILLER', 'NIL', $assertion_prov->{WHERE})
if (not defined $assertion_prov->{BASE_FILLER} ) or ($assertion_prov->{BASE_FILLER}->tooriginalstring() eq 'NIL');
}
}
}
# Check if realis is present for Event assertions
sub validate_realis {
my ($kb, $subject, $verb, $object, $source) = @_;
my ($retval_verb, $retval_realis, $domain);
# remove the domain from the potential_verb
if($verb =~ /^(.*?):/) {
$domain = $1;
$verb =~ s/^.*?://;
}
my %acceptable_realis = map {$_=>1} qw(actual generic other);
my @elements = split(/\./, $verb);
if(@elements > 1) {
# there is a dot in the verb
# a realis could potentially be there
my $potential_realis = $elements[$#elements];
my $potential_verb = join(".", map {$elements[$_]} (0..$#elements-1));
# There are following possible cases
# and notice that we are not going to check the legitimacy of the verb here
# if verb is a type
if($potential_verb eq "type") {
# throw an error because the realis should not be provided
$kb->{LOGGER}->record_problem("UNEXPECTED_REALIS", "none", $potential_realis, $source);
# if the value of realis is illegal
$kb->{LOGGER}->record_problem("ILLEGAL_REALIS", $potential_realis, $source)
unless (exists $acceptable_realis{$potential_realis});
$retval_verb = $potential_verb;
$retval_realis = $potential_realis;
}
# if both the verb and the realis are legitimate
# then check if the realis was required
elsif(exists $acceptable_realis{$potential_realis} && exists $kb->{PREDICATES}{$potential_verb}) {
# throw an error if the realis should not be provided
$kb->{LOGGER}->record_problem("UNEXPECTED_REALIS", "none", $potential_realis, $source)
unless(($subject =~ /^:Event/ || $object =~ /^:Event/) && $potential_verb ne "type");
$retval_verb = $potential_verb;
$retval_realis = $potential_realis;
}
# if none are legitimate ------ (A)
# then check if the original verb is legitimate
# - in this case the realis is missing
# - therefore verify if realis was required
# otherwise there are possibly two problems here:
# (1) the realis is not legitimate,
# (2) the realis could be unexpected
elsif(not exists $acceptable_realis{$potential_realis} && not exists $kb->{PREDICATES}{$potential_verb}) {
if(exists $kb->{PREDICATES}{$potential_verb.".".$potential_realis}) {
# if the original verb is legitimate
# the realis is not there, throw an error if it was required
$kb->{LOGGER}->record_problem("UNEXPECTED_REALIS", "actual, generic, or other", "none", $source)
if(($subject =~ /^:Event/ || $object =~ /^:Event/) && $potential_verb ne "type");
}
else{
# the realis is not legitimate
$kb->{LOGGER}->record_problem("ILLEGAL_REALIS", $potential_realis, $source);
# throw an error if the realis should not be provided
$kb->{LOGGER}->record_problem("UNEXPECTED_REALIS", "none", $potential_realis, $source)
unless(($subject =~ /^:Event/ || $object =~ /^:Event/) && $potential_verb ne "type");
}
$retval_verb = $potential_verb.".".$potential_realis;
}
# if verb is legitimate but the realis is not
elsif(not exists $acceptable_realis{$potential_realis} && exists $kb->{PREDICATES}{$potential_verb}) {
# Illegal realis used
$kb->{LOGGER}->record_problem("ILLEGAL_REALIS", $potential_realis, $source);
# throw an error if the realis should not be provided
$kb->{LOGGER}->record_problem("UNEXPECTED_REALIS", "none", $potential_realis, $source)
if(($subject =~ /^:Event/ || $object =~ /^:Event/) && $potential_verb ne "type");
$retval_verb = $potential_verb;
$retval_realis = $potential_realis;
}
# if verb is not legitimate but the realis is
elsif(exists $acceptable_realis{$potential_realis} && not exists $kb->{PREDICATES}{$potential_verb}) {
# throw an error if the realis should not be provided
$kb->{LOGGER}->record_problem("UNEXPECTED_REALIS", "none", $potential_realis, $source)
if(($subject =~ /^:Event/ || $object =~ /^:Event/) && $potential_verb ne "type");
$retval_verb = $potential_verb;
$retval_realis = $potential_realis;
}
}
else {
my $potential_verb = $verb;
# the realis is not there, throw an error if it was required
# notice that we are not verfying here if the verb is acceptable
$kb->{LOGGER}->record_problem("UNEXPECTED_REALIS", "actual, generic, or other", "none", $source)
if(($subject =~ /^:Event/ || $object =~ /^:Event/) && $potential_verb ne "type");
$retval_verb = $potential_verb;
}
$retval_verb = "$domain:$retval_verb" if $domain;
($retval_verb, $retval_realis);
}
my @do_not_check_endpoints = (
'type',
'mention',
'canonical_mention',
'link',
);
my %do_not_check_endpoints = map {$_ => $_} @do_not_check_endpoints;
# Each endpoint of a relation that is an entity must be attested in
# a document that attests to the relation
sub check_relation_endpoints {
my ($kb) = @_;
foreach my $assertion ($kb->get_assertions()) {
next unless ref $assertion->{PREDICATE};
next if $do_not_check_endpoints{$assertion->{PREDICATE}{NAME}};
my $provenance = &get_provenance($assertion);
if (defined $assertion->{SUBJECT_ENTITY}) {
my @subject_mentions;
my $docid = $provenance->get_docid();
unless(@subject_mentions) {
@subject_mentions = $kb->get_assertions($assertion->{SUBJECT_ENTITY}, 'mention', undef, $docid);
@subject_mentions = $kb->get_assertions($assertion->{SUBJECT_ENTITY}, 'nominal_mention', undef, $docid)
unless @subject_mentions;
}
$kb->{LOGGER}->record_problem('UNATTESTED_RELATION_ENTITY',
$assertion->{PRINT_STRING},
$assertion->{SUBJECT_ENTITY}{NAME},
$provenance->tooriginalstring(),
$assertion->{SOURCE})
unless @subject_mentions;
}
if (defined $assertion->{OBJECT_ENTITY}) {
my @object_mentions;
my $docid = $provenance->get_docid();
unless(@object_mentions) {
@object_mentions = $kb->get_assertions($assertion->{OBJECT_ENTITY}, 'mention', undef, $docid);
@object_mentions = $kb->get_assertions($assertion->{OBJECT_ENTITY}, 'nominal_mention', undef, $docid)
unless @object_mentions;
}
$kb->{LOGGER}->record_problem('UNATTESTED_RELATION_ENTITY',
$assertion->{PRINT_STRING},
$assertion->{OBJECT_ENTITY}{NAME},
$provenance->tooriginalstring(),
$assertion->{SOURCE})
unless @object_mentions;
}
}
}
# Perform a number of basic checks to make sure that the KB is well-formed
sub check_integrity {
my ($kb, $predicate_constraints) = @_;
$kb->check_entity_types();
$kb->check_definitions();
$kb->check_provenance_lists();
$kb->check_mention_string();
$kb->assert_inverses();
$kb->assert_mentions(!defined $predicate_constraints || $predicate_constraints->{'canonical_mention'});
$kb->check_relation_endpoints();
$kb->check_confidence();
}
# Print out all assertions