Merge pull request #9 from EspressoSystems/nix

Repo configuration

CODEOWNERS

@@ -0,0 +1,9 @@
+# These owners will be the default owners for everything in the repo. Unless a
+# later match takes precedence, they will be requested for review when someone
+# opens a pull request.
+
+*       @nomaxg @sveitser @jbearer
+
+#  Dependabot PRs
+*.toml  @nomaxg @sveitser
+*.lock  @nomaxg @sveitser

flake.nix

@@ -0,0 +1,63 @@
+{
+  description = "A Nix-flake-based Go 1.17 development environment";
+
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+  inputs.flake-utils.url = "github:numtide/flake-utils";
+  inputs.flake-compat.url = "github:edolstra/flake-compat";
+  inputs.flake-compat.flake = false;
+
+  inputs.foundry.url = "github:shazow/foundry.nix/monthly"; # Use monthly branch for permanent releases
+
+  outputs = { self, flake-utils, nixpkgs, foundry, ... }:
+    let
+      goVersion = 19; # Change this to update the whole stack
+      overlays = [
+        (final: prev: {
+          go = prev."go_1_${toString goVersion}";
+          # Overlaying nodejs here to ensure nodePackages use the desired
+          # version of nodejs.
+          nodejs = prev.nodejs-16_x;
+          pnpm = prev.nodePackages.pnpm;
+          yarn = prev.nodePackages.yarn;
+        })
+        foundry.overlay
+      ];
+    in
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        pkgs = import nixpkgs {
+          inherit overlays system;
+          config = {
+            permittedInsecurePackages = [ "nodejs-16.20.1" ];
+          };
+        };
+      in
+      {
+        devShells.default = pkgs.mkShell {
+          packages = with pkgs; [
+            go
+            # goimports, godoc, etc.
+            gotools
+            # https://github.com/golangci/golangci-lint
+            golangci-lint
+
+            # Node
+            pnpm
+            yarn # `pnpm build` fails without this
+
+            # Foundry, and tools like the anvil dev node
+            foundry-bin
+
+            # Docker
+            docker-compose # provides the `docker-compose` command
+
+            # Python
+            (python3.withPackages (ps: with ps; [ ]))
+            jq
+
+            # geth node
+            go-ethereum
+          ];
+        };
+      });
+}

shell.nix

@@ -0,0 +1,13 @@
+(import
+  (
+    let
+      lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+    in
+    fetchTarball {
+      url = "https://github.com/edolstra/flake-compat/archive/${lock.nodes.flake-compat.locked.rev}.tar.gz";
+      sha256 = lock.nodes.flake-compat.locked.narHash;
+    }
+  )
+  {
+    src = ./.;
+  }).shellNix