code5

.PAG 'CODE5'
	STA TXTPTR
	LDA LOWTR+1
	SBC #0
	STA TXTPTR+1
GORTS	RTS
RETURN	BNE GORTS
	LDA #255
	STA FORPNT+1
	JSR FNDFOR
	TXS
	CMP #GOSUTK
	BEQ RETU1
	LDX #ERRRG
	.BYT $2C
USERR	LDX #ERRUS
	JMP ERROR
SNERR2	JMP SNERR
RETU1	PLA
	PLA
	STA CURLIN
	PLA
	STA CURLIN+1
	PLA
	STA TXTPTR
	PLA
	STA TXTPTR+1
DATA	JSR DATAN
ADDON	TYA
	CLC
	ADC TXTPTR
	STA TXTPTR
	BCC REMRTS
	INC TXTPTR+1
REMRTS	RTS
DATAN	LDX #':
	.BYT $2C
REMN	LDX #0
	STX CHARAC
	LDY #0
	STY ENDCHR
EXCHQT	LDA ENDCHR
	LDX CHARAC
	STA CHARAC
	STX ENDCHR
REMER	LDA (TXTPTR)Y
	BEQ REMRTS
	CMP ENDCHR
	BEQ REMRTS
	INY
	CMP #34
	BNE REMER
	BEQ EXCHQT
IF	JSR FRMEVL
	JSR CHRGOT
	CMP #GOTOTK
	BEQ OKGOTO
	LDA #THENTK
	JSR SYNCHR
OKGOTO	LDA FACEXP
	BNE DOCOND
REM	JSR REMN
	BEQ ADDON
DOCOND	JSR CHRGOT
	BCS DOCO
	JMP GOTO
DOCO	JMP GONE3
ONGOTO	JSR GETBYT
	PHA
	CMP #GOSUTK
	BEQ ONGLOP
SNERR3	CMP #GOTOTK
	BNE SNERR2
ONGLOP	DEC FACLO
	BNE ONGLP1
	PLA
	JMP GONE2
ONGLP1	JSR CHRGET
	JSR LINGET
	CMP #44
	BEQ ONGLOP
	PLA
ONGRTS	RTS
LINGET	LDX #0
	STX LINNUM
	STX LINNUM+1
MORLIN	BCS ONGRTS
	SBC #$2F
	STA CHARAC
	LDA LINNUM+1
	STA INDEX
	CMP #25
	BCS SNERR3
	LDA LINNUM
	ASL A
	ROL INDEX
	ASL A
	ROL INDEX
	ADC LINNUM
	STA LINNUM
	LDA INDEX
	ADC LINNUM+1
	STA LINNUM+1
	ASL LINNUM
	ROL LINNUM+1
	LDA LINNUM
	ADC CHARAC
	STA LINNUM
	BCC NXTLGC
	INC LINNUM+1
NXTLGC	JSR CHRGET
	JMP MORLIN
LET	JSR PTRGET
	STA FORPNT
	STY FORPNT+1
	LDA #$B2
	JSR SYNCHR
	LDA INTFLG
	PHA
	LDA VALTYP
	PHA
	JSR FRMEVL
	PLA
	ROL A
	JSR CHKVAL
	BNE COPSTR
	PLA
QINTGR	BPL COPFLT
	JSR ROUND
	JSR AYINT
	LDY #0
	LDA FACMO
	STA (FORPNT)Y
	INY
	LDA FACLO
	STA (FORPNT)Y
	RTS
COPFLT	JMP MOVVF
COPSTR	PLA
INPCOM	LDY FORPNT+1
	CPY #>ZERO
	BNE GETSPT
	JSR FREFAC
	CMP #6
	BNE FCERR2
	LDY #0
	STY FACEXP
	STY FACSGN
.FIL CODE6