build.gradle

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:5.2.0'
    }
}

allprojects {

    ext {
        //Version = 1.0.0-SNAPSHOT //(silly versioning)
        appName = 'Leikr'
        mini2DxVersion = '2.0.0-alpha.34'
        groovyVersion = '4.0.0-alpha-1'
        gdxVersion = '1.9.12'
        gdxControllersVersion = '2.0.0-SNAPSHOT'
        lwjglNatives32 = 'natives-linux-arm32'
        lwjglNatives64 = 'natives-linux-arm64'
        lwjglVersion = '3.2.3'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
        maven { url "https://jitpack.io" }
        maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
    }
    
    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
        }
    }
}

project(":core") {
    apply plugin: 'java'
    apply plugin: 'jacoco'
    apply plugin: 'groovy'

    dependencies {
        //implementation "com.badlogicgames.gdx-controllers:gdx-controllers-core:$gdxControllersVersion"
        
        implementation "com.badlogicgames.gdx:gdx-controllers-lwjgl3:$gdxVersion"
        implementation "org.mini2Dx:mini2dx-libgdx-desktop-lwjgl3:$mini2DxVersion"
        
        implementation "org.mini2Dx:mini2dx-core:$mini2DxVersion"
        implementation "org.mini2Dx:mini2dx-tiled:$mini2DxVersion"
        implementation "org.apache.groovy:groovy:$groovyVersion"
        
        // lwjgl3natives:
        implementation "org.lwjgl:lwjgl:$lwjglVersion"
        implementation "org.lwjgl:lwjgl-glfw:$lwjglVersion"
        implementation "org.lwjgl:lwjgl-openal:$lwjglVersion"
        implementation "org.lwjgl:lwjgl-opengl:$lwjglVersion"
        
        // arm32 lwjgl native libs 
        runtimeOnly "org.lwjgl:lwjgl::$lwjglNatives32"
        runtimeOnly "org.lwjgl:lwjgl-glfw::$lwjglNatives32"
        runtimeOnly "org.lwjgl:lwjgl-openal::$lwjglNatives32"
        runtimeOnly "org.lwjgl:lwjgl-opengl::$lwjglNatives32"
        
        // arm64 lwjgl native libs
        runtimeOnly "org.lwjgl:lwjgl::$lwjglNatives64"
        runtimeOnly "org.lwjgl:lwjgl-glfw::$lwjglNatives64"
        runtimeOnly "org.lwjgl:lwjgl-openal::$lwjglNatives64"
        runtimeOnly "org.lwjgl:lwjgl-opengl::$lwjglNatives64"
        
        testImplementation 'org.spockframework:spock-core:2.0-M3-groovy-3.0'
    }
    
    // tests broken with Groovy 4
    test.finalizedBy jacocoTestReport
}

project(":desktop") {
    apply plugin: "application"

    dependencies {
        implementation project(":core")
        //implementation "com.badlogicgames.gdx-controllers:gdx-controllers-desktop:$gdxControllersVersion"
        
        implementation "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
        implementation "org.mini2Dx:mini2dx-libgdx-desktop-lwjgl3:$mini2DxVersion"
    }
}