build.gradle

import de.michiruf.gradle.findversion.FindVersion

plugins {
    id 'java'
    id 'fabric-loom' version '1.4-SNAPSHOT'
}

apply from: 'build.allprojects.gradle'
apply from: 'build.versions.gradle'

def minecraftVersion = project.minecraftVersion as String ?: '1.19.1'
def minecraftVersionDefinitions = ext.minecraftVersionDefinitions
def minecraftVersionDefinition = minecraftVersionDefinitions[minecraftVersion]
project.version = "${project.version}+${minecraftVersion}"

sourceSets {
    main.java.srcDirs = [
            'src/main/java',
            //"src/versionedFeature/${FindVersion.findClosestLowerOrEqualVersionInDirectory(file('src/versionedFeature'), minecraftVersion)}"
    ]
}

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
    maven { url "https://maven.shedaniel.me/" }
}

dependencies {
    // Minecraft and fabric
    minecraft "com.mojang:minecraft:${minecraftVersion}"
    mappings "net.fabricmc:yarn:${minecraftVersionDefinition['mappings']}:v2"
    modImplementation "net.fabricmc:fabric-loader:${minecraftVersionDefinition['fabric']}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${minecraftVersionDefinition['fabricApi']}"

    // OrmLite
    modImplementation include('com.j256.ormlite:ormlite-jdbc:6.1')
    modImplementation include('org.xerial:sqlite-jdbc:3.40.0.0')
    modImplementation include('mysql:mysql-connector-java:8.0.30')
    modImplementation include('org.postgresql:postgresql:42.5.1')

    // Tests
    testImplementation 'org.junit.jupiter:junit-jupiter:5.9.1'
}

processResources {
    var replaceProperties = [
            version  : project.version,
            minecraft: minecraftVersion,
            mappings : minecraftVersionDefinition['mappings'],
            fabric   : minecraftVersionDefinition['fabric'],
            fabricApi: minecraftVersionDefinition['fabricApi']
    ]
    inputs.properties replaceProperties
    filteringCharset 'UTF-8'
    filesMatching('fabric.mod.json') {
        expand replaceProperties
    }
}

def targetJavaVersion = 17
tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        it.options.release = targetJavaVersion
    }
}

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

test {
    useJUnitPlatform()
    maxHeapSize = '1G'
    testLogging {
        events 'passed'
    }
}