File mode specification error: (void-function rust-mode)

[jroimartin]

The following error is returned when opening a .rs file:

File mode specification error: (void-function rust-mode)

It seems to be caused by:

rust-mode/rust-mode.el

Lines 78 to 79 in d8a09f2

	;;;###autoload
	(add-to-list 'auto-mode-alist '("\\.rs\\'" . rust-mode))

Because after the last changes to support treesitter, no rust-mode is autoloaded.

rust-mode/rust-mode.el

Lines 74 to 76 in d8a09f2

	(if (and (version<= "29.1" emacs-version) rust-mode-treesitter-derive)
	(require 'rust-mode-treesitter)
	(require 'rust-prog-mode))

rust-mode/rust-prog-mode.el

Line 1448 in d8a09f2

(define-derived-mode rust-mode prog-mode "Rust"

rust-mode/rust-mode-treesitter.el

Line 15 in d8a09f2

(define-derived-mode rust-mode rust-ts-mode "Rust"

My current workaround it is to require 'rust-mode in my init.el. However, this was not necessary before and it woud be great to continue supporting lazy-loading.

[psibi]

How are you installing rust-mode ?

[psibi]

With this configuration I'm not able to reproduce the issue:

(use-package rust-mode
  :defer t
  :init
  (setq rust-mode-treesitter-derive t))

[jroimartin]

@psibi plain package.el. These are the relevant pieces of my configuration:

(custom-set-variables
 ;; custom-set-variables was added by Custom.
 ;; If you edit it by hand, you could mess it up, so be careful.
 ;; Your init file should contain only one such instance.
 ;; If there is more than one, they won't work right.
 '(package-selected-packages
   '(denote forge dockerfile-mode rust-mode yaml-mode magit go-mode markdown-mode)))

;; Install selected packages if any is missing.
(unless (seq-every-p #'package-installed-p package-selected-packages)
  (package-install-selected-packages))

;; Rust.
;; Requires: rustup [+toolchain] component add rust-analyzer
;; Indentation: 4 spaces
(customize-set-variable 'rust-indent-offset 4)
(add-hook 'rust-mode-hook
          #'(lambda ()
              (setq indent-tabs-mode nil)))
(add-hook 'rust-mode-hook
          #'(lambda ()
              (eglot-ensure)
              (add-hook 'before-save-hook #'eglot-format-buffer nil t)))

[psibi]

Thanks!

Does reverting this PR fix it: https://github.com/rust-lang/rust-mode/pull/526/files ?

[jroimartin]

@psibi probably, but that would break the treesitter derived mode, right?

If I'm not wrong, you choose the right rust-mode based on this:

rust-mode/rust-mode.el

Lines 74 to 76 in d8a09f2

	(if (and (version<= "29.1" emacs-version) rust-mode-treesitter-derive)
	(require 'rust-mode-treesitter)
	(require 'rust-prog-mode))

What about doing something like this? (not tested)

;;;###autoload
(add-to-list 'auto-mode-alist '("\\.rs\\'" . rust-mode-choose))

;;;###autoload
(defun rust-mode-choose ()
  "Choose the appropriate rust-mode."
  (if (and (version<= "29.1" emacs-version) rust-mode-treesitter-derive)
      (require 'rust-mode-treesitter)
    (require 'rust-prog-mode))
  (rust-mode))

[psibi]

That sounds fair, can you send out a PR for it ? CC: @condy0919 What do you think about the above proposed patch ?

[psibi]

(add-to-list 'auto-mode-alist '("\.rs\'" . rust-mode-choose))

Thinking further, I'm not so sure about this: Since rust-mode-chose is not a mode.

[jroimartin]

I have just created #530. You can see in the default auto-mode-alist value, that this pattern is commonly used. For instance,

     ("[/.]c\\(?:on\\)?f\\(?:i?g\\)?\\(?:\\.[a-zA-Z0-9._-]+\\)?\\'" . conf-mode-maybe)

(defun conf-mode-maybe ()
  "Select Conf mode or XML mode according to start of file."
  (if (save-excursion
	(save-restriction
	  (widen)
	  (goto-char (point-min))
	  (looking-at "<\\?xml \\|<!-- \\|<!DOCTYPE ")))
      (xml-mode)
    (conf-mode)))

[psibi]

Cool, thanks!

[jroimartin]

That being said, I'm far from being an experienced elisp programmer. So, take everything I said with a grain of salt.

[condy0919]

Good job！

[ia0]

Thanks! I confirm the fix on my side.