build.gradle

group = 'de.mfo.jsurf'
version = '0.3.0'

apply plugin: 'application'
apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'maven-publish'

targetCompatibility = 1.7
sourceCompatibility = 1.7

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'javax.vecmath', name: 'vecmath', version: '1.5.2'
    compile 'org.antlr:antlr-runtime:3.4@jar'
    compile 'commons-cli:commons-cli:1.2'
    testCompile group: 'junit', name: 'junit', version: '4.11'
}

task wrapper(type: Wrapper) {
	gradleVersion = '1.12'
}

task sourceJar(type: Jar) {
        from sourceSets.main.allJava
}

jar {
    manifest {
        attributes( "Implementation-Title": project.group,
                   "Implementation-Version": project.version,
                   "Implementation-Vendor": "Mathematisches Forschungsinstitut Oberwolfach" )
    }
}

publishing {
        publications {
                mavenJava(MavenPublication) {
                        from components.java

                        artifact sourceJar {
                                classifier "sources"
                        }
                }
        }
        repositories {
                maven {
                        // change if necessary
                        url "$projectDir/../maven-repository"
                }
        }
}

mainClassName = "de.mfo.jsurf.Main"

run {
	args = [ "-s", "512", "--gui", "examples/record_kummerquartic.jsurf" ]
}