build.gradle

//It all starts here
buildscript {
  repositories {
    mavenLocal()
    gradlePluginPortal()
    maven { url "https://repo.grails.org/grails/core" }
  }
  dependencies {
    classpath "org.grails:grails-gradle-plugin:$grailsVersion"
    classpath "com.github.spotbugs.snom:spotbugs-gradle-plugin:4.7.9"
    classpath "org.yakworks:gradle-plugins:$vShipyak"
    classpath "io.github.gradle-nexus:publish-plugin:$vMavenNexus"
  }
}

group = "org.yakworks"

//our opinionated defaults for gradle groovy & grails projects
apply plugin: 'yakworks.shipyak'
apply plugin: "io.github.gradle-nexus.publish-plugin"

// only setup publishing if its not a snapshot
if(!isSnapshot) {
  nexusPublishing {
    repositories {
      sonatype()
    }
  }
}

subprojects { subprj ->
  apply plugin: 'java'

  group = "org.yakworks"

  repositories {
    mavenLocal()
    mavenCentral()
    maven { url "https://repo.grails.org/grails/core" }
    maven {
      url "http://repo.9ci.com/oss-snapshots"
      allowInsecureProtocol = true
      mavenContent { snapshotsOnly() }
    }
    maven { url "http://repo.9ci.com/public-libs"; allowInsecureProtocol = true }
  }
  // get prop with default if null, converts to boolean
  Closure getProp = { pname, defualtv -> (subprj.findProperty(pname)?:defualtv).toBoolean() }

  ext { // see gradle.properties in sub-projects
    //default true for isGormLibrary and isPublishable, set to false in gradle.props
    isPublishable = getProp('isPublishable', true)
    isGormLibrary = getProp('isGormLibrary', true)
    isExample = getProp('isExample', false)
  }

  plugins.withId('java') {
    sourceCompatibility = "$javaCompatibility"
    targetCompatibility = "$javaCompatibility"
    tasks.withType(JavaCompile) {
      options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
    }
  }

  plugins.withId('groovy') {
    tasks.withType(GroovyCompile) {
      configure(groovyOptions) {
        // sets the path to sys properties so we can use it find grails-app/conf during AST
        forkOptions.jvmArgs = ['-Xmx1524m', '-XX:+UseSerialGC', '-Dgradle.projectDir=' + project.projectDir.absolutePath]
      }
    }
  }

  // if its a lib then setup gpg signing, see signing.gnupg.keyName
  if (isPublishable){
    // println "${subprj} isPublishable ${subprj.findProperty('isPublishable')}"
    apply plugin: 'java-library'

    // gpg signing required by nexus/sonatype
    apply plugin: 'signing'
    afterEvaluate {
      if(!isSnapshot) {
        signing {
          required { gradle.taskGraph.hasTask("publish") }
          useGpgCmd()
          sign publishing.publications.javaLibrary
        }
      }
    }
  } // end isPublishable

  configurations {
    testImplementation.extendsFrom compileOnly
    // compile.extendsFrom implementation
    all {
      resolutionStrategy.cacheChangingModulesFor 1, 'seconds' //when changing = true this sets the cache time
    }
  }

  tasks.withType(Test) {
    //so that we can use in config and share resources/rootlocation across projects for testing
    systemProperty "gradle.rootProjectDir", rootProject.projectDir.absolutePath
    systemProperty "gradle.projectDir", project.projectDir.absolutePath
  }

}
//overrides for the yakworks shipkit configs
ext.codenarcRuleset= '''
  // getRule('Println').enabled = false
  getRule('ClosureAsLastMethodParameter').enabled = false
  getRule('EmptyCatchBlock').enabled = false
  getRule('UnnecessaryToString').enabled = false
  getRule('ExplicitHashMapInstantiation').enabled = false

'''

//TEST logging config for the logger plugin
subprojects { subprj ->
  test {
    // Defaults from https://github.com/radarsh/gradle-test-logger-plugin
    testlogger {
      // theme 'standard'
      showExceptions true
      showStandardStreams = true //shows the printlns in console
      showPassed true
      showSkipped true
      showFailed true
      // slowThreshold 2000 //if tests take longer than this will show time it took
      // showSummary true
      // showSimpleNames false
      // showPassed true
      // showSkipped true
      // showFailed true
      // showPassedStandardStreams true
      // showSkippedStandardStreams true
      // showFailedStandardStreams true
    }
  }
}