build.gradle

/**
 * Copyright 2019 Esri
 *
 * Licensed under the Apache License, Version 2.0 (the "License"); you may not 
 * use this file except in compliance with the License. You may obtain a copy 
 * of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software 
 * distributed under the License is distributed on an "AS IS" BASIS, WITHOUT 
 * WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the 
 * License for the specific language governing permissions and limitations 
 * under the License.
 */

plugins {
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.0.13'
}

ext {
    arcgisVersion = '200.1.0-3734'
}

repositories {
    mavenCentral()
    mavenLocal()
}

configurations {
    natives
}

dependencies {
    implementation "com.esri.arcgisruntime:arcgis-java:$arcgisVersion"
    natives "com.esri.arcgisruntime:arcgis-java-jnilibs:$arcgisVersion"
    natives "com.esri.arcgisruntime:arcgis-java-resources:$arcgisVersion"
    implementation "org.slf4j:slf4j-nop:2.0.5"
    implementation 'com.pi4j:pi4j-core:2.3.0'
    implementation 'com.pi4j:pi4j-plugin-raspberrypi:2.3.0'
    implementation 'com.pi4j:pi4j-plugin-pigpio:2.3.0'
    implementation 'com.pi4j:pi4j-plugin-linuxfs:2.3.0'
    implementation 'one.microproject.rpi:rpi-drivers:2.1.1'
    implementation 'eu.hansolo:medusa:17.1.7'
    implementation 'eu.hansolo:toolboxfx:17.0.41'
    implementation 'eu.hansolo:toolbox:17.0.41'
}

javafx {
    version = "17.0.7"
    modules = [ 'javafx.controls', 'javafx.graphics', 'javafx.fxml', 'javafx.web', 'javafx.media', 'javafx.swing' ]
}

application {
    mainModule = "com.mbcoder.iot.weatherstation"
    mainClass = "com.mbcoder.iot.weatherstation.Weather_logger"
}

task copyNatives(type: Copy) {
    description = "Copies the arcgis native libraries into the .arcgis directory for development."
    group = "build"
    configurations.natives.asFileTree.each {
        from(zipTree(it))
    }
    into "${System.properties.getProperty("user.home")}/.arcgis/$arcgisVersion"
}

run {
    dependsOn copyNatives
}