build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
apply from: 'dependencies.gradle'

buildscript {
  apply from: 'dependencies.gradle'

  repositories {
    jcenter()
  }
  dependencies {
    classpath gradlePlugins.androidToolsPlugin
    classpath gradlePlugins.jacoco
  }
}

allprojects {
  repositories {
    jcenter()
  }
}

subprojects {
  // Log instrumentation tests results.
  tasks.withType(com.android.build.gradle.internal.tasks.AndroidTestTask) { task ->
    doFirst {
      logging.setLevel(LogLevel.INFO)
    }
    doLast {
      logging.setLevel(LogLevel.LIFECYCLE)
    }
  }
}

task wrapper(type: Wrapper) {
  gradleVersion = '2.14.1'
}

task clean(type: Delete) {
  delete rootProject.buildDir
}

def isCi() {
  project.hasProperty('CI') && CI.equals('true')
}

def isReleaseBuild() {
  return VERSION_NAME.contains("SNAPSHOT") == false
}

def getReleaseRepositoryUrl() {
  return hasProperty('RELEASE_REPOSITORY_URL') ? RELEASE_REPOSITORY_URL : "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
}

def getSnapshotRepositoryUrl() {
  return hasProperty('SNAPSHOT_REPOSITORY_URL') ? SNAPSHOT_REPOSITORY_URL : "https://oss.sonatype.org/content/repositories/snapshots/"
}

def getRepositoryUsername() {
  return hasProperty('NEXUS_USERNAME') ? NEXUS_USERNAME : ""
}

def getRepositoryPassword() {
  return hasProperty('NEXUS_PASSWORD') ? NEXUS_PASSWORD : ""
}