build.gradle

plugins {
    id "org.springframework.boot" version "2.2.6.RELEASE"
    id "io.spring.dependency-management" version "1.0.9.RELEASE"
    id "checkstyle"
    id "java"
}

group = "run.halo.app"
version = "1.3.2"
description = "Halo, An excellent open source blog publishing application."

java {
    archivesBaseName = "halo"
    sourceCompatibility = JavaVersion.VERSION_1_8
}

repositories {
    maven {
        url "https://maven.aliyun.com/nexus/content/groups/public"
    }
    mavenCentral()
    jcenter()
}

configurations {
    implementation {
        exclude module: "spring-boot-starter-tomcat"
        exclude module: "slf4j-log4j12"
    }

    developmentOnly

    runtimeClasspath {
        extendsFrom developmentOnly
    }

    compileOnly {
        extendsFrom annotationProcessor
    }
}


springBoot {
    buildInfo()
}

// gradle 的 Property Expansion 的占位符 ${..} 与 springboot 的占位符 冲突， springboot 的需要转义 \${..}
processResources {
    filesMatching("application.yaml") {
        expand(project.properties)
    }
}

ext {
    hutoolVersion =  "5.3.2"
    upyunSdkVersion =  "4.2.0"
    qiniuSdkVersion =  "7.2.28"
    aliyunSdkVersion =  "3.9.1"
    baiduSdkVersion =  "0.10.106"
    qcloudSdkVersion =  "5.6.22"
    swaggerVersion =  "2.9.2"
    commonsLangVersion =  "3.10"
    httpclientVersion =  "4.5.12"
    dataformatYamlVersion =  "2.11.0"
    jgitVersion =  "5.7.0.202003110725-r"
    flexmarkVersion =  "0.61.24"
    thumbnailatorVersion =  "0.4.11"
    image4jVersion =  "0.7zensight1"
    flywayVersion =  "6.4.1"
    h2Version =  "1.4.196"
    levelDbVersion =  "0.12"
    jsonVersion =  "20190722"
    fastJsonVersion =  "1.2.68"
    annotationsVersion = "3.0.1u2"
    jedisVersion= '3.2.0'
    zxingVersion = "3.4.0"
    huaweiObsVersion = "3.19.7"
}

dependencies {
    implementation "org.springframework.boot:spring-boot-starter-actuator"
    implementation "org.springframework.boot:spring-boot-starter-data-jpa"
    implementation "org.springframework.boot:spring-boot-starter-web"
    implementation "org.springframework.boot:spring-boot-starter-undertow"
    implementation "redis.clients:jedis:$jedisVersion"
    implementation "org.springframework.boot:spring-boot-starter-freemarker"
    implementation "com.sun.mail:jakarta.mail"

    implementation "cn.hutool:hutool-core:$hutoolVersion"
    implementation "cn.hutool:hutool-crypto:$hutoolVersion"
    implementation "cn.hutool:hutool-extra:$hutoolVersion"
    implementation "com.upyun:java-sdk:$upyunSdkVersion"
    implementation "com.qiniu:qiniu-java-sdk:$qiniuSdkVersion"
    implementation "com.aliyun.oss:aliyun-sdk-oss:$aliyunSdkVersion"
    implementation "com.baidubce:bce-java-sdk:$baiduSdkVersion"
    implementation "com.qcloud:cos_api:$qcloudSdkVersion"
    implementation "com.huaweicloud:esdk-obs-java:$huaweiObsVersion"
    implementation "io.springfox:springfox-swagger2:$swaggerVersion"
    implementation "io.springfox:springfox-swagger-ui:$swaggerVersion"
    implementation "org.apache.commons:commons-lang3:$commonsLangVersion"
    implementation "org.apache.httpcomponents:httpclient:$httpclientVersion"
    implementation "com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:$dataformatYamlVersion"
    implementation "org.eclipse.jgit:org.eclipse.jgit:$jgitVersion"
    implementation "com.google.code.findbugs:annotations:$annotationsVersion"

    implementation "com.vladsch.flexmark:flexmark:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-attributes:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-autolink:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-emoji:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-escaped-character:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-gfm-strikethrough:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-gfm-tasklist:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-ins:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-media-tags:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-tables:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-toc:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-superscript:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-yaml-front-matter:$flexmarkVersion"
    implementation "com.vladsch.flexmark:flexmark-ext-gitlab:$flexmarkVersion"
//    implementation "com.vladsch.flexmark:flexmark-html-parser:$flexmarkVersion"

    implementation "net.coobird:thumbnailator:$thumbnailatorVersion"
    implementation "net.sf.image4j:image4j:$image4jVersion"
    implementation "org.flywaydb:flyway-core:$flywayVersion"

    implementation "org.json:json:$jsonVersion"
    implementation "com.alibaba:fastjson:$fastJsonVersion"

    implementation "com.google.zxing:core:$zxingVersion"

    implementation "org.iq80.leveldb:leveldb:$levelDbVersion"
    runtimeOnly "com.h2database:h2:$h2Version"
    runtimeOnly "mysql:mysql-connector-java"


    compileOnly "org.projectlombok:lombok"
    annotationProcessor "org.projectlombok:lombok"

    testCompileOnly "org.projectlombok:lombok"
    testAnnotationProcessor "org.projectlombok:lombok"

    testImplementation "org.springframework.boot:spring-boot-starter-test"

    developmentOnly "org.springframework.boot:spring-boot-devtools"
}