-
Notifications
You must be signed in to change notification settings - Fork 3
/
FigShape.m
1121 lines (785 loc) · 59.7 KB
/
FigShape.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(*Header comments*)
(* :Title: FigShape *)
(* :Context: SciDraw` *)
(* :Summary: Basic drawing shapes *)
(* :Author: Mark A. Caprio, Department of Physics, University of Notre Dame *)
(* :Copyright: Copyright FIGYEAR, Mark A. Caprio *)
(* :Package Version: FIGVERSION *)
(* :Mathematica Version: MATHVERSION *)
(* :Discussion: FIGDISCUSSION *)
(* :History: See package information file. *)
(*Begin package*)
(*Package context definition*)
BeginPackage["SciDraw`",SciDraw`Private`$ExternalContexts];
Unprotect[Evaluate[$Context<>"*"]];
(*Object usage*)
FigLine::usage="FIGURE OBJECT: FigLine[curve] generates a curve.";
FigPolygon::usage="FIGURE OBJECT: FigPolygon[curve] generates a polygon.";
FigCircle::usage="FIGURE OBJECT: FigCircle[center] generates a circle or, more generally, an ellipse.";
FigRectangle::usage="FIGURE OBJECT: FigRectangle[center] or FigRectangle[corner1,corner2] or FigRectangle[region] generates a rectangular box.";
FigPoint::usage="FIGURE OBJECT: FigPoint[point] generates a point.";
FigAnchorMarker::usage="FIGURE OBJECT: FigAnchorMarker[point] generates an anchor marker (point plus direction) for diagnostic or illustrative purposes.";
FigBracket::usage="FIGURE OBJECT: FigBracket[side,coordinate,range] generates an annotation bracket.";
FigRule::usage="FIGURE OBJECT: FigRule[orientation,coordinate,range] ";
FigBSpline::usage="FIGURE OBJECT: FigBSpline[{pt1,pt2,...}] generates a B-spline curve with the given control points.";
FigBezier::usage="FIGURE OBJECT: FigBezier[{pt1,pt2,...}] generates a (cubic) Bezier curve with the given control points.";
(*Other usage*)
FillTexture::usage="Option name for use with figure objects.";
AngleRange::usage="Option name for use with figure objects.";
InvertAngleRange::usage="Option name for use with figure objects.";
Shift::usage="Option name for use with figure objects.";
(*Begin private context*)
Begin["`Private`"];
(*Dependencies*)
(*FigLine*)
(*Object declaration*)
DeclareFigClass[
FigLine,
{"Points"},
{},
{Center,Left,Right,Tail,Head}
];
DefineFigClassOptions[
FigLine,
{
(* curve/arrowhead *)
FigArrowheadOptions[False,False],
FigCurveOptions
}
];
(*Constructor*)
Constructor[Class:FigLine,Self_Object][Curve:FigCurvePattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CanvasPoints,InterpolationFunction},
(* validate extra options *)
FigCheckArrowheadOptions[Self];
FigCheckCurveOptions[Self];
(* prerequisite calculations *)
CanvasPoints=FigResolveCurve[Self,Curve,FigOptions];
(* save data needed for anchor generation *)
Self@SetPoints[CanvasPoints];
(* make graphics elements *)
(* curve *)
FigLineElement[
{Line[CanvasPoints]},
FigOptions
];
(* arrowheads *)
FigLineElement[
{Line[FigCurveArrowheadPoints[
Self@MakeAnchor[Tail,None],
Self@MakeAnchor[Head,None],
FigOptions
]]},
Flatten[{LineDashing->None,FigOptions}]
];
]
];
(*Methods*)
MakeAnchor[Class:FigLine,Self_Object][Name_,Arg:_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
FigCurveAnchorFromPoints[Self@GetPoints[],Name,Arg]
];
MakeBoundingBox[Class:FigLine,Self_Object][]:=FigCurveBoundingBox[Self@GetPoints[]];
(*FigPolygon*)
(*Object declaration*)
DeclareFigClass[
FigPolygon,
{"Points"},
{},
{Center,Left,Right}
];
DefineFigClassOptions[
FigPolygon,
{
(* curve *)
FigCurveOptions ,
(* Mathematica polygon *)
VertexColors->Automatic,FillTexture->None,VertexTextureCoordinates->None
}
];
(*Constructor*)
Constructor[Class:FigPolygon,Self_Object][Curve:FigCurvePattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CanvasPoints},
(* validate extra options *)
FigCheckCurveOptions[Self];
(* generate curve points *)
CanvasPoints=FigResolveCurve[Self,Curve,FigOptions];
(* some polar plots may make quasi-closed curve, which disrupts interpolation, leading to error messages *)
(* so drop last point if is approximately same as first point *)
If[
Chop[First[CanvasPoints]-Last[CanvasPoints]]=={0,0},
CanvasPoints=Most[CanvasPoints]
];
(* make polygon *)
FigPolygonElement[
{
If[(FillTexture/.FigOptions)=!=None,Texture[(FillTexture/.FigOptions)],{}],
Polygon[CanvasPoints,FilterRules[FigOptions,Options[Polygon]]]},
FigOptions
];
(* save curve data *)
(* saved closed set of points for anchor generation *)
Self@SetPoints[Append[CanvasPoints,First[CanvasPoints]]];
]
]
(*Methods*)
MakeAnchor[Class:FigPolygon,Self_Object][Name_,Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
FigCurveAnchorFromPoints[Self@GetPoints[],Name,Arg]
];
MakeBoundingBox[Class:FigPolygon,Self_Object][]:=FigCurveBoundingBox[Self@GetPoints[]];
(*FigRectangle*)
(*Object declaration*)
DeclareFigClass[
FigRectangle,
{"Center","Radius","Pivot","Rotation"},
{},
{Center,Left,Right,Bottom,Top}
];
DefineFigClassOptions[
FigRectangle,
{
(* "circle" geometry *)
FigRectangleOptions,
(* rounding *)
RoundingRadius->None
}
];
(*Constructor*)
(*shared code common to all forms of the constructor*)
BasicRectangle[Self_Object][CanvasCenter_,CanvasPivot_,CanvasRadius_,RotationAngle_,UsedRoundingRadius_]:=Module[
{},
(* make rectangle *)
FigPolygonElement[
{Rotate[
Rectangle[(CanvasCenter-CanvasRadius),(CanvasCenter+CanvasRadius),RoundingRadius->UsedRoundingRadius],
RotationAngle,CanvasPivot
]},
FigOptions
];
(* save object data *)
Self@SetCenter[CanvasCenter];
Self@SetRadius[CanvasRadius];
Self@SetPivot[CanvasPivot];
Self@SetRotation[RotationAngle];
];
(*given center (with option Radius)*)
Constructor[Class:FigRectangle,Self_Object][p:FigPointPattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle,UsedRoundingRadius},
(* validate extra options *)
FigCheckRectangleOptions[Self];
FigCheckOption[Self,RoundingRadius,FigRadiusPattern,FigOptions];
(* generate geometry *)
{CanvasCenter,CanvasRadius,CanvasPivot,RotationAngle}=MakeRectangleGeometry [p,FigOptions];
UsedRoundingRadius=FigResolveRadius[(RoundingRadius/.FigOptions)];
BasicRectangle[Self][CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle,UsedRoundingRadius];
]
];
(*given region specification*)
Constructor[Class:FigRectangle,Self_Object][r:FigRegionPattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle,UsedRoundingRadius},
(* validate extra options *)
FigCheckRectangleOptions[Self];
(* generate geometry *)
{CanvasCenter,CanvasRadius,CanvasPivot,RotationAngle}=MakeRectangleGeometry [r,FigOptions];
UsedRoundingRadius=FigResolveRadius[(RoundingRadius/.FigOptions)];
BasicRectangle[Self][CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle,UsedRoundingRadius];
]
];
(*given diametric corners*)
Constructor[Class:FigRectangle,Self_Object][p1:FigPointPattern,p2:FigPointPattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle,UsedRoundingRadius},
(* validate extra options *)
FigCheckRectangleOptions[Self];
(* generate geometry *)
{CanvasCenter,CanvasRadius,CanvasPivot,RotationAngle}=MakeRectangleGeometry [p1,p2,FigOptions];
UsedRoundingRadius=FigResolveRadius[(RoundingRadius/.FigOptions)];
BasicRectangle[Self][CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle,UsedRoundingRadius];
]
];
(*Methods*)
MakeAnchor[Class:FigRectangle,Self_Object][Name_,Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
FigRectangleAnchor[
Self@GetCenter[],Self@GetRadius[],Self@GetPivot[],Self@GetRotation[],
Name,Arg
]
];
MakeBoundingBox[Class:FigRectangle,Self_Object][]:=FigRectangleBoundingBox[
Self@GetCenter[],Self@GetRadius[],Self@GetPivot[],Self@GetRotation[]
];
(*FigCircle*)
(*Object declaration*)
DeclareFigClass[
FigCircle,
{"Center","Radius","AngleRange","Pivot","Rotation"},
{},
{Center,Left,Right,Bottom,Top,Tangent,Normal,Head,Tail,HeadRadius,TailRadius}
];
DefineFigClassOptions[
FigCircle,
{
(* arrowhead *)
FigArrowheadOptions[False,False],
(* "circle" geometry *)
FigRectangleOptions,
(* arc control *)
AngleRange->None,
InvertAngleRange->False,
CurveClosed->False
}
];
(*Constructor*)
(*shared code common to all forms of the constructor*)
BasicCircle[Self_Object][CanvasCenter_,CanvasPivot_,CanvasRadius_,RotationAngle_]:=Module[
{UsedAngleRange,ArrowheadCurve},
(* how Mathematica Circle/Disk apparently decides to draw the arc the "long way" or "short way" -- Mathematica ignores given order of angles -- apparently sorts angles into ascending numerical order, *then* draws counterclockwise arc *)
(*UsedAngleRange=SortBy[AngleRange,N];*) (* put angles in counterclockwise order; SortBy so sorted as numbers not expressions *)
UsedAngleRange=Replace[
(AngleRange/.FigOptions),
None->{0,2*Pi}
];
UsedAngleRange=N[Replace[
UsedAngleRange,
pr:FigPointPattern:>CanvasRayAngle[{CanvasCenter,FigResolvePoint[pr]}],
{1}]];
If[
(InvertAngleRange/.FigOptions),
(* add 2*Pi to lesser angle *)
UsedAngleRange=UsedAngleRange+Switch[
Sign[Last[UsedAngleRange]-First[UsedAngleRange]],
+1,{2*Pi,0},
-1|0,{0,2*Pi}
]
];
(* save object data *)
Self@SetCenter[CanvasCenter];
Self@SetRadius[CanvasRadius];
Self@SetAngleRange[UsedAngleRange];
Self@SetPivot[CanvasPivot];
Self@SetRotation[RotationAngle];
(* make circle *)
(* use Disk edge for outline only if CurveClosed\[Rule]True *)
FigPolygonElement[
{Rotate[Disk[CanvasCenter,CanvasRadius,UsedAngleRange],RotationAngle,CanvasPivot]},
Flatten[{
If[!(CurveClosed/.FigOptions),{ShowLine->False},{}],
FigOptions
}]
];
(* use Circle for outline only if CurveClosed\[Rule]False *)
FigLineElement[
{Rotate[Circle[CanvasCenter,CanvasRadius,UsedAngleRange],RotationAngle,CanvasPivot]},
Flatten[{
If[(CurveClosed/.FigOptions),{Show->False},{}],
FigOptions
}]
];
(* make arrowhead lines *)
FigLineElement[
{Line[FigCurveArrowheadPoints[
Self@MakeAnchor[Tail,None],
Self@MakeAnchor[Head,None],
FigOptions
]]},
Flatten[{LineDashing->None,FigOptions}]
];
];
(*given center (with option Radius)*)
Constructor[Class:FigCircle,Self_Object][p:FigPointPattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle,UsedRoundingRadius},
(* validate extra options *)
FigCheckRectangleOptions[Self];
FigCheckArrowheadOptions[Self];
FigCheckOption[Self,AngleRange,None|{(_?NumericQ)|FigPointPattern,(_?NumericQ)|FigPointPattern},FigOptions];
FigCheckOption[Self,InvertAngleRange,LogicalPattern,FigOptions];
FigCheckOption[Self,CurveClosed,LogicalPattern,FigOptions];
(* generate geometry *)
{CanvasCenter,CanvasRadius,CanvasPivot,RotationAngle}=MakeRectangleGeometry [p,FigOptions];
BasicCircle[Self][CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle];
]
];
(*given region specification*)
Constructor[Class:FigCircle,Self_Object][r:FigRegionPattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle,UsedRoundingRadius},
(* validate extra options *)
FigCheckRectangleOptions[Self];
FigCheckArrowheadOptions[Self];
FigCheckOption[Self,AngleRange,None|{(_?NumericQ)|FigPointPattern,(_?NumericQ)|FigPointPattern},FigOptions];
FigCheckOption[Self,InvertAngleRange,LogicalPattern,FigOptions];
FigCheckOption[Self,CurveClosed,LogicalPattern,FigOptions];
(* generate geometry *)
{CanvasCenter,CanvasRadius,CanvasPivot,RotationAngle}=MakeRectangleGeometry [r,FigOptions];
BasicCircle[Self][CanvasCenter,CanvasPivot,CanvasRadius,RotationAngle];
]
];
(*Methods*)
MakeAnchor[Class:FigCircle,Self_Object][Name_,Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
FigCircleAnchor[
Self@GetCenter[],Self@GetRadius[],Self@GetAngleRange[],Self@GetPivot[],Self@GetRotation[],
Name,Arg
]
];
MakeBoundingBox[Class:FigCircle,Self_Object][]:=FigCircleBoundingBox[
Self@GetCenter[],Self@GetRadius[],Self@GetAngleRange[],Self@GetPivot[],Self@GetRotation[]
];
(*FigPoint*)
(*Object declaration*)
DeclareFigClass[
FigPoint,
{"Point","PointRadius"},
{},
{Center,Left,Right,Bottom,Top}
];
DefineFigClassOptions[
FigPoint,
{
}
];
(*Constructor*)
Constructor[Class:FigPoint,Self_Object][p:FigPointPattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CanvasPoint,d},
(* generate point *)
CanvasPoint=FigResolvePoint[p];
(* make point *)
FigPointElement[
{Point[CanvasPoint]},
FigOptions
];
(* save point data *)
Self@SetPoint[CanvasPoint];
d=First[FigResolvePointSize[(PointSize/.FigOptions)]]; (* may not be numeric if size directive such as Large used for PointSize *)
Self@SetPointRadius[If[NumericQ[d],d/2,0]];
]
];
(*Methods*)
MakeAnchor[Class:FigPoint,Self_Object][Name_,Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
FigCircleAnchor[Self@GetPoint[],Self@GetPointRadius[]*{1,1},{0,2*Pi},{0,0},0,Name,Arg]
];
MakeBoundingBox[Class:FigPoint,Self_Object][]:=FigPointBoundingBox[Self@GetPoint[]];
(*FigAnchorMarker*)
(*Object declaration*)
DeclareFigClass[
FigAnchorMarker,
{"TheAnchor"},
{},
{}
];
DefineFigClassOptions[
FigAnchorMarker,
{PointSize->5,LineColor->Red,TextFrame->True,TextBackground->LightGray,Layer->4}, (* inheritance overrides *)
{
Length->12,Text->None
}
];
(*Constructor*)
Constructor[Class:FigAnchorMarker,Self_Object][p:FigPointPattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{Anchor,CanvasPoint,d,TextArt},
(* validate options *)
FigCheckOption[Self,Length,_?NumericQ,FigOptions];
(* generate point *)
Anchor=FigAnchor[p];
CanvasPoint=Anchor@GetPoint[];
(* make text *)
(* draw text first so that -- with a layer override putting all elements in the same layer -- text box won't hide point and line *)
TextArt=(Text/.FigOptions);
FigTextElement[
Anchor,
TextArt,
FigOptions
];
(* make line *)
FigLineElement[
{Line[{CanvasPoint,CanvasPoint+FromPolar[{(Length/.FigOptions),Anchor@GetAngle[]}]}]},
FigOptions
];
(* make point *)
FigPointElement[
{Point[CanvasPoint]},
FigOptions
];
(* save point data *)
Self@SetTheAnchor[Anchor];
]
];
(*Methods*)
MakeAnchor[Class:FigAnchorMarker,Self_Object][Name_,Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,Null];
MakeBoundingBox[Class:FigAnchorMarker,Self_Object][]:=FigPointBoundingBox[(Self@GetTheAnchor[])@GetPoint[]];
(*FigBracket*)
(*Object declaration*)
DeclareFigClass[
FigBracket,
{
"Points", (* canvas endpoints *)
"Side", (* name of bracket orientation *)
"LeftIsOutside" (* whether or not curve "left" is outside (label side) of bracket *)
},
{},
{Center,Left,Right,Tail,Head,"Bracket"}
];
DefineFigClassOptions[
FigBracket,
{
(* curve/arrowhead *)
FigArrowheadOptions[True,0,{3,0},End],
(*FigCurveOptions *)
(* geometry *)
Shift->0
}
];
(*Constructor*)
Constructor[Class:FigBracket,Self_Object][
Side:(Left|Right|Bottom|Top)|(Horizontal|Vertical),
Coordinate:FigCoordinatePattern,
Range:{FigCoordinatePattern,FigCoordinatePattern}|FigRegionPattern,
Opts___?OptionQ
]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CoordinateIndex,CanvasCoordinate,CanvasCoordinateShiftSense,CanvasCoordinateShift,CanvasInterval,CanvasPoints,LeftIsOutside},
(* common error: chastize user for accidentally giving side as Horizontal or Vertical *)
(* better than generic syntax error *)
FigCheckValue[Self,Side,Except[Horizontal|Vertical],"side"];
(* validate extra options *)
(* validate options *)
FigCheckOption[Self,Shift,FigCoordinatePattern,FigOptions];
FigCheckArrowheadOptions[Self,EndLength];
(*FigCheckCurveOptions[Self];*)
(* determine horizontal/vertical direction *)
CoordinateIndex=Switch[
Side,
Left|Right,1,
Bottom|Top,2
];
(* convert coordinate and interval to canvas values *)
CanvasCoordinate=FigResolveCoordinate[Coordinate,CoordinateIndex];
CanvasCoordinateShift=FigResolveCoordinateDisplacement[(Shift/.FigOptions),CoordinateIndex];
CanvasCoordinateShiftSense=Switch[
Side,
Left|Bottom,-1,
Right|Top,+1
];
CanvasCoordinate+=CanvasCoordinateShiftSense*CanvasCoordinateShift;
CanvasInterval=Sort@Replace[
Range,
{
{x1:FigCoordinatePattern,x2:FigCoordinatePattern}:>{
FigResolveCoordinate[x1,AntiCoordinateIndex[CoordinateIndex]],
FigResolveCoordinate[x2,AntiCoordinateIndex[CoordinateIndex]]
},
r:FigRegionPattern:>FigResolveRegion[r][[AntiCoordinateIndex[CoordinateIndex]]]
}
];
(* generate curve points *)
(* curve always goes in "positive" coordinate direction *)
CanvasPoints=Switch[
Side,
Left|Right,{{CanvasCoordinate,CanvasInterval[[1]]},{CanvasCoordinate,CanvasInterval[[2]]}},
Bottom|Top,{{CanvasInterval[[1]],CanvasCoordinate},{CanvasInterval[[2]],CanvasCoordinate}}
];
(* save curve data *)
Self@SetPoints[CanvasPoints];
Self@SetSide[Side];
(* make curve line *)
FigLineElement[
{Line[CanvasPoints]},
FigOptions
];
(* make arrowhead lines *)
(* need to flip head lip specification on Left/Top brackets so "left" entry in head width specification becomes "inside" width *)
LeftIsOutside=Switch[
Side,
Left|Top,True,
Bottom|Right,False
];
Self@SetLeftIsOutside[LeftIsOutside];
FigLineElement[
{Line[
FigCurveArrowheadPoints[
Self@MakeAnchor[Tail,None],
Self@MakeAnchor[Head,None],
LeftIsOutside,
FigOptions,End
]
]},
Flatten[{LineDashing->None,FigOptions}]
];
]
]
Constructor[Class:FigBracket,Self_Object][
Side:Above|Below,
Range:{r1:FigPointPattern,r2:FigPointPattern},
Opts___?OptionQ
]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CoordinateIndex,CanvasCoordinate,CanvasInterval,CanvasPoints,RightwardGoing,LeftIsOutside},
(* validate extra options *)
FigCheckArrowheadOptions[Self,EndLength];
(* generate curve points *)
CanvasPoints=FigResolvePoint/@Range;
(* save curve data *)
Self@SetPoints[CanvasPoints];
Self@SetSide[Side];
(* make curve line *)
FigLineElement[
{Line[CanvasPoints]},
FigOptions
];
(* make arrowhead lines *)
(* need to flip head lip specification so "left" entry in head width specification becomes "inside" width *)
(* for a pair of endpoints with positive x displacement (i.e., in NE or SE quadrants), "above" is curve's "left", so "outside" is left, and "inside" is right *)
RightwardGoing=NonNegative[-First[Subtract@@CanvasPoints]];
LeftIsOutside=Switch[
Side,
Above,RightwardGoing,
Below,Not[RightwardGoing]
];
Self@SetLeftIsOutside[LeftIsOutside];
FigLineElement[
{Line[
FigCurveArrowheadPoints[
Self@MakeAnchor[Tail,None],
Self@MakeAnchor[Head,None],
LeftIsOutside,
FigOptions,End
]
]},
Flatten[{LineDashing->None,FigOptions}]
];
]
]
(*Methods*)
MakeAnchor[Class:FigBracket,Self_Object][Name:"Bracket",Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
FigCurveAnchorFromPoints[
Self@GetPoints[],
If[Self@GetLeftIsOutside[],Left,Right],
Arg
]
];
(*define standard curve anchors (needed, e.g., for arrowheads)*)
MakeAnchor[Class:FigBracket,Self_Object][Name:Except["Bracket"],Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
FigCurveAnchorFromPoints[Self@GetPoints[],Name,Arg]
];
(*define standard bounding box*)
MakeBoundingBox[Class:FigBracket,Self_Object][]:=FigCurveBoundingBox[Self@GetPoints[]];
(*FigRule*)
(*similar to FigAxis with following differences:*)
(* arrowheads default ShowHead->False*)
(* convenience labels like Lev*)
(* might ultimately want to define Bottom and Top anchors*)
(* range should be specified *numerically* (though positioning coordinate can still be specified in generic fashion)*)
(*Object declaration*)
DeclareFigClass[
FigRule,
{"Points","Orientation"},
{},
{Center,Left,Right,Tail,Head}
];
DefineFigClassOptions[
FigRule,
{
(* curve/arrowhead *)
FigArrowheadOptions[False,False]
}
];
(*Constructor*)
Constructor[Class:FigRule,Self_Object][
Orientation:(Horizontal|Vertical),
Coordinate:FigCoordinatePattern,
Range:{FigCoordinatePattern,FigCoordinatePattern}|FigRegionPattern,
Opts___?OptionQ
]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{
CoordinateIndex,CanvasCoordinate,CanvasInterval,CanvasPoints,CanvasTail,CanvasHead
},
(* validate extra options *)
FigCheckArrowheadOptions[Self];
(* determine horizontal/vertical direction *)
(* CoordinateIndex -- coordinate for *positioning* axis *)
CoordinateIndex=Switch[
Orientation,
Vertical,1,
Horizontal,2
];
(* convert coordinate and interval to canvas values *)
CanvasCoordinate=FigResolveCoordinate[Coordinate,CoordinateIndex];
CanvasInterval=Sort@Replace[
Range,
{
{x1:FigCoordinatePattern,x2:FigCoordinatePattern}:>{
FigResolveCoordinate[x1,AntiCoordinateIndex[CoordinateIndex]],
FigResolveCoordinate[x2,AntiCoordinateIndex[CoordinateIndex]]
},
r:FigRegionPattern:>FigResolveRegion[r][[AntiCoordinateIndex[CoordinateIndex]]]
}
];
(* generate curve points *)
(* curve always goes in "positive" coordinate direction *)
CanvasPoints=Switch[
Orientation,
Vertical,{{CanvasCoordinate,CanvasInterval[[1]]},{CanvasCoordinate,CanvasInterval[[2]]}},
Horizontal,{{CanvasInterval[[1]],CanvasCoordinate},{CanvasInterval[[2]],CanvasCoordinate}}
];
(* save curve data *)
Self@SetPoints[CanvasPoints];
Self@SetOrientation[Orientation];
(* make curve line *)
FigLineElement[
{Line[CanvasPoints]},
FigOptions
];
(* make arrowhead lines *)
FigLineElement[
{Line[
FigCurveArrowheadPoints[
Self@MakeAnchor[Tail,None],
Self@MakeAnchor[Head,None],
Flatten[{
FigOptions
}]
]
]},
Flatten[{Dashing->None,FigOptions}]
];
]
];
(*Methods*)
(*define standard curve anchors (needed, e.g., for arrowheads)*)
MakeAnchor[Class:FigRule,Self_Object][Name_,Arg_]:=FigMakeAnchorWrapper[Class,Self,Name,Arg,
FigCurveAnchorFromPoints[Self@GetPoints[],Name,Arg]
];
(*define standard bounding box*)
MakeBoundingBox[Class:FigRule,Self_Object][]:=FigCurveBoundingBox[Self@GetPoints[]];
(*FigBSpline*)
(*Object declaration*)
DeclareFigClass[
FigBSpline,
{"Points","InterpolationFunction","TangentFunction"},
{},
{Center,Left,Right,Tail,Head}
];
DefineFigClassOptions[
FigBSpline,
{
(* curve/arrowhead *)
FigArrowheadOptions[False,False],
FigCurveOptions,
(* spline-specific options *)
SplineClosed->False,SplineDegree->Automatic,SplineKnots->Automatic,SplineWeights->Automatic
}
];
(*Constructor*)
Constructor[Class:FigBSpline,Self_Object][Curve:FigCurvePattern,Opts___?OptionQ]:=FigObjectWrapper[Class,Self,{Opts},
Module[
{CanvasPoints},
(* validate extra options *)
FigCheckArrowheadOptions[Self];
FigCheckCurveOptions[Self];
FigCheckOption[Self,SplineClosed,LogicalPattern,FigOptions];
FigCheckOption[Self,SplineDegree,Automatic|((_Integer)?Positive),FigOptions];
FigCheckOption[Self,SplineKnots,(Automatic|{((_Integer)?Positive)..}|"Clamped"|"Unclamped"),FigOptions];
FigCheckOption[Self,SplineWeights,Automatic|(_List),FigOptions];
(* prerequisite calculations *)
CanvasPoints=FigResolveCurve[Self,Curve,FigOptions];
(* save data needed for anchor generation *)
(* CAVEAT -- these interpolation functions are not linear in the canvas metric *)
Self@SetPoints[CanvasPoints];
Self@SetInterpolationFunction[BSplineFunction[CanvasPoints,FilterRules[FigOptions,Options[BSplineCurve]]]];
Self@SetTangentFunction[Derivative[1][BSplineFunction[CanvasPoints,FilterRules[FigOptions,Options[BSplineCurve]]]]];
(* make graphics elements *)
(* curve *)
FigLineElement[
{BSplineCurve[CanvasPoints,FilterRules[FigOptions,Options[BSplineCurve]]]},
FigOptions
];
(* arrowheads *)
FigLineElement[
{Line[FigCurveArrowheadPoints[
Self@MakeAnchor[Tail,None],
Self@MakeAnchor[Head,None],
FigOptions
]]},
Flatten[{LineDashing->None,FigOptions}]
];
]
];