build.gradle

plugins {
  id 'maven'
  id 'java'
  id 'eclipse'
  id 'application'
  id 'com.github.johnrengelman.shadow' version '2.0.1'
}

repositories {
  mavenCentral()
  maven {
    url "http://oss.sonatype.org/content/groups/public/"
  }
}

mainClassName = 'me.lcw.sc2api.SyncExample1'

project.archivesBaseName='sc2-java-api'

dependencies {
  compile (
    "org.threadly:threadly:5.2",
    "org.threadly:litesockets:4.0",
    "org.threadly:litesockets-http-protocol:0.10",
    "com.google.protobuf:protobuf-java:3.3.1",
    "com.google.protobuf:protobuf-java-util:3.3.1",
    "org.slf4j:slf4j-api:1.7.25",
    "org.slf4j:slf4j-simple:1.7.25",
  )

  testCompile group: 'junit', name: 'junit', version: '4.12'
}

compileJava {
  options.compilerArgs << "-Xlint:all"
}

compileTestJava {
  options.compilerArgs << "-Xlint:all" << "-Xlint:-deprecation" << "-Werror"
}

test {
  getReports().getJunitXml().setDestination(file("${buildDir}/reports/tests/xml"))
  getReports().getHtml().setDestination(file("${buildDir}/reports/tests/html"))
  setBinResultsDir(file("${buildDir}/reports/tests/bin"))
}

jar {
  manifest {
    attributes 'Implementation-Title': 'sc2-java-api', 'Implementation-Version': version
  }
  baseName = 'sc2-java-api'
}

javadoc {
  source = sourceSets.main.allJava
  options.memberLevel = org.gradle.external.javadoc.JavadocMemberLevel.PUBLIC
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  classifier = 'javadoc'
  from 'build/docs/javadoc'
}

task sourcesJar(type: Jar) {
  from sourceSets.main.allSource
  classifier = 'sources'
}