shell.nix

{ pkgs ? import ./nixpkgs { }, docTools ? true, ghcVersion ? "9.4.8" }:

with pkgs;

let
  macOS-security =
    # make `/usr/bin/security` available in `PATH`, which is needed for stack
    # on darwin which calls this binary to find certificates
    writeScriptBin "security" ''exec /usr/bin/security "$@"'';
in
mkShell {
  TMPDIR = "/tmp";

  GHC_VERSION = ghcVersion;

  # Set UTF-8 local so that run-tests can parse GHC's unicode output.
  LANG = "C.UTF-8";

  buildInputs = [
    go
    nix
    which
    perl
    python3
    jdk11
    # For stack_install.
    stack
    # Needed for ghcide which expects ghc in PATH.
    haskell.packages."ghc${ builtins.replaceStrings [ "." ] [ "" ] ghcVersion }".ghc
    # Needed for @com_github_golang_protobuf, itself needed by buildifier.
    git
    # Needed to get correct locale for tests with encoding
    glibcLocales
    # to avoid CA certificate failures on macOS CI
    cacert
    # Needed for debug/linking_utils
    binutils
    # check the start script for problems
    shellcheck
    file
  ]
  ++ lib.optionals docTools [ graphviz python3Packages.sphinx zip unzip ]
  ++ lib.optional stdenv.isDarwin macOS-security;

  packages = [ bazel_6 ];

  shellHook = ''
    # Add nix config flags to .bazelrc.local.
    #
    BAZELRC_LOCAL=".bazelrc.local"
    if [ ! -e "$BAZELRC_LOCAL" ]
    then
      echo "[!] It looks like you are using a Nix-based system."
      echo "In order to build this project, you need to add the two"
      echo "following host_platform entries to your .bazelrc.local file:"
      echo
      echo "build --host_platform=@rules_nixpkgs_core//platforms:host"
      echo "run --host_platform=@rules_nixpkgs_core//platforms:host"
    fi
  '';
}