KubesmasTreeESP32.ino

#include <FastLED.h>
#include <Arduino.h>
#include <WiFi.h>
#include <WiFiMulti.h>
#include <HTTPClient.h>

#define USE_SERIAL Serial

#define NUM_LEDS 150
#define DATA_PIN 13
#define SWITCH_PIN 21

// Illumination Pattern
#define STATIC 1
#define WAVE 2
#define RANDOM 3

// Run Mode
#define WIFI 0
#define STAND_ALONE 1

// Parameters
#define WAIT_TIME_MILLIS 5000
#define WAVE_INTERVAL 8
#define WAVE_COLOR_VARIATION_WIDTH 1
#define RANDOM_INTERVAL 100
#define BRIGHTNESS 255
#define POD_MAGNIFICATION 5
#define SPECIAL_INTERVAL (2000/NUM_LEDS)
#define SPECIAL_WAIT 2000
#define NUM_PODS 15

WiFiMulti wifiMulti;

CRGB leds[NUM_LEDS];
int run_mode;

/*
  const char* ca = \
  "-----BEGIN CERTIFICATE-----\n" \
  "MIIEkjCCA3qgAwIBAgIQCgFBQgAAAVOFc2oLheynCDANBgkqhkiG9w0BAQsFADA/\n" \
  "MSQwIgYDVQQKExtEaWdpdGFsIFNpZ25hdHVyZSBUcnVzdCBDby4xFzAVBgNVBAMT\n" \
  "DkRTVCBSb290IENBIFgzMB4XDTE2MDMxNzE2NDA0NloXDTIxMDMxNzE2NDA0Nlow\n" \
  "SjELMAkGA1UEBhMCVVMxFjAUBgNVBAoTDUxldCdzIEVuY3J5cHQxIzAhBgNVBAMT\n" \
  "GkxldCdzIEVuY3J5cHQgQXV0aG9yaXR5IFgzMIIBIjANBgkqhkiG9w0BAQEFAAOC\n" \
  "AQ8AMIIBCgKCAQEAnNMM8FrlLke3cl03g7NoYzDq1zUmGSXhvb418XCSL7e4S0EF\n" \
  "q6meNQhY7LEqxGiHC6PjdeTm86dicbp5gWAf15Gan/PQeGdxyGkOlZHP/uaZ6WA8\n" \
  "SMx+yk13EiSdRxta67nsHjcAHJyse6cF6s5K671B5TaYucv9bTyWaN8jKkKQDIZ0\n" \
  "Z8h/pZq4UmEUEz9l6YKHy9v6Dlb2honzhT+Xhq+w3Brvaw2VFn3EK6BlspkENnWA\n" \
  "a6xK8xuQSXgvopZPKiAlKQTGdMDQMc2PMTiVFrqoM7hD8bEfwzB/onkxEz0tNvjj\n" \
  "/PIzark5McWvxI0NHWQWM6r6hCm21AvA2H3DkwIDAQABo4IBfTCCAXkwEgYDVR0T\n" \
  "AQH/BAgwBgEB/wIBADAOBgNVHQ8BAf8EBAMCAYYwfwYIKwYBBQUHAQEEczBxMDIG\n" \
  "CCsGAQUFBzABhiZodHRwOi8vaXNyZy50cnVzdGlkLm9jc3AuaWRlbnRydXN0LmNv\n" \
  "bTA7BggrBgEFBQcwAoYvaHR0cDovL2FwcHMuaWRlbnRydXN0LmNvbS9yb290cy9k\n" \
  "c3Ryb290Y2F4My5wN2MwHwYDVR0jBBgwFoAUxKexpHsscfrb4UuQdf/EFWCFiRAw\n" \
  "VAYDVR0gBE0wSzAIBgZngQwBAgEwPwYLKwYBBAGC3xMBAQEwMDAuBggrBgEFBQcC\n" \
  "ARYiaHR0cDovL2Nwcy5yb290LXgxLmxldHNlbmNyeXB0Lm9yZzA8BgNVHR8ENTAz\n" \
  "MDGgL6AthitodHRwOi8vY3JsLmlkZW50cnVzdC5jb20vRFNUUk9PVENBWDNDUkwu\n" \
  "Y3JsMB0GA1UdDgQWBBSoSmpjBH3duubRObemRWXv86jsoTANBgkqhkiG9w0BAQsF\n" \
  "AAOCAQEA3TPXEfNjWDjdGBX7CVW+dla5cEilaUcne8IkCJLxWh9KEik3JHRRHGJo\n" \
  "uM2VcGfl96S8TihRzZvoroed6ti6WqEBmtzw3Wodatg+VyOeph4EYpr/1wXKtx8/\n" \
  "wApIvJSwtmVi4MFU5aMqrSDE6ea73Mj2tcMyo5jMd6jmeWUHK8so/joWUoHOUgwu\n" \
  "X4Po1QYz+3dszkDqMp4fklxBwXRsW10KXzPMTZ+sOPAveyxindmjkW8lGy+QsRlG\n" \
  "PfZ+G6Z6h7mjem0Y+iWlkYcV4PIWL1iwBi8saCbGS5jN2p8M+X+Q7UNKEkROb3N6\n" \
  "KOqkqm57TH2H3eDJAkSnh6/DNFu0Qg==\n" \
  "-----END CERTIFICATE-----\n";
*/

void setup() {

  USE_SERIAL.begin(115200);

  USE_SERIAL.println();
  USE_SERIAL.println();
  USE_SERIAL.println();

  pinMode(SWITCH_PIN, INPUT_PULLUP);

  run_mode =
    digitalRead(SWITCH_PIN) == HIGH
    ? WIFI
    : STAND_ALONE;

  if (run_mode == WIFI) {
    wifiMulti.addAP("uzuhouse", "uzuhouse");// addAP(SSID, PASSWORD);
  }

  FastLED.addLeds<WS2812B, DATA_PIN, GRB>(leds, NUM_LEDS);
  randomSeed(0);
}

void loop() {
  switch (run_mode) {
    case WIFI:
      // wait for WiFi connection
      if ((wifiMulti.run() == WL_CONNECTED)) {

        HTTPClient http;

        USE_SERIAL.print("[HTTP] begin...\n");
        http.begin("http://20.194.189.218/iot"); //HTTP

        USE_SERIAL.print("[HTTP] GET...\n");
        // start connection and send HTTP header
        int httpCode = http.GET();

        // httpCode will be negative on error
        if (httpCode > 0) {
          // HTTP header has been send and Server response header has been handled
          USE_SERIAL.printf("[HTTP] GET... code: %d\n", httpCode);

          // file found at server
          if (httpCode == HTTP_CODE_OK) {
            String payload = http.getString();
            USE_SERIAL.println(payload);

            String first_data = "";
            String second_data = "";
            for (int i = 0; i < payload.length(); i++) {
              const char c = payload.charAt(i);
              if (c == ',') {
                second_data = payload.substring(i + 1);
                break;
              } else {
                first_data.concat(c);
              }
            }

            const int pod = first_data.toInt();
            const int illuminationPattern = second_data.toInt();

            USE_SERIAL.print(pod);
            USE_SERIAL.print(" ");
            USE_SERIAL.println(illuminationPattern);

            illuminate(pod, illuminationPattern);
            //illuminate(150, 3);
          }
        } else {
          USE_SERIAL.printf("[HTTP] GET... failed, error: %s\n", http.errorToString(httpCode).c_str());
        }

        http.end();
      }
      break;

    case STAND_ALONE:
      illuminate(NUM_PODS, STATIC);
      illuminate(NUM_PODS, WAVE);
      illuminate(NUM_PODS, RANDOM);
      break;
  }
}

void illuminate(const int pod, const int illuminationPattern) {
  FastLED.setBrightness(BRIGHTNESS);
  int num_lighted_LEDs = pod * POD_MAGNIFICATION;
  if (num_lighted_LEDs >= NUM_LEDS) {
    illuminate_special();
    num_lighted_LEDs = NUM_LEDS;
  }
  switch (illuminationPattern) {
    case STATIC:
      illuminate_static(num_lighted_LEDs);
      break;
    case WAVE:
      illuminate_wave(num_lighted_LEDs);
      break;
    case RANDOM:
      illuminate_random(num_lighted_LEDs);
      break;
  }
  reset_LED();
  FastLED.show();
}

void illuminate_special() {
  for (int i = 0; i < NUM_LEDS; i++) {
    reset_LED();
    leds[i] = CHSV(random(256), 255, 255);
    FastLED.show();
    delay(SPECIAL_INTERVAL);
  }
  reset_LED();
  FastLED.show();
  delay(SPECIAL_WAIT);
}

void illuminate_static(const int num_lighted_LEDs) {
  const int led_width = NUM_LEDS / num_lighted_LEDs;
  for (int i = 0; i < NUM_LEDS; i++) {
    leds[i] =
      i % led_width == 0
      ? CHSV(random(256), 255, 255)
      : CHSV(0, 0, 0);
  }
  FastLED.show();
  delay(WAIT_TIME_MILLIS);
}

void illuminate_wave(const int num_lighted_LEDs) {
  for (int i = 0; i < WAIT_TIME_MILLIS / WAVE_INTERVAL; i++) {
    reset_LED();
    for (int j = 0; j < num_lighted_LEDs; j++) {
      leds[(i + j) % NUM_LEDS] = CHSV(((i * 2 + j) * WAVE_COLOR_VARIATION_WIDTH) % 256, 255, 255);
    }
    FastLED.show();
    delay(WAVE_INTERVAL);
  }
}

void illuminate_random(const int num_lighted_LEDs) {
  for (int i = 0; i < WAIT_TIME_MILLIS / RANDOM_INTERVAL; i++) {
    bool LED_enabled[NUM_LEDS] = {false};
    for (int i = 0; i < num_lighted_LEDs; i++) {
      LED_enabled[i] = true;
    }
    shuffle(LED_enabled);
    for (int j = 0; j < NUM_LEDS; j++) {
      leds[j] =
        LED_enabled[j]
        ? CHSV(random(256), 255, 255)
        : CHSV(0, 0, 0);
    }
    FastLED.show();
    delay(RANDOM_INTERVAL);
  }
}

void reset_LED() {
  for (int i = 0; i < NUM_LEDS; i++) {
    leds[i] = CRGB::Black;
  }
}

void shuffle(bool arr[]) {
  for (int i = 0; i < NUM_LEDS; i++) {
    int j = random(NUM_LEDS);
    int t = arr[i];
    arr[i] = arr[j];
    arr[j] = t;
  }
}