build.gradle

apply plugin: 'java-library'
apply plugin: 'maven-publish'
apply plugin: 'signing'
apply plugin: 'signing'


sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

dependencies {
    implementation 'com.squareup.okhttp3:okhttp:4.11.0'
    implementation 'com.google.code.gson:gson:2.10.1'
    implementation 'com.auth0:java-jwt:4.4.0'
    implementation 'org.bouncycastle:bcprov-jdk15on:1.70'

    testImplementation 'org.junit.jupiter:junit-jupiter:5.10.0'
}

repositories {
    mavenCentral()
}

java {
    withSourcesJar()
    withJavadocJar()
}

javadoc {
    source = sourceSets.main.allJava
}

//signing {
//    def signingKey = findProperty("signingKey")
//    def signingPassword = findProperty("signingPassword")
//    useInMemoryPgpKeys(signingKey, signingPassword)
//    sign publishing.publications
//}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = 'com.apple.itunes.storekit'
            artifactId = 'app-store-server-library'

            from components.java
            pom {
                name = "App Store Server Library"
                description = "The Java server library for the App Store Server API and App Store Server Notifications"
                url = "https://github.com/apple/app-store-server-library-java/"
                licenses {
                    license {
                        name = "MIT License"
                        url = "https://github.com/apple/app-store-server-library-java/blob/main/LICENSE.txt"
                    }
                }
                developers {
                    developer {
                        id = 'app-store-server-library-project-authors'
                        name = 'App Store Server Library project authors'
                        email = 'app-store-server-library@group.apple.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com:apple/app-store-server-library-java.git'
                    developerConnection = 'scm:git:ssh://github.com:apple/app-store-server-library-java.git'
                    url = 'https://github.com/apple/app-store-server-library-java/'
                }
            }
        }
    }
    repositories {
        maven {
            credentials {
                username findProperty("mavenUsername")
                password findProperty("mavenPassword")
            }
            if (project.version.endsWith('-SNAPSHOT')) {
                url "https://s01.oss.sonatype.org/content/repositories/snapshots/"
            } else {
                url "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
            }
        }
    }
}

test {
    useJUnitPlatform()
}