Strange simulation results

[dsm]

I have a ltspice sim. this is the result(expected result) voltage on C2.

and same circuit in qucs-s result is strange normal diode and 1n4007 diode result also different.

Normal Diode

1N4007

[cmat21]

Hi @dsm , consider checking the number of point on settings transient, maybe that will help.

[ivandi69]

tran 0.001 3
works just fine

[ra3xdh]

@dsm

You are using a default diode model in the first circuit. LTspice and Qucs-S have the different default diode model. You have BV=10V in Qucs-S by default and diode goes to breakdown producing wrong output. Set the BV=1000V and everything will work as expected. The another issue is that you have used default transient points number. Ngspice is able to adjust transient time step but only to some extension. You have to set the points numbers manually for long transient simulation durations. Espesially if Tstop is greater than 5-10 waves of the input signal source. You have Tstop=3s and F=50Hz. Ngspice may skip the sine waves and show wrong result.

The convergence issues with 1N4007 model is not a Qucs-S bug. It is related to Ngspice bug: https://sourceforge.net/p/ngspice/mailman/ngspice-devel/?viewmonth=202205 I have reported this once, but it seems it has appeared again. The workaround is to set Ikf=1e-20 in the diode parameters. I can patch the diodes libraries to provide this workaround for all users.

[dsm]

BV=1000V will solve the problem and number of the point not set to default but not as high as 32768. thank you for your explanation.

[ra3xdh]

I am transferring this to discussion. The issue with Ikf parameter probably should be reported to Ngspice team after providing a minimal netlist example to reproduce.

[dwarning]

It is unclear which ngspice version was used.
The mentioned diode problem with absurd parameter input IKF=0 was solved by ngspice commits 67508ea from 2022-05-02, immediately after your bug report by switching off this model effect.
Please provide the missing version information, the generated logfile and a simple test case (netlist) to reproduce the problem.

[dsm]

Latest ngspice 42 is used.

[ra3xdh]

@dwarning I will prepare a minimal netlist reproducing this problem. Maybe some other bug with diode has appeared.

[ra3xdh]

Here is a minimal netlist reproducing this. issue. The diode models are using default Ikf value. The 1N4007 model fails to converge, but the generic diode works.

* diode test schematic
V1 _net1 0 DC 0 SIN(0 470 50 0 0 0) AC 470 ACPHASE 0
C1 0 out  10U 
R1 _net0 out  400K tc1=0.0 tc2=0.0 
R2 0 out  4.2K tc1=0.0 tc2=0.0 
*D1 _net1 _net0 DMOD_D_1N4007_1 AREA=1.0 Temp=26.85
* uncomment this line to switch diode models
D1 _net1 _net0 DMOD_D1 AREA=1.0 Temp=26.85
* This model fails to converge
.MODEL DMOD_D_1N4007_1 D (Is=7.69e-11 N=1.45 Cj0=2.65e-11 M=0.333 Vj=0.7 Fc=0.5 Rs=0.042 
+ Tt=4.32e-6 Kf=0 Af=1 Bv=1000 Ibv=5e-6 Xti=3 Eg=1.11 Tcv=0 Trs=0 
+ Ttt1=0 Ttt2=0 Tm1=0 Tm2=0 Tnom=26.85 )
* This model works as expected
.MODEL DMOD_D1 D (Is=1e-15 N=1 Cj0=1e-14 M=0.5 Vj=0.7 Fc=0.5 Rs=0 
+ Tt=0 Kf=0 Af=1 Bv=1000 Ibv=0.001 Xti=3 Eg=1.11 Tcv=0 Trs=0 
+ Ttt1=0 Ttt2=0 Tm1=0 Tm2=0 Tnom=26.85 )
.tran 0.001 3 0

[ra3xdh]

I am using Ngspice-42 too. The Ngspice-39 fails to converge too. The Ngspice-27 works, but gives a wrong waveform. The 1N4007 model works only if an explicit Ikf=1e-20 value is given.

[dwarning]

There was no IKF in the netlist!

Reducing max. timestep in tran, e.g.

tran 0.001 3 0 10u

will work without IKF, with IKF=0 and IKF=1e-20.

BTW - Qucs-S netlister seem to omit IKF if it set to 0. This is dangerous, perhaps a quick workaround from the past, where you found the IKF problem.

EDIT:
This warning doesn't appear in the Qucs-S log file if IKF=0:

Warning: IKF too small - model effect disabled!

[ivandi69]

For me tran 0.001 3 works without IKF, with IKF=0 and IKF=1e-20, both sparse and klu solvers. No need to reduce max step.
Even 2m step gives acceptable result.

With Ikf=0 ngspice prints a warning:
Warning: IKF too small - model effect disabled!

I am using ngspice-42 compiled from source:
--enable-xspice
--enable-cider
--enable-osdi
--enable-predictor
--enable-capbypass
--enable-klu
--enable-openmp

[dwarning]

@ivandi69
Which circuit you are using: The inital request or the shorter test case from Vadim?
You see the warning in Qucs-S log file?

EDIT:
OK --enable-predictor makes the difference for time step control

[ivandi69]

@dwarning
The shorter test case from Vadim. I added IKF to the 1N4007 model and tested it in ngspice.
In Qucs-s when using 1N4007 diode from Diodes.lib there is no IKF in the generated netlist even if the parameter is available and set to zero. When using spice diode (the red one) with model card and IKF=0 the warning is there.

[ra3xdh]

I am getting convergence error even with omitted maxstep and explicit Ikf=0. Only Ikf=1e-20 works for me. See the log below.

ngspice 6 -> listing
        * diode test schematic

     2 : .global gnd
     3 : v1 _net1 0 dc 0 sin(0 470 50 0 0 0) ac 470 acphase 0
     4 : c1 0 out 10u
     5 : r1 _net0 out 400k tc1=0.0 tc2=0.0
     6 : r2 0 out 4.2k tc1=0.0 tc2=0.0
     7 : d1 _net1 _net0 dmod_d_1n4007_1 area=1.0 temp=26.85
    11 : .model dmod_d_1n4007_1 d (is=7.69e-11 n=1.45 cj0=2.65e-11 m=0.333 vj=0.7 fc=0.5 rs=0.042 tt=4.32e-6 kf=0 af=1 bv=1000 ibv=5e-6 xti=3 eg=1.11 tcv=0 trs=0 ttt1=0 ttt2=0 tm1=0 tm2=0 tnom=26.85 ikf=0)
    14 : .tran 0.001 3
    15 : .end
ngspice 7 -> run
Doing analysis at TEMP = 27.000000 and TNOM = 27.000000

Warning: IKF too small - model effect disabled!

Initial Transient Solution
--------------------------

Node                                   Voltage
----                                   -------
_net1                                        0
out                                -2.2502e-19
_net0                             -2.16555e-17
v1#branch                          5.35763e-23

doAnalyses: TRAN:  Timestep too small; time = 1.54423, timestep = 1.25e-15: trouble with dmod_d_1n4007_1-instance d1


run simulation(s) aborted
ngspice 8 -> 

[ivandi69]

OK, it fails with windows build of ngspice-42+ and Ikf=0.
Timestep too small; time = 1.66187, timestep = 1.25e-15

It works with Ikf=1e-20.

[ivandi69]

On windows ngspice-42+ if I put option klu in spiceinit it converges with step 0.001, but the resulting waveform is wrong. Reducing the step to 100us works for both sparse and klu solvers.